1*> \brief \b SSYT01_AA
2*
3*  =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6*            http://www.netlib.org/lapack/explore-html/
7*
8*  Definition:
9*  ===========
10*
11*       SUBROUTINE SSYT01_AA( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV,
12*                             C, LDC, RWORK, RESID )
13*
14*       .. Scalar Arguments ..
15*       CHARACTER          UPLO
16*       INTEGER            LDA, LDAFAC, LDC, N
17*       REAL               RESID
18*       ..
19*       .. Array Arguments ..
20*       INTEGER            IPIV( * )
21*       REAL               A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * ),
22*      $                   RWORK( * )
23*       ..
24*
25*
26*> \par Purpose:
27*  =============
28*>
29*> \verbatim
30*>
31*> SSYT01_AA reconstructs a symmetric indefinite matrix A from its
32*> block L*D*L' or U*D*U' factorization and computes the residual
33*>    norm( C - A ) / ( N * norm(A) * EPS ),
34*> where C is the reconstructed matrix and EPS is the machine epsilon.
35*> \endverbatim
36*
37*  Arguments:
38*  ==========
39*
40*> \param[in] UPLO
41*> \verbatim
42*>          UPLO is CHARACTER*1
43*>          Specifies whether the upper or lower triangular part of the
44*>          symmetric matrix A is stored:
45*>          = 'U':  Upper triangular
46*>          = 'L':  Lower triangular
47*> \endverbatim
48*>
49*> \param[in] N
50*> \verbatim
51*>          N is INTEGER
52*>          The number of rows and columns of the matrix A.  N >= 0.
53*> \endverbatim
54*>
55*> \param[in] A
56*> \verbatim
57*>          A is REAL array, dimension (LDA,N)
58*>          The original symmetric matrix A.
59*> \endverbatim
60*>
61*> \param[in] LDA
62*> \verbatim
63*>          LDA is INTEGER
64*>          The leading dimension of the array A.  LDA >= max(1,N)
65*> \endverbatim
66*>
67*> \param[in] AFAC
68*> \verbatim
69*>          AFAC is REAL array, dimension (LDAFAC,N)
70*>          The factored form of the matrix A.  AFAC contains the block
71*>          diagonal matrix D and the multipliers used to obtain the
72*>          factor L or U from the block L*D*L' or U*D*U' factorization
73*>          as computed by SSYTRF.
74*> \endverbatim
75*>
76*> \param[in] LDAFAC
77*> \verbatim
78*>          LDAFAC is INTEGER
79*>          The leading dimension of the array AFAC.  LDAFAC >= max(1,N).
80*> \endverbatim
81*>
82*> \param[in] IPIV
83*> \verbatim
84*>          IPIV is INTEGER array, dimension (N)
85*>          The pivot indices from SSYTRF.
86*> \endverbatim
87*>
88*> \param[out] C
89*> \verbatim
90*>          C is REAL array, dimension (LDC,N)
91*> \endverbatim
92*>
93*> \param[in] LDC
94*> \verbatim
95*>          LDC is INTEGER
96*>          The leading dimension of the array C.  LDC >= max(1,N).
97*> \endverbatim
98*>
99*> \param[out] RWORK
100*> \verbatim
101*>          RWORK is REAL array, dimension (N)
102*> \endverbatim
103*>
104*> \param[out] RESID
105*> \verbatim
106*>          RESID is REAL
107*>          If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS )
108*>          If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )
109*> \endverbatim
110*
111*  Authors:
112*  ========
113*
114*> \author Univ. of Tennessee
115*> \author Univ. of California Berkeley
116*> \author Univ. of Colorado Denver
117*> \author NAG Ltd.
118*
119*> \date November 2017
120*
121*
122*> \ingroup real_lin
123*
124*  =====================================================================
125      SUBROUTINE SSYT01_AA( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV, C,
126     $                      LDC, RWORK, RESID )
127*
128*  -- LAPACK test routine (version 3.8.0) --
129*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
130*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
131*     November 2017
132*
133*     .. Scalar Arguments ..
134      CHARACTER          UPLO
135      INTEGER            LDA, LDAFAC, LDC, N
136      REAL               RESID
137*     ..
138*     .. Array Arguments ..
139      INTEGER            IPIV( * )
140      REAL               A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * ),
141     $                   RWORK( * )
142*     ..
143*
144*  =====================================================================
145*
146*     .. Parameters ..
147      REAL               ZERO, ONE
148      PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0 )
149*     ..
150*     .. Local Scalars ..
151      INTEGER            I, J
152      REAL               ANORM, EPS
153*     ..
154*     .. External Functions ..
155      LOGICAL            LSAME
156      REAL               SLAMCH, SLANSY
157      EXTERNAL           LSAME, SLAMCH, SLANSY
158*     ..
159*     .. External Subroutines ..
160      EXTERNAL           SLASET, SLAVSY, SSWAP, STRMM, SLACPY
161*     ..
162*     .. Intrinsic Functions ..
163      INTRINSIC          DBLE
164*     ..
165*     .. Executable Statements ..
166*
167*     Quick exit if N = 0.
168*
169      IF( N.LE.0 ) THEN
170         RESID = ZERO
171         RETURN
172      END IF
173*
174*     Determine EPS and the norm of A.
175*
176      EPS = SLAMCH( 'Epsilon' )
177      ANORM = SLANSY( '1', UPLO, N, A, LDA, RWORK )
178*
179*     Initialize C to the tridiagonal matrix T.
180*
181      CALL SLASET( 'Full', N, N, ZERO, ZERO, C, LDC )
182      CALL SLACPY( 'F', 1, N, AFAC( 1, 1 ), LDAFAC+1, C( 1, 1 ), LDC+1 )
183      IF( N.GT.1 ) THEN
184         IF( LSAME( UPLO, 'U' ) ) THEN
185            CALL SLACPY( 'F', 1, N-1, AFAC( 1, 2 ), LDAFAC+1, C( 1, 2 ),
186     $                   LDC+1 )
187            CALL SLACPY( 'F', 1, N-1, AFAC( 1, 2 ), LDAFAC+1, C( 2, 1 ),
188     $                   LDC+1 )
189         ELSE
190            CALL SLACPY( 'F', 1, N-1, AFAC( 2, 1 ), LDAFAC+1, C( 1, 2 ),
191     $                   LDC+1 )
192            CALL SLACPY( 'F', 1, N-1, AFAC( 2, 1 ), LDAFAC+1, C( 2, 1 ),
193     $                   LDC+1 )
194         ENDIF
195*
196*        Call STRMM to form the product U' * D (or L * D ).
197*
198         IF( LSAME( UPLO, 'U' ) ) THEN
199            CALL STRMM( 'Left', UPLO, 'Transpose', 'Unit', N-1, N,
200     $                  ONE, AFAC( 1, 2 ), LDAFAC, C( 2, 1 ), LDC )
201         ELSE
202            CALL STRMM( 'Left', UPLO, 'No transpose', 'Unit', N-1, N,
203     $                  ONE, AFAC( 2, 1 ), LDAFAC, C( 2, 1 ), LDC )
204         END IF
205*
206*        Call STRMM again to multiply by U (or L ).
207*
208         IF( LSAME( UPLO, 'U' ) ) THEN
209            CALL STRMM( 'Right', UPLO, 'No transpose', 'Unit', N, N-1,
210     $                  ONE, AFAC( 1, 2 ), LDAFAC, C( 1, 2 ), LDC )
211         ELSE
212            CALL STRMM( 'Right', UPLO, 'Transpose', 'Unit', N, N-1,
213     $                  ONE, AFAC( 2, 1 ), LDAFAC, C( 1, 2 ), LDC )
214         END IF
215      ENDIF
216*
217*     Apply symmetric pivots
218*
219      DO J = N, 1, -1
220         I = IPIV( J )
221         IF( I.NE.J )
222     $      CALL SSWAP( N, C( J, 1 ), LDC, C( I, 1 ), LDC )
223      END DO
224      DO J = N, 1, -1
225         I = IPIV( J )
226         IF( I.NE.J )
227     $      CALL SSWAP( N, C( 1, J ), 1, C( 1, I ), 1 )
228      END DO
229*
230*
231*     Compute the difference  C - A .
232*
233      IF( LSAME( UPLO, 'U' ) ) THEN
234         DO J = 1, N
235            DO I = 1, J
236               C( I, J ) = C( I, J ) - A( I, J )
237            END DO
238         END DO
239      ELSE
240         DO J = 1, N
241            DO I = J, N
242               C( I, J ) = C( I, J ) - A( I, J )
243            END DO
244         END DO
245      END IF
246*
247*     Compute norm( C - A ) / ( N * norm(A) * EPS )
248*
249      RESID = SLANSY( '1', UPLO, N, C, LDC, RWORK )
250*
251      IF( ANORM.LE.ZERO ) THEN
252         IF( RESID.NE.ZERO )
253     $      RESID = ONE / EPS
254      ELSE
255         RESID = ( ( RESID / DBLE( N ) ) / ANORM ) / EPS
256      END IF
257*
258      RETURN
259*
260*     End of SSYT01_AA
261*
262      END
263