1<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
2                xmlns:xslo="http://www.w3.org/1999/XSL/TransformAlias"
3                version="1.0">
4
5<xsl:output indent="no" method="xml"/>
6
7<xsl:namespace-alias stylesheet-prefix="xslo" result-prefix="xsl"/>
8
9<xsl:template match="node()|@*">
10    <xsl:copy>
11      <xsl:apply-templates select="@*"/>
12      <xsl:apply-templates/>
13   </xsl:copy>
14</xsl:template>
15
16<xsl:template match="xsl:output">
17  <xsl:comment>Same as xhtml but with doctypes removed from xsl:output </xsl:comment>
18  <xsl:text>&#10;</xsl:text>
19  <xsl:comment>and including from ../xhtml directory </xsl:comment>
20  <xsl:text>&#10;</xsl:text>
21  <xslo:output method="xml" encoding="UTF-8" indent="no"/>
22</xsl:template>
23
24<xsl:template match="xsl:include/@href">
25  <xsl:choose>
26    <xsl:when test="starts-with(., '../')">
27      <xsl:copy-of select="."/>
28    </xsl:when>
29    <xsl:otherwise>
30      <xsl:attribute name="href">
31        <xsl:value-of select="concat('../xhtml/', .)"/>
32      </xsl:attribute>
33    </xsl:otherwise>
34  </xsl:choose>
35</xsl:template>
36
37<xsl:template match="comment()
38             [starts-with(string(.), 'This file was created automatically')]">
39  <xsl:text>&#10;</xsl:text>
40  <xsl:comment>This file was created automatically by xhtml2xhtml5.xsl from the xhtml stylesheet.</xsl:comment>
41  <xsl:text>&#10;</xsl:text>
42</xsl:template>
43
44<xsl:template match="comment()
45             [starts-with(string(.), 'from the HTML stylesheets')]"/>
46
47<xsl:include href="../common/subtitles.xsl"/>
48</xsl:stylesheet>
49
50