1*> \brief \b DGTT05
2*
3*  =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6*            http://www.netlib.org/lapack/explore-html/
7*
8*  Definition:
9*  ===========
10*
11*       SUBROUTINE DGTT05( TRANS, N, NRHS, DL, D, DU, B, LDB, X, LDX,
12*                          XACT, LDXACT, FERR, BERR, RESLTS )
13*
14*       .. Scalar Arguments ..
15*       CHARACTER          TRANS
16*       INTEGER            LDB, LDX, LDXACT, N, NRHS
17*       ..
18*       .. Array Arguments ..
19*       DOUBLE PRECISION   B( LDB, * ), BERR( * ), D( * ), DL( * ),
20*      $                   DU( * ), FERR( * ), RESLTS( * ), X( LDX, * ),
21*      $                   XACT( LDXACT, * )
22*       ..
23*
24*
25*> \par Purpose:
26*  =============
27*>
28*> \verbatim
29*>
30*> DGTT05 tests the error bounds from iterative refinement for the
31*> computed solution to a system of equations A*X = B, where A is a
32*> general tridiagonal matrix of order n and op(A) = A or A**T,
33*> depending on TRANS.
34*>
35*> RESLTS(1) = test of the error bound
36*>           = norm(X - XACT) / ( norm(X) * FERR )
37*>
38*> A large value is returned if this ratio is not less than one.
39*>
40*> RESLTS(2) = residual from the iterative refinement routine
41*>           = the maximum of BERR / ( NZ*EPS + (*) ), where
42*>             (*) = NZ*UNFL / (min_i (abs(op(A))*abs(X) +abs(b))_i )
43*>             and NZ = max. number of nonzeros in any row of A, plus 1
44*> \endverbatim
45*
46*  Arguments:
47*  ==========
48*
49*> \param[in] TRANS
50*> \verbatim
51*>          TRANS is CHARACTER*1
52*>          Specifies the form of the system of equations.
53*>          = 'N':  A * X = B     (No transpose)
54*>          = 'T':  A**T * X = B  (Transpose)
55*>          = 'C':  A**H * X = B  (Conjugate transpose = Transpose)
56*> \endverbatim
57*>
58*> \param[in] N
59*> \verbatim
60*>          N is INTEGER
61*>          The number of rows of the matrices X and XACT.  N >= 0.
62*> \endverbatim
63*>
64*> \param[in] NRHS
65*> \verbatim
66*>          NRHS is INTEGER
67*>          The number of columns of the matrices X and XACT.  NRHS >= 0.
68*> \endverbatim
69*>
70*> \param[in] DL
71*> \verbatim
72*>          DL is DOUBLE PRECISION array, dimension (N-1)
73*>          The (n-1) sub-diagonal elements of A.
74*> \endverbatim
75*>
76*> \param[in] D
77*> \verbatim
78*>          D is DOUBLE PRECISION array, dimension (N)
79*>          The diagonal elements of A.
80*> \endverbatim
81*>
82*> \param[in] DU
83*> \verbatim
84*>          DU is DOUBLE PRECISION array, dimension (N-1)
85*>          The (n-1) super-diagonal elements of A.
86*> \endverbatim
87*>
88*> \param[in] B
89*> \verbatim
90*>          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
91*>          The right hand side vectors for the system of linear
92*>          equations.
93*> \endverbatim
94*>
95*> \param[in] LDB
96*> \verbatim
97*>          LDB is INTEGER
98*>          The leading dimension of the array B.  LDB >= max(1,N).
99*> \endverbatim
100*>
101*> \param[in] X
102*> \verbatim
103*>          X is DOUBLE PRECISION array, dimension (LDX,NRHS)
104*>          The computed solution vectors.  Each vector is stored as a
105*>          column of the matrix X.
106*> \endverbatim
107*>
108*> \param[in] LDX
109*> \verbatim
110*>          LDX is INTEGER
111*>          The leading dimension of the array X.  LDX >= max(1,N).
112*> \endverbatim
113*>
114*> \param[in] XACT
115*> \verbatim
116*>          XACT is DOUBLE PRECISION array, dimension (LDX,NRHS)
117*>          The exact solution vectors.  Each vector is stored as a
118*>          column of the matrix XACT.
119*> \endverbatim
120*>
121*> \param[in] LDXACT
122*> \verbatim
123*>          LDXACT is INTEGER
124*>          The leading dimension of the array XACT.  LDXACT >= max(1,N).
125*> \endverbatim
126*>
127*> \param[in] FERR
128*> \verbatim
129*>          FERR is DOUBLE PRECISION array, dimension (NRHS)
130*>          The estimated forward error bounds for each solution vector
131*>          X.  If XTRUE is the true solution, FERR bounds the magnitude
132*>          of the largest entry in (X - XTRUE) divided by the magnitude
133*>          of the largest entry in X.
134*> \endverbatim
135*>
136*> \param[in] BERR
137*> \verbatim
138*>          BERR is DOUBLE PRECISION array, dimension (NRHS)
139*>          The componentwise relative backward error of each solution
140*>          vector (i.e., the smallest relative change in any entry of A
141*>          or B that makes X an exact solution).
142*> \endverbatim
143*>
144*> \param[out] RESLTS
145*> \verbatim
146*>          RESLTS is DOUBLE PRECISION array, dimension (2)
147*>          The maximum over the NRHS solution vectors of the ratios:
148*>          RESLTS(1) = norm(X - XACT) / ( norm(X) * FERR )
149*>          RESLTS(2) = BERR / ( NZ*EPS + (*) )
150*> \endverbatim
151*
152*  Authors:
153*  ========
154*
155*> \author Univ. of Tennessee
156*> \author Univ. of California Berkeley
157*> \author Univ. of Colorado Denver
158*> \author NAG Ltd.
159*
160*> \date November 2011
161*
162*> \ingroup double_lin
163*
164*  =====================================================================
165      SUBROUTINE DGTT05( TRANS, N, NRHS, DL, D, DU, B, LDB, X, LDX,
166     $                   XACT, LDXACT, FERR, BERR, RESLTS )
167*
168*  -- LAPACK test routine (version 3.4.0) --
169*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
170*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
171*     November 2011
172*
173*     .. Scalar Arguments ..
174      CHARACTER          TRANS
175      INTEGER            LDB, LDX, LDXACT, N, NRHS
176*     ..
177*     .. Array Arguments ..
178      DOUBLE PRECISION   B( LDB, * ), BERR( * ), D( * ), DL( * ),
179     $                   DU( * ), FERR( * ), RESLTS( * ), X( LDX, * ),
180     $                   XACT( LDXACT, * )
181*     ..
182*
183*  =====================================================================
184*
185*     .. Parameters ..
186      DOUBLE PRECISION   ZERO, ONE
187      PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
188*     ..
189*     .. Local Scalars ..
190      LOGICAL            NOTRAN
191      INTEGER            I, IMAX, J, K, NZ
192      DOUBLE PRECISION   AXBI, DIFF, EPS, ERRBND, OVFL, TMP, UNFL, XNORM
193*     ..
194*     .. External Functions ..
195      LOGICAL            LSAME
196      INTEGER            IDAMAX
197      DOUBLE PRECISION   DLAMCH
198      EXTERNAL           LSAME, IDAMAX, DLAMCH
199*     ..
200*     .. Intrinsic Functions ..
201      INTRINSIC          ABS, MAX, MIN
202*     ..
203*     .. Executable Statements ..
204*
205*     Quick exit if N = 0 or NRHS = 0.
206*
207      IF( N.LE.0 .OR. NRHS.LE.0 ) THEN
208         RESLTS( 1 ) = ZERO
209         RESLTS( 2 ) = ZERO
210         RETURN
211      END IF
212*
213      EPS = DLAMCH( 'Epsilon' )
214      UNFL = DLAMCH( 'Safe minimum' )
215      OVFL = ONE / UNFL
216      NOTRAN = LSAME( TRANS, 'N' )
217      NZ = 4
218*
219*     Test 1:  Compute the maximum of
220*        norm(X - XACT) / ( norm(X) * FERR )
221*     over all the vectors X and XACT using the infinity-norm.
222*
223      ERRBND = ZERO
224      DO 30 J = 1, NRHS
225         IMAX = IDAMAX( N, X( 1, J ), 1 )
226         XNORM = MAX( ABS( X( IMAX, J ) ), UNFL )
227         DIFF = ZERO
228         DO 10 I = 1, N
229            DIFF = MAX( DIFF, ABS( X( I, J )-XACT( I, J ) ) )
230   10    CONTINUE
231*
232         IF( XNORM.GT.ONE ) THEN
233            GO TO 20
234         ELSE IF( DIFF.LE.OVFL*XNORM ) THEN
235            GO TO 20
236         ELSE
237            ERRBND = ONE / EPS
238            GO TO 30
239         END IF
240*
241   20    CONTINUE
242         IF( DIFF / XNORM.LE.FERR( J ) ) THEN
243            ERRBND = MAX( ERRBND, ( DIFF / XNORM ) / FERR( J ) )
244         ELSE
245            ERRBND = ONE / EPS
246         END IF
247   30 CONTINUE
248      RESLTS( 1 ) = ERRBND
249*
250*     Test 2:  Compute the maximum of BERR / ( NZ*EPS + (*) ), where
251*     (*) = NZ*UNFL / (min_i (abs(op(A))*abs(X) +abs(b))_i )
252*
253      DO 60 K = 1, NRHS
254         IF( NOTRAN ) THEN
255            IF( N.EQ.1 ) THEN
256               AXBI = ABS( B( 1, K ) ) + ABS( D( 1 )*X( 1, K ) )
257            ELSE
258               AXBI = ABS( B( 1, K ) ) + ABS( D( 1 )*X( 1, K ) ) +
259     $                ABS( DU( 1 )*X( 2, K ) )
260               DO 40 I = 2, N - 1
261                  TMP = ABS( B( I, K ) ) + ABS( DL( I-1 )*X( I-1, K ) )
262     $                   + ABS( D( I )*X( I, K ) ) +
263     $                  ABS( DU( I )*X( I+1, K ) )
264                  AXBI = MIN( AXBI, TMP )
265   40          CONTINUE
266               TMP = ABS( B( N, K ) ) + ABS( DL( N-1 )*X( N-1, K ) ) +
267     $               ABS( D( N )*X( N, K ) )
268               AXBI = MIN( AXBI, TMP )
269            END IF
270         ELSE
271            IF( N.EQ.1 ) THEN
272               AXBI = ABS( B( 1, K ) ) + ABS( D( 1 )*X( 1, K ) )
273            ELSE
274               AXBI = ABS( B( 1, K ) ) + ABS( D( 1 )*X( 1, K ) ) +
275     $                ABS( DL( 1 )*X( 2, K ) )
276               DO 50 I = 2, N - 1
277                  TMP = ABS( B( I, K ) ) + ABS( DU( I-1 )*X( I-1, K ) )
278     $                   + ABS( D( I )*X( I, K ) ) +
279     $                  ABS( DL( I )*X( I+1, K ) )
280                  AXBI = MIN( AXBI, TMP )
281   50          CONTINUE
282               TMP = ABS( B( N, K ) ) + ABS( DU( N-1 )*X( N-1, K ) ) +
283     $               ABS( D( N )*X( N, K ) )
284               AXBI = MIN( AXBI, TMP )
285            END IF
286         END IF
287         TMP = BERR( K ) / ( NZ*EPS+NZ*UNFL / MAX( AXBI, NZ*UNFL ) )
288         IF( K.EQ.1 ) THEN
289            RESLTS( 2 ) = TMP
290         ELSE
291            RESLTS( 2 ) = MAX( RESLTS( 2 ), TMP )
292         END IF
293   60 CONTINUE
294*
295      RETURN
296*
297*     End of DGTT05
298*
299      END
300