1*> \brief \b ZGELQS
2*
3*  =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6*            http://www.netlib.org/lapack/explore-html/
7*
8*  Definition:
9*  ===========
10*
11*       SUBROUTINE ZGELQS( M, N, NRHS, A, LDA, TAU, B, LDB, WORK, LWORK,
12*                          INFO )
13*
14*       .. Scalar Arguments ..
15*       INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
16*       ..
17*       .. Array Arguments ..
18*       COMPLEX*16         A( LDA, * ), B( LDB, * ), TAU( * ),
19*      $                   WORK( LWORK )
20*       ..
21*
22*
23*> \par Purpose:
24*  =============
25*>
26*> \verbatim
27*>
28*> Compute a minimum-norm solution
29*>     min || A*X - B ||
30*> using the LQ factorization
31*>     A = L*Q
32*> computed by ZGELQF.
33*> \endverbatim
34*
35*  Arguments:
36*  ==========
37*
38*> \param[in] M
39*> \verbatim
40*>          M is INTEGER
41*>          The number of rows of the matrix A.  M >= 0.
42*> \endverbatim
43*>
44*> \param[in] N
45*> \verbatim
46*>          N is INTEGER
47*>          The number of columns of the matrix A.  N >= M >= 0.
48*> \endverbatim
49*>
50*> \param[in] NRHS
51*> \verbatim
52*>          NRHS is INTEGER
53*>          The number of columns of B.  NRHS >= 0.
54*> \endverbatim
55*>
56*> \param[in] A
57*> \verbatim
58*>          A is COMPLEX*16 array, dimension (LDA,N)
59*>          Details of the LQ factorization of the original matrix A as
60*>          returned by ZGELQF.
61*> \endverbatim
62*>
63*> \param[in] LDA
64*> \verbatim
65*>          LDA is INTEGER
66*>          The leading dimension of the array A.  LDA >= M.
67*> \endverbatim
68*>
69*> \param[in] TAU
70*> \verbatim
71*>          TAU is COMPLEX*16 array, dimension (M)
72*>          Details of the orthogonal matrix Q.
73*> \endverbatim
74*>
75*> \param[in,out] B
76*> \verbatim
77*>          B is COMPLEX*16 array, dimension (LDB,NRHS)
78*>          On entry, the m-by-nrhs right hand side matrix B.
79*>          On exit, the n-by-nrhs solution matrix X.
80*> \endverbatim
81*>
82*> \param[in] LDB
83*> \verbatim
84*>          LDB is INTEGER
85*>          The leading dimension of the array B. LDB >= N.
86*> \endverbatim
87*>
88*> \param[out] WORK
89*> \verbatim
90*>          WORK is COMPLEX*16 array, dimension (LWORK)
91*> \endverbatim
92*>
93*> \param[in] LWORK
94*> \verbatim
95*>          LWORK is INTEGER
96*>          The length of the array WORK.  LWORK must be at least NRHS,
97*>          and should be at least NRHS*NB, where NB is the block size
98*>          for this environment.
99*> \endverbatim
100*>
101*> \param[out] INFO
102*> \verbatim
103*>          INFO is INTEGER
104*>          = 0: successful exit
105*>          < 0: if INFO = -i, the i-th argument had an illegal value
106*> \endverbatim
107*
108*  Authors:
109*  ========
110*
111*> \author Univ. of Tennessee
112*> \author Univ. of California Berkeley
113*> \author Univ. of Colorado Denver
114*> \author NAG Ltd.
115*
116*> \ingroup complex16_lin
117*
118*  =====================================================================
119      SUBROUTINE ZGELQS( M, N, NRHS, A, LDA, TAU, B, LDB, WORK, LWORK,
120     $                   INFO )
121*
122*  -- LAPACK test routine --
123*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
124*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
125*
126*     .. Scalar Arguments ..
127      INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
128*     ..
129*     .. Array Arguments ..
130      COMPLEX*16         A( LDA, * ), B( LDB, * ), TAU( * ),
131     $                   WORK( LWORK )
132*     ..
133*
134*  =====================================================================
135*
136*     .. Parameters ..
137      COMPLEX*16         CZERO, CONE
138      PARAMETER          ( CZERO = ( 0.0D+0, 0.0D+0 ),
139     $                   CONE = ( 1.0D+0, 0.0D+0 ) )
140*     ..
141*     .. External Subroutines ..
142      EXTERNAL           XERBLA, ZLASET, ZTRSM, ZUNMLQ
143*     ..
144*     .. Intrinsic Functions ..
145      INTRINSIC          MAX
146*     ..
147*     .. Executable Statements ..
148*
149*     Test the input parameters.
150*
151      INFO = 0
152      IF( M.LT.0 ) THEN
153         INFO = -1
154      ELSE IF( N.LT.0 .OR. M.GT.N ) THEN
155         INFO = -2
156      ELSE IF( NRHS.LT.0 ) THEN
157         INFO = -3
158      ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
159         INFO = -5
160      ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
161         INFO = -8
162      ELSE IF( LWORK.LT.1 .OR. LWORK.LT.NRHS .AND. M.GT.0 .AND. N.GT.0 )
163     $          THEN
164         INFO = -10
165      END IF
166      IF( INFO.NE.0 ) THEN
167         CALL XERBLA( 'ZGELQS', -INFO )
168         RETURN
169      END IF
170*
171*     Quick return if possible
172*
173      IF( N.EQ.0 .OR. NRHS.EQ.0 .OR. M.EQ.0 )
174     $   RETURN
175*
176*     Solve L*X = B(1:m,:)
177*
178      CALL ZTRSM( 'Left', 'Lower', 'No transpose', 'Non-unit', M, NRHS,
179     $            CONE, A, LDA, B, LDB )
180*
181*     Set B(m+1:n,:) to zero
182*
183      IF( M.LT.N )
184     $   CALL ZLASET( 'Full', N-M, NRHS, CZERO, CZERO, B( M+1, 1 ),
185     $                LDB )
186*
187*     B := Q' * B
188*
189      CALL ZUNMLQ( 'Left', 'Conjugate transpose', N, NRHS, M, A, LDA,
190     $             TAU, B, LDB, WORK, LWORK, INFO )
191*
192      RETURN
193*
194*     End of ZGELQS
195*
196      END
197