1@echo off
2
3:: Some SVN clients can use localized messages (e.g. SlikSVN), force English
4set LC_ALL=C
5set svn_revision=
6set use_svn_versions=
7set version_cpp=
8
9for /f "tokens=2" %%i in ('svn info ^| find /I "Revision:"') do set svn_revision=%%i
10
11if "%svn_revision%"=="" (
12  for /f %%i in ('git rev-list --count HEAD') do set svn_revision=%%i
13)
14if "%svn_revision%"=="" (
15  set svn_revision=UNKNOWN
16  echo Unknown SVN revision. SVN missing in PATH or not a working copy.
17)
18echo SVN Revision: %svn_revision%
19echo.
20
21echo #define SVN_REVISION "%svn_revision%">src\svn_revision.h
22
23:: Get values of USE_SVN_VERSIONS & VERSION
24for /f "tokens=3" %%j in ('type src\version.cpp ^| find /I "USE_SVN_VERSIONS"') do set use_svn_versions=%%j
25for /f "tokens=3" %%k in ('type src\version.cpp ^| find /I "#define VERSION"') do set version_cpp=%%k
26
27:: Remove quotes
28setlocal enableDelayedExpansion
29for /f "delims=" %%A in ("!use_svn_versions!") do endlocal & set "use_svn_versions=%%~A"
30setlocal enableDelayedExpansion
31for /f "delims=" %%A in ("!version_cpp!") do endlocal & set "version_cpp=%%~A"
32
33:: Verify svn revision & version are actually numbers and version has at least ver_major.ver_minor.ver_build
34if defined use_svn_versions (
35  echo %svn_revision%|findstr /r /c:"^[0-9][0-9]*$" >nul
36  if errorlevel 1 (set use_svn_versions=)
37)
38
39if defined version_cpp (
40  echo %version_cpp%|findstr /r /c:"^[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*$" >nul
41  if errorlevel 1 (set version_cpp=)
42)
43
44if defined version_cpp (
45  if [%use_svn_versions%]==[1] (
46    echo %version_cpp%.%svn_revision%>setup\scripts\pkg_version
47  ) else (
48    echo %version_cpp%>setup\scripts\pkg_version
49  )
50)
51
52set svn_revision=
53set use_svn_versions=
54set version_cpp=
55