1install_data(
2  'gnome-session-custom-session',
3  install_dir: session_bindir
4)
5
6deps = session_deps + [
7  sm_dep,
8  ice_dep
9]
10
11cflags = ['-DLOCALE_DIR="@0@"'.format(session_localedir)]
12
13programs = [
14  # name, deps, cflags, install_dir
15  ['gnome-session-quit', deps, cflags, session_bindir],
16  ['gnome-session-inhibit', session_deps, cflags, session_bindir]
17]
18
19if enable_systemd_session
20  programs += [['gnome-session-ctl', session_bin_deps, cflags, session_libexecdir]]
21endif
22
23if enable_session_selector
24  deps = [
25    glib_dep,
26    gtk_dep
27  ]
28
29  cflags += '-DGTKBUILDER_DIR="@0@"'.format(session_pkgdatadir)
30
31  programs += [['gnome-session-selector', deps, cflags, session_bindir]]
32endif
33
34deps = [
35  gtk_dep,
36  x11_dep,
37  dependency('egl'),
38  dependency('glesv2')
39]
40
41cflags = '-DPKGDATADIR="@0@"'.format(session_pkgdatadir)
42
43programs += [['gnome-session-check-accelerated-gles-helper', deps, cflags, session_libexecdir]]
44
45deps = [
46  glib_dep,
47  x11_dep,
48  dependency('gl'),
49  dependency('epoxy'),
50  dependency('xcomposite')
51]
52
53programs += [['gnome-session-check-accelerated-gl-helper', deps, cflags, session_libexecdir]]
54
55deps += [gtk_dep]
56
57cflags = '-DLIBEXECDIR="@0@"'.format(session_libexecdir)
58
59programs += [['gnome-session-check-accelerated', deps, cflags, session_libexecdir]]
60
61foreach program: programs
62  executable(
63    program[0],
64    program[0] + '.c',
65    include_directories: top_inc,
66    dependencies: program[1],
67    c_args: program[2],
68    install: true,
69    install_dir: program[3]
70  )
71endforeach
72