1project('gnome-extensions-tool', 'c',
2  version: '41.1',
3  meson_version: '>= 0.53.0',
4  license: 'GPLv2+'
5)
6
7gio_req = '>= 2.56.0'
8
9fs = import('fs')
10gnome = import('gnome')
11i18n  = import('i18n')
12
13if meson.is_subproject()
14  package_name = get_option('package_name')
15  assert(package_name != '',
16    'package_name must be specified for subproject builds')
17else
18  package_name = meson.project_name()
19endif
20
21package_version = meson.project_version()
22prefix = get_option('prefix')
23
24bindir = join_paths(prefix, get_option('bindir'))
25datadir = join_paths(prefix, get_option('datadir'))
26mandir = join_paths(prefix, get_option('mandir'))
27
28localedir = join_paths(datadir, 'locale')
29
30gio_dep = dependency('gio-2.0', version: gio_req)
31gio_unix_dep = dependency('gio-unix-2.0', version: gio_req)
32autoar_dep = dependency('gnome-autoar-0')
33json_dep = dependency('json-glib-1.0')
34
35cc = meson.get_compiler('c')
36
37bash_completion = dependency('bash-completion', required: get_option('bash_completion'))
38
39po_dir = meson.source_root() + '/po'
40
41subdir('src')
42
43if bash_completion.found()
44  install_data('completion/bash/gnome-extensions',
45    install_dir: bash_completion.get_pkgconfig_variable('completionsdir', define_variable: ['datadir', datadir])
46  )
47endif
48
49if get_option('man')
50  if fs.exists('man/gnome-extensions.1')
51    install_man('man/gnome-extensions.1')
52  else
53    a2x = find_program('a2x')
54    subdir('man')
55  endif
56endif
57
58if not meson.is_subproject()
59  subdir('po')
60
61  summary_dirs = {
62    'prefix': get_option('prefix'),
63    'bindir': get_option('bindir'),
64    'datadir': get_option('datadir'),
65  }
66
67  if get_option('man')
68    summary_dirs += { 'mandir': get_option('mandir') }
69  endif
70
71  summary_build = {
72    'buildtype': get_option('buildtype'),
73    'debug': get_option('debug'),
74  }
75
76  summary_options = {
77    'man': get_option('man'),
78    'bash_completion': bash_completion.found(),
79  }
80
81  summary(summary_dirs, section: 'Directories')
82  summary(summary_build, section: 'Build Configuration')
83  summary(summary_options, section: 'Build Options')
84endif
85