1*> \brief \b ZRZT01
2*
3*  =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6*            http://www.netlib.org/lapack/explore-html/
7*
8*  Definition:
9*  ===========
10*
11*       DOUBLE PRECISION FUNCTION ZRZT01( M, N, A, AF, LDA, TAU, WORK,
12*                        LWORK )
13*
14*       .. Scalar Arguments ..
15*       INTEGER            LDA, LWORK, M, N
16*       ..
17*       .. Array Arguments ..
18*       COMPLEX*16         A( LDA, * ), AF( LDA, * ), TAU( * ),
19*      $                   WORK( LWORK )
20*       ..
21*
22*
23*> \par Purpose:
24*  =============
25*>
26*> \verbatim
27*>
28*> ZRZT01 returns
29*>      || A - R*Q || / ( M * eps * ||A|| )
30*> for an upper trapezoidal A that was factored with ZTZRZF.
31*> \endverbatim
32*
33*  Arguments:
34*  ==========
35*
36*> \param[in] M
37*> \verbatim
38*>          M is INTEGER
39*>          The number of rows of the matrices A and AF.
40*> \endverbatim
41*>
42*> \param[in] N
43*> \verbatim
44*>          N is INTEGER
45*>          The number of columns of the matrices A and AF.
46*> \endverbatim
47*>
48*> \param[in] A
49*> \verbatim
50*>          A is COMPLEX*16 array, dimension (LDA,N)
51*>          The original upper trapezoidal M by N matrix A.
52*> \endverbatim
53*>
54*> \param[in] AF
55*> \verbatim
56*>          AF is COMPLEX*16 array, dimension (LDA,N)
57*>          The output of ZTZRZF for input matrix A.
58*>          The lower triangle is not referenced.
59*> \endverbatim
60*>
61*> \param[in] LDA
62*> \verbatim
63*>          LDA is INTEGER
64*>          The leading dimension of the arrays A and AF.
65*> \endverbatim
66*>
67*> \param[in] TAU
68*> \verbatim
69*>          TAU is COMPLEX*16 array, dimension (M)
70*>          Details of the  Householder transformations as returned by
71*>          ZTZRZF.
72*> \endverbatim
73*>
74*> \param[out] WORK
75*> \verbatim
76*>          WORK is COMPLEX*16 array, dimension (LWORK)
77*> \endverbatim
78*>
79*> \param[in] LWORK
80*> \verbatim
81*>          LWORK is INTEGER
82*>          The length of the array WORK.  LWORK >= m*n + m.
83*> \endverbatim
84*
85*  Authors:
86*  ========
87*
88*> \author Univ. of Tennessee
89*> \author Univ. of California Berkeley
90*> \author Univ. of Colorado Denver
91*> \author NAG Ltd.
92*
93*> \ingroup complex16_lin
94*
95*  =====================================================================
96      DOUBLE PRECISION FUNCTION ZRZT01( M, N, A, AF, LDA, TAU, WORK,
97     $                 LWORK )
98*
99*  -- LAPACK test routine --
100*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
101*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
102*
103*     .. Scalar Arguments ..
104      INTEGER            LDA, LWORK, M, N
105*     ..
106*     .. Array Arguments ..
107      COMPLEX*16         A( LDA, * ), AF( LDA, * ), TAU( * ),
108     $                   WORK( LWORK )
109*     ..
110*
111*  =====================================================================
112*
113*     .. Parameters ..
114      DOUBLE PRECISION   ZERO, ONE
115      PARAMETER          ( ZERO = 0.0D0, ONE = 1.0D0 )
116*     ..
117*     .. Local Scalars ..
118      INTEGER            I, INFO, J
119      DOUBLE PRECISION   NORMA
120*     ..
121*     .. Local Arrays ..
122      DOUBLE PRECISION   RWORK( 1 )
123*     ..
124*     .. External Functions ..
125      DOUBLE PRECISION   DLAMCH, ZLANGE
126      EXTERNAL           DLAMCH, ZLANGE
127*     ..
128*     .. External Subroutines ..
129      EXTERNAL           XERBLA, ZAXPY, ZLASET, ZUNMRZ
130*     ..
131*     .. Intrinsic Functions ..
132      INTRINSIC          DBLE, DCMPLX, MAX
133*     ..
134*     .. Executable Statements ..
135*
136      ZRZT01 = ZERO
137*
138      IF( LWORK.LT.M*N+M ) THEN
139         CALL XERBLA( 'ZRZT01', 8 )
140         RETURN
141      END IF
142*
143*     Quick return if possible
144*
145      IF( M.LE.0 .OR. N.LE.0 )
146     $   RETURN
147*
148      NORMA = ZLANGE( 'One-norm', M, N, A, LDA, RWORK )
149*
150*     Copy upper triangle R
151*
152      CALL ZLASET( 'Full', M, N, DCMPLX( ZERO ), DCMPLX( ZERO ), WORK,
153     $             M )
154      DO 20 J = 1, M
155         DO 10 I = 1, J
156            WORK( ( J-1 )*M+I ) = AF( I, J )
157   10    CONTINUE
158   20 CONTINUE
159*
160*     R = R * P(1) * ... *P(m)
161*
162      CALL ZUNMRZ( 'Right', 'No tranpose', M, N, M, N-M, AF, LDA, TAU,
163     $             WORK, M, WORK( M*N+1 ), LWORK-M*N, INFO )
164*
165*     R = R - A
166*
167      DO 30 I = 1, N
168         CALL ZAXPY( M, DCMPLX( -ONE ), A( 1, I ), 1,
169     $               WORK( ( I-1 )*M+1 ), 1 )
170   30 CONTINUE
171*
172      ZRZT01 = ZLANGE( 'One-norm', M, N, WORK, M, RWORK )
173*
174      ZRZT01 = ZRZT01 / ( DLAMCH( 'Epsilon' )*DBLE( MAX( M, N ) ) )
175      IF( NORMA.NE.ZERO )
176     $   ZRZT01 = ZRZT01 / NORMA
177*
178      RETURN
179*
180*     End of ZRZT01
181*
182      END
183