xref: /freebsd/contrib/kyua/admin/check-style-cpp.awk (revision b0d29bc4)

# Copyright 2015 The Kyua Authors.
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are
# met:
#
# * Redistributions of source code must retain the above copyright
#   notice, this list of conditions and the following disclaimer.
# * Redistributions in binary form must reproduce the above copyright
#   notice, this list of conditions and the following disclaimer in the
#   documentation and/or other materials provided with the distribution.
# * Neither the name of Google Inc. nor the names of its contributors
#   may be used to endorse or promote products derived from this software
#   without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

function warn(msg) {
    print FILENAME "[" FNR "]: " msg > "/dev/stderr"
    error = 1
}

BEGIN {
    skip = 0
    error = 0
}

/CHECK_STYLE_DISABLE/ {
    skip = 1
    next
}

/CHECK_STYLE_ENABLE/ {
    skip = 0
    next
}

/CHECK_STYLE_(ENABLE|DISABLE)/ {
    next
}

{
    if (skip)
        next
}

/#ifdef/ {
    warn("Undesired usage of #ifdef; use #if defined()")
}

/#ifndef/ {
    warn("Undesired usage of #ifndef; use #if !defined()")
}

/assert[ \t]*\(/ {
    warn("Use the macros in sanity.hpp instead of assert");
}

/#.*include.*assert/ {
    warn("Do not include assert.h nor cassert");
}

/std::endl/ {
    warn("Use \\n instead of std::endl");
}

/\/\*/ && ! /\*\// {
    warn("Do not use multi-line C-style comments");
}

END {
    if (skip)
        warn("Missing CHECK_STYLE_ENABLE");
    if (error)
        exit 1
}