1# Compare hidden3d and pm3d methods for handling hidden surface removal
2
3unset border
4set dummy u, v
5unset key
6set view 225, 206, 1.25, 0.50
7unset xtics
8unset ytics
9unset ztics
10unset colorbox
11
12set parametric
13set dummy u,v
14set urange [ -3.14159 : 3.14159 ] noreverse nowriteback
15set vrange [ 0.250000 : 3.14159 ] noreverse nowriteback
16set isosamples 50, 20
17
18set multiplot layout 1,2 margins .05,.95,.2,.8 spacing 0.05
19
20set title "hidden3d 2-color surface"
21set hidden3d back offset 1
22
23splot (cos(u)+.5*cos(u)*cos(v))*(1.+sin(11.*u)/10.), \
24      (sin(u)+.5*sin(u)*cos(v))*(1.+sin(11.*u)/10.), \
25      0.5*sin(v) with lines lt 3
26
27set title "pm3d 2-color surface"
28set pm3d depthorder
29set pm3d interpolate 1,1 # border linecolor rgb "#a0a0f0"  linewidth 0.500
30set pm3d lighting primary 0.33 specular 0.2 spec2 0.3
31set isosamples 200,200
32
33splot (cos(u)+.5*cos(u)*cos(v))*(1.+sin(11.*u)/10.), \
34      (sin(u)+.5*sin(u)*cos(v))*(1.+sin(11.*u)/10.), \
35      0.5*sin(v) with pm3d fc ls 3
36
37unset multiplot
38
39pause -1 "<return> to continue"
40reset
41