1AC_DEFUN([MY_CHECK_LIBPCAP], [
2    libpcap_CFLAGS=""
3    libpcap_LIBS="-lpcap"
4
5    AC_ARG_WITH(
6        [libpcap],
7        AC_HELP_STRING([--with-libpcap=DIR], [libpcap installation path]),
8        [],
9        [withval="yes"]
10    )
11    if test "$withval" = "yes"; then
12        withval="/usr /usr/local"
13    fi
14
15    libpcap_dir=""
16
17    AC_MSG_CHECKING([for libpcap headers])
18    for dir in $withval; do
19        if test -f "$dir/include/pcap.h"; then
20            libpcap_dir="$dir"
21            if test "$dir" != "/usr"; then
22                libpcap_CFLAGS="-I$dir/include"
23            fi
24            break
25        fi
26    done
27    if test -n "$libpcap_dir"; then
28        AC_MSG_RESULT([$libpcap_dir])
29    else
30        AC_MSG_ERROR([cannot find pcap.h in $withval])
31    fi
32
33    save_LDFLAGS="$LDFLAGS"
34    save_LIBS="$LIBS"
35    if test "$libpcap_dir" != "/usr"; then
36        libpcap_LIBS="$libpcap_LIBS -L$libpcap_dir/lib"
37        LDFLAGS="-L$libpcap_dir/lib"
38    fi
39    AC_CHECK_LIB(
40        [pcap],
41        [pcap_open_offline],
42        [],
43        [AC_MSG_ERROR([required library not found])]
44    )
45    AC_SEARCH_LIBS(
46        [pcap_create],
47        [pcap],
48        AC_DEFINE([HAVE_PCAP_CREATE], [1], [Define to 1 if pcap_create() is available.])
49    )
50    LDFLAGS="$save_LDFLAGS"
51    LIBS="$save_LIBS"
52
53    AC_SUBST([libpcap_CFLAGS])
54    AC_SUBST([libpcap_LIBS])
55])
56