1dnl Available from the GNU Autoconf Macro Archive at:
2dnl http://www.gnu.org/software/ac-archive/htmldoc/ax_check_glu.html
3dnl
4AC_DEFUN([AX_CHECK_GLU],
5[AC_REQUIRE([AX_CHECK_GL])dnl
6AC_REQUIRE([AC_PROG_CXX])dnl
7GLU_CFLAGS="${GL_CFLAGS}"
8if test "X${with_apple_opengl_framework}" != "Xyes"; then
9  AC_CACHE_CHECK([for OpenGL Utility library], [ax_cv_check_glu_libglu],
10  [ax_cv_check_glu_libglu="no"
11  ax_save_CPPFLAGS="${CPPFLAGS}"
12  CPPFLAGS="${GL_CFLAGS} ${CPPFLAGS}"
13  ax_save_LIBS="${LIBS}"
14  LIBS=""
15  ax_check_libs="-lglu32 -lGLU"
16  for ax_lib in ${ax_check_libs}; do
17    if test X$ax_compiler_ms = Xyes; then
18      ax_try_lib=`echo $ax_lib | sed -e 's/^-l//' -e 's/$/.lib/'`
19    else
20      ax_try_lib="${ax_lib}"
21    fi
22    LIBS="-L${prefix}/lib ${ax_try_lib} ${GL_LIBS} ${ax_save_LIBS}"
23    #
24    # libGLU typically links with libstdc++ on POSIX platforms. However,
25    # setting the language to C++ means that test program source is named
26    # "conftest.cc"; and Microsoft cl doesn't know what to do with such a
27    # file.
28    #
29    AC_LANG_PUSH([C++])
30    if test X$ax_compiler_ms = Xyes; then
31      AC_LANG_PUSH([C])
32    fi
33    AC_LINK_IFELSE(
34    [AC_LANG_PROGRAM([[
35# if HAVE_WINDOWS_H && defined(_WIN32)
36#   include <windows.h>
37# endif
38# include <GL/glu.h>]],
39                     [[gluBeginCurve(0)]])],
40    [ax_cv_check_glu_libglu="-L${prefix}/lib ${ax_try_lib}"; break])
41    if test X$ax_compiler_ms = Xyes; then
42      AC_LANG_POP([C])
43    fi
44    AC_LANG_POP([C++])
45  done
46  LIBS=${ax_save_LIBS}
47  CPPFLAGS=${ax_save_CPPFLAGS}])
48  if test "X${ax_cv_check_glu_libglu}" = "Xno"; then
49    no_glu="yes"
50    GLU_CFLAGS=""
51    GLU_LIBS=""
52  else
53    GLU_LIBS="${ax_cv_check_glu_libglu} ${GL_LIBS}"
54  fi
55fi
56AC_SUBST([GLU_CFLAGS])
57AC_SUBST([GLU_LIBS])
58])
59