xref: /freebsd/sys/contrib/openzfs/config/kernel.m4 (revision 61e21613) 
1dnl #
2dnl # Default ZFS kernel configuration
3dnl #
4AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
5	AM_COND_IF([BUILD_LINUX], [
6		dnl # Setup the kernel build environment.
7		ZFS_AC_KERNEL
8		ZFS_AC_QAT
9
10		dnl # Sanity checks for module building and CONFIG_* defines
11		ZFS_AC_KERNEL_CONFIG_DEFINED
12		ZFS_AC_MODULE_SYMVERS
13
14		dnl # Sequential ZFS_LINUX_TRY_COMPILE tests
15		ZFS_AC_KERNEL_FPU_HEADER
16		ZFS_AC_KERNEL_OBJTOOL_HEADER
17		ZFS_AC_KERNEL_WAIT_QUEUE_ENTRY_T
18		ZFS_AC_KERNEL_MISC_MINOR
19		ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
20
21		dnl # Parallel ZFS_LINUX_TEST_SRC / ZFS_LINUX_TEST_RESULT tests
22		ZFS_AC_KERNEL_TEST_SRC
23		ZFS_AC_KERNEL_TEST_RESULT
24
25		AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
26			KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
27		])
28
29		AC_SUBST(KERNEL_MAKE)
30	])
31])
32
33dnl #
34dnl # Generate and compile all of the kernel API test cases to determine
35dnl # which interfaces are available.  By invoking the kernel build system
36dnl # only once the compilation can be done in parallel significantly
37dnl # speeding up the process.
38dnl #
39AC_DEFUN([ZFS_AC_KERNEL_TEST_SRC], [
40	ZFS_AC_KERNEL_SRC_OBJTOOL
41	ZFS_AC_KERNEL_SRC_GLOBAL_PAGE_STATE
42	ZFS_AC_KERNEL_SRC_ACCESS_OK_TYPE
43	ZFS_AC_KERNEL_SRC_PDE_DATA
44	ZFS_AC_KERNEL_SRC_FALLOCATE
45	ZFS_AC_KERNEL_SRC_FADVISE
46	ZFS_AC_KERNEL_SRC_GENERIC_FADVISE
47	ZFS_AC_KERNEL_SRC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
48	ZFS_AC_KERNEL_SRC_RWSEM
49	ZFS_AC_KERNEL_SRC_SCHED
50	ZFS_AC_KERNEL_SRC_USLEEP_RANGE
51	ZFS_AC_KERNEL_SRC_KMEM_CACHE
52	ZFS_AC_KERNEL_SRC_KVMALLOC
53	ZFS_AC_KERNEL_SRC_VMALLOC_PAGE_KERNEL
54	ZFS_AC_KERNEL_SRC_WAIT
55	ZFS_AC_KERNEL_SRC_INODE_TIMES
56	ZFS_AC_KERNEL_SRC_INODE_LOCK
57	ZFS_AC_KERNEL_SRC_GROUP_INFO_GID
58	ZFS_AC_KERNEL_SRC_RW
59	ZFS_AC_KERNEL_SRC_TIMER_SETUP
60	ZFS_AC_KERNEL_SRC_SUPER_USER_NS
61	ZFS_AC_KERNEL_SRC_PROC_OPERATIONS
62	ZFS_AC_KERNEL_SRC_BLOCK_DEVICE_OPERATIONS
63	ZFS_AC_KERNEL_SRC_BIO
64	ZFS_AC_KERNEL_SRC_BLKDEV
65	ZFS_AC_KERNEL_SRC_BLK_QUEUE
66	ZFS_AC_KERNEL_SRC_GENHD_FLAGS
67	ZFS_AC_KERNEL_SRC_REVALIDATE_DISK
68	ZFS_AC_KERNEL_SRC_GET_DISK_RO
69	ZFS_AC_KERNEL_SRC_GENERIC_READLINK_GLOBAL
70	ZFS_AC_KERNEL_SRC_DISCARD_GRANULARITY
71	ZFS_AC_KERNEL_SRC_INODE_OWNER_OR_CAPABLE
72	ZFS_AC_KERNEL_SRC_XATTR
73	ZFS_AC_KERNEL_SRC_ACL
74	ZFS_AC_KERNEL_SRC_INODE_SETATTR
75	ZFS_AC_KERNEL_SRC_INODE_GETATTR
76	ZFS_AC_KERNEL_SRC_INODE_SET_FLAGS
77	ZFS_AC_KERNEL_SRC_INODE_SET_IVERSION
78	ZFS_AC_KERNEL_SRC_SHOW_OPTIONS
79	ZFS_AC_KERNEL_SRC_FILE_INODE
80	ZFS_AC_KERNEL_SRC_FILE_DENTRY
81	ZFS_AC_KERNEL_SRC_FSYNC
82	ZFS_AC_KERNEL_SRC_AIO_FSYNC
83	ZFS_AC_KERNEL_SRC_EVICT_INODE
84	ZFS_AC_KERNEL_SRC_DIRTY_INODE
85	ZFS_AC_KERNEL_SRC_SHRINKER
86	ZFS_AC_KERNEL_SRC_MKDIR
87	ZFS_AC_KERNEL_SRC_LOOKUP_FLAGS
88	ZFS_AC_KERNEL_SRC_CREATE
89	ZFS_AC_KERNEL_SRC_PERMISSION
90	ZFS_AC_KERNEL_SRC_GET_LINK
91	ZFS_AC_KERNEL_SRC_PUT_LINK
92	ZFS_AC_KERNEL_SRC_TMPFILE
93	ZFS_AC_KERNEL_SRC_AUTOMOUNT
94	ZFS_AC_KERNEL_SRC_ENCODE_FH_WITH_INODE
95	ZFS_AC_KERNEL_SRC_COMMIT_METADATA
96	ZFS_AC_KERNEL_SRC_CLEAR_INODE
97	ZFS_AC_KERNEL_SRC_SETATTR_PREPARE
98	ZFS_AC_KERNEL_SRC_INSERT_INODE_LOCKED
99	ZFS_AC_KERNEL_SRC_DENTRY
100	ZFS_AC_KERNEL_SRC_DENTRY_ALIAS_D_U
101	ZFS_AC_KERNEL_SRC_TRUNCATE_SETSIZE
102	ZFS_AC_KERNEL_SRC_SECURITY_INODE
103	ZFS_AC_KERNEL_SRC_FST_MOUNT
104	ZFS_AC_KERNEL_SRC_BDI
105	ZFS_AC_KERNEL_SRC_SET_NLINK
106	ZFS_AC_KERNEL_SRC_SGET
107	ZFS_AC_KERNEL_SRC_LSEEK_EXECUTE
108	ZFS_AC_KERNEL_SRC_VFS_FILEMAP_DIRTY_FOLIO
109	ZFS_AC_KERNEL_SRC_VFS_READ_FOLIO
110	ZFS_AC_KERNEL_SRC_VFS_GETATTR
111	ZFS_AC_KERNEL_SRC_VFS_FSYNC_2ARGS
112	ZFS_AC_KERNEL_SRC_VFS_ITERATE
113	ZFS_AC_KERNEL_SRC_VFS_DIRECT_IO
114	ZFS_AC_KERNEL_SRC_VFS_READPAGES
115	ZFS_AC_KERNEL_SRC_VFS_SET_PAGE_DIRTY_NOBUFFERS
116	ZFS_AC_KERNEL_SRC_VFS_RW_ITERATE
117	ZFS_AC_KERNEL_SRC_VFS_GENERIC_WRITE_CHECKS
118	ZFS_AC_KERNEL_SRC_VFS_IOV_ITER
119	ZFS_AC_KERNEL_SRC_VFS_COPY_FILE_RANGE
120	ZFS_AC_KERNEL_SRC_VFS_GENERIC_COPY_FILE_RANGE
121	ZFS_AC_KERNEL_SRC_VFS_REMAP_FILE_RANGE
122	ZFS_AC_KERNEL_SRC_VFS_CLONE_FILE_RANGE
123	ZFS_AC_KERNEL_SRC_VFS_DEDUPE_FILE_RANGE
124	ZFS_AC_KERNEL_SRC_VFS_FILE_OPERATIONS_EXTEND
125	ZFS_AC_KERNEL_SRC_KMAP_ATOMIC_ARGS
126	ZFS_AC_KERNEL_SRC_FOLLOW_DOWN_ONE
127	ZFS_AC_KERNEL_SRC_MAKE_REQUEST_FN
128	ZFS_AC_KERNEL_SRC_GENERIC_IO_ACCT
129	ZFS_AC_KERNEL_SRC_FPU
130	ZFS_AC_KERNEL_SRC_FMODE_T
131	ZFS_AC_KERNEL_SRC_KUIDGID_T
132	ZFS_AC_KERNEL_SRC_KUID_HELPERS
133	ZFS_AC_KERNEL_SRC_RENAME
134	ZFS_AC_KERNEL_SRC_CURRENT_TIME
135	ZFS_AC_KERNEL_SRC_USERNS_CAPABILITIES
136	ZFS_AC_KERNEL_SRC_IN_COMPAT_SYSCALL
137	ZFS_AC_KERNEL_SRC_KTIME
138	ZFS_AC_KERNEL_SRC_TOTALRAM_PAGES_FUNC
139	ZFS_AC_KERNEL_SRC_TOTALHIGH_PAGES
140	ZFS_AC_KERNEL_SRC_KSTRTOUL
141	ZFS_AC_KERNEL_SRC_PERCPU
142	ZFS_AC_KERNEL_SRC_CPU_HOTPLUG
143	ZFS_AC_KERNEL_SRC_GENERIC_FILLATTR
144	ZFS_AC_KERNEL_SRC_MKNOD
145	ZFS_AC_KERNEL_SRC_SYMLINK
146	ZFS_AC_KERNEL_SRC_BIO_MAX_SEGS
147	ZFS_AC_KERNEL_SRC_SIGNAL_STOP
148	ZFS_AC_KERNEL_SRC_SIGINFO
149	ZFS_AC_KERNEL_SRC_SYSFS
150	ZFS_AC_KERNEL_SRC_SET_SPECIAL_STATE
151	ZFS_AC_KERNEL_SRC_STANDALONE_LINUX_STDARG
152	ZFS_AC_KERNEL_SRC_PAGEMAP_FOLIO_WAIT_BIT
153	ZFS_AC_KERNEL_SRC_ADD_DISK
154	ZFS_AC_KERNEL_SRC_KTHREAD
155	ZFS_AC_KERNEL_SRC_ZERO_PAGE
156	ZFS_AC_KERNEL_SRC___COPY_FROM_USER_INATOMIC
157	ZFS_AC_KERNEL_SRC_USER_NS_COMMON_INUM
158	ZFS_AC_KERNEL_SRC_IDMAP_MNT_API
159	ZFS_AC_KERNEL_SRC_IATTR_VFSID
160	ZFS_AC_KERNEL_SRC_FILEMAP
161	ZFS_AC_KERNEL_SRC_WRITEPAGE_T
162	ZFS_AC_KERNEL_SRC_RECLAIMED
163	ZFS_AC_KERNEL_SRC_REGISTER_SYSCTL_TABLE
164	ZFS_AC_KERNEL_SRC_COPY_SPLICE_READ
165	ZFS_AC_KERNEL_SRC_SYNC_BDEV
166	case "$host_cpu" in
167		powerpc*)
168			ZFS_AC_KERNEL_SRC_CPU_HAS_FEATURE
169			ZFS_AC_KERNEL_SRC_FLUSH_DCACHE_PAGE
170			;;
171		riscv*)
172			ZFS_AC_KERNEL_SRC_FLUSH_DCACHE_PAGE
173			;;
174	esac
175
176	AC_MSG_CHECKING([for available kernel interfaces])
177	ZFS_LINUX_TEST_COMPILE_ALL([kabi])
178	AC_MSG_RESULT([done])
179])
180
181dnl #
182dnl # Check results of kernel interface tests.
183dnl #
184AC_DEFUN([ZFS_AC_KERNEL_TEST_RESULT], [
185	ZFS_AC_KERNEL_ACCESS_OK_TYPE
186	ZFS_AC_KERNEL_GLOBAL_PAGE_STATE
187	ZFS_AC_KERNEL_OBJTOOL
188	ZFS_AC_KERNEL_PDE_DATA
189	ZFS_AC_KERNEL_FALLOCATE
190	ZFS_AC_KERNEL_FADVISE
191	ZFS_AC_KERNEL_GENERIC_FADVISE
192	ZFS_AC_KERNEL_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
193	ZFS_AC_KERNEL_RWSEM
194	ZFS_AC_KERNEL_SCHED
195	ZFS_AC_KERNEL_USLEEP_RANGE
196	ZFS_AC_KERNEL_KMEM_CACHE
197	ZFS_AC_KERNEL_KVMALLOC
198	ZFS_AC_KERNEL_VMALLOC_PAGE_KERNEL
199	ZFS_AC_KERNEL_WAIT
200	ZFS_AC_KERNEL_INODE_TIMES
201	ZFS_AC_KERNEL_INODE_LOCK
202	ZFS_AC_KERNEL_GROUP_INFO_GID
203	ZFS_AC_KERNEL_RW
204	ZFS_AC_KERNEL_TIMER_SETUP
205	ZFS_AC_KERNEL_SUPER_USER_NS
206	ZFS_AC_KERNEL_PROC_OPERATIONS
207	ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS
208	ZFS_AC_KERNEL_BIO
209	ZFS_AC_KERNEL_BLKDEV
210	ZFS_AC_KERNEL_BLK_QUEUE
211	ZFS_AC_KERNEL_GENHD_FLAGS
212	ZFS_AC_KERNEL_REVALIDATE_DISK
213	ZFS_AC_KERNEL_GET_DISK_RO
214	ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
215	ZFS_AC_KERNEL_DISCARD_GRANULARITY
216	ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
217	ZFS_AC_KERNEL_XATTR
218	ZFS_AC_KERNEL_ACL
219	ZFS_AC_KERNEL_INODE_SETATTR
220	ZFS_AC_KERNEL_INODE_GETATTR
221	ZFS_AC_KERNEL_INODE_SET_FLAGS
222	ZFS_AC_KERNEL_INODE_SET_IVERSION
223	ZFS_AC_KERNEL_SHOW_OPTIONS
224	ZFS_AC_KERNEL_FILE_INODE
225	ZFS_AC_KERNEL_FILE_DENTRY
226	ZFS_AC_KERNEL_FSYNC
227	ZFS_AC_KERNEL_AIO_FSYNC
228	ZFS_AC_KERNEL_EVICT_INODE
229	ZFS_AC_KERNEL_DIRTY_INODE
230	ZFS_AC_KERNEL_SHRINKER
231	ZFS_AC_KERNEL_MKDIR
232	ZFS_AC_KERNEL_LOOKUP_FLAGS
233	ZFS_AC_KERNEL_CREATE
234	ZFS_AC_KERNEL_PERMISSION
235	ZFS_AC_KERNEL_GET_LINK
236	ZFS_AC_KERNEL_PUT_LINK
237	ZFS_AC_KERNEL_TMPFILE
238	ZFS_AC_KERNEL_AUTOMOUNT
239	ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
240	ZFS_AC_KERNEL_COMMIT_METADATA
241	ZFS_AC_KERNEL_CLEAR_INODE
242	ZFS_AC_KERNEL_SETATTR_PREPARE
243	ZFS_AC_KERNEL_INSERT_INODE_LOCKED
244	ZFS_AC_KERNEL_DENTRY
245	ZFS_AC_KERNEL_DENTRY_ALIAS_D_U
246	ZFS_AC_KERNEL_TRUNCATE_SETSIZE
247	ZFS_AC_KERNEL_SECURITY_INODE
248	ZFS_AC_KERNEL_FST_MOUNT
249	ZFS_AC_KERNEL_BDI
250	ZFS_AC_KERNEL_SET_NLINK
251	ZFS_AC_KERNEL_SGET
252	ZFS_AC_KERNEL_LSEEK_EXECUTE
253	ZFS_AC_KERNEL_VFS_FILEMAP_DIRTY_FOLIO
254	ZFS_AC_KERNEL_VFS_READ_FOLIO
255	ZFS_AC_KERNEL_VFS_GETATTR
256	ZFS_AC_KERNEL_VFS_FSYNC_2ARGS
257	ZFS_AC_KERNEL_VFS_ITERATE
258	ZFS_AC_KERNEL_VFS_DIRECT_IO
259	ZFS_AC_KERNEL_VFS_READPAGES
260	ZFS_AC_KERNEL_VFS_SET_PAGE_DIRTY_NOBUFFERS
261	ZFS_AC_KERNEL_VFS_RW_ITERATE
262	ZFS_AC_KERNEL_VFS_GENERIC_WRITE_CHECKS
263	ZFS_AC_KERNEL_VFS_IOV_ITER
264	ZFS_AC_KERNEL_VFS_COPY_FILE_RANGE
265	ZFS_AC_KERNEL_VFS_GENERIC_COPY_FILE_RANGE
266	ZFS_AC_KERNEL_VFS_REMAP_FILE_RANGE
267	ZFS_AC_KERNEL_VFS_CLONE_FILE_RANGE
268	ZFS_AC_KERNEL_VFS_DEDUPE_FILE_RANGE
269	ZFS_AC_KERNEL_VFS_FILE_OPERATIONS_EXTEND
270	ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
271	ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
272	ZFS_AC_KERNEL_MAKE_REQUEST_FN
273	ZFS_AC_KERNEL_GENERIC_IO_ACCT
274	ZFS_AC_KERNEL_FPU
275	ZFS_AC_KERNEL_FMODE_T
276	ZFS_AC_KERNEL_KUIDGID_T
277	ZFS_AC_KERNEL_KUID_HELPERS
278	ZFS_AC_KERNEL_RENAME
279	ZFS_AC_KERNEL_CURRENT_TIME
280	ZFS_AC_KERNEL_USERNS_CAPABILITIES
281	ZFS_AC_KERNEL_IN_COMPAT_SYSCALL
282	ZFS_AC_KERNEL_KTIME
283	ZFS_AC_KERNEL_TOTALRAM_PAGES_FUNC
284	ZFS_AC_KERNEL_TOTALHIGH_PAGES
285	ZFS_AC_KERNEL_KSTRTOUL
286	ZFS_AC_KERNEL_PERCPU
287	ZFS_AC_KERNEL_CPU_HOTPLUG
288	ZFS_AC_KERNEL_GENERIC_FILLATTR
289	ZFS_AC_KERNEL_MKNOD
290	ZFS_AC_KERNEL_SYMLINK
291	ZFS_AC_KERNEL_BIO_MAX_SEGS
292	ZFS_AC_KERNEL_SIGNAL_STOP
293	ZFS_AC_KERNEL_SIGINFO
294	ZFS_AC_KERNEL_SYSFS
295	ZFS_AC_KERNEL_SET_SPECIAL_STATE
296	ZFS_AC_KERNEL_STANDALONE_LINUX_STDARG
297	ZFS_AC_KERNEL_PAGEMAP_FOLIO_WAIT_BIT
298	ZFS_AC_KERNEL_ADD_DISK
299	ZFS_AC_KERNEL_KTHREAD
300	ZFS_AC_KERNEL_ZERO_PAGE
301	ZFS_AC_KERNEL___COPY_FROM_USER_INATOMIC
302	ZFS_AC_KERNEL_USER_NS_COMMON_INUM
303	ZFS_AC_KERNEL_IDMAP_MNT_API
304	ZFS_AC_KERNEL_IATTR_VFSID
305	ZFS_AC_KERNEL_FILEMAP
306	ZFS_AC_KERNEL_WRITEPAGE_T
307	ZFS_AC_KERNEL_RECLAIMED
308	ZFS_AC_KERNEL_REGISTER_SYSCTL_TABLE
309	ZFS_AC_KERNEL_COPY_SPLICE_READ
310	ZFS_AC_KERNEL_SYNC_BDEV
311	case "$host_cpu" in
312		powerpc*)
313			ZFS_AC_KERNEL_CPU_HAS_FEATURE
314			ZFS_AC_KERNEL_FLUSH_DCACHE_PAGE
315			;;
316		riscv*)
317			ZFS_AC_KERNEL_FLUSH_DCACHE_PAGE
318			;;
319	esac
320])
321
322dnl #
323dnl # Detect name used for Module.symvers file in kernel
324dnl #
325AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
326	modpost=$LINUX/scripts/Makefile.modpost
327	AC_MSG_CHECKING([kernel file name for module symbols])
328	AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
329		AS_IF([grep -q Modules.symvers $modpost], [
330			LINUX_SYMBOLS=Modules.symvers
331		], [
332			LINUX_SYMBOLS=Module.symvers
333		])
334
335		AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
336			AC_MSG_ERROR([
337	*** Please make sure the kernel devel package for your distribution
338	*** is installed.  If you are building with a custom kernel, make sure
339	*** the kernel is configured, built, and the '--with-linux=PATH'
340	*** configure option refers to the location of the kernel source.
341			])
342		])
343	], [
344		LINUX_SYMBOLS=NONE
345	])
346	AC_MSG_RESULT($LINUX_SYMBOLS)
347	AC_SUBST(LINUX_SYMBOLS)
348])
349
350dnl #
351dnl # Detect the kernel to be built against
352dnl #
353dnl # Most modern Linux distributions have separate locations for bare
354dnl # source (source) and prebuilt (build) files. Additionally, there are
355dnl # `source` and `build` symlinks in `/lib/modules/$(KERNEL_VERSION)`
356dnl # pointing to them. The directory search order is now:
357dnl #
358dnl # - `configure` command line values if both `--with-linux` and
359dnl #   `--with-linux-obj` were defined
360dnl #
361dnl # - If only `--with-linux` was defined, `--with-linux-obj` is assumed
362dnl #   to have the same value as `--with-linux`
363dnl #
364dnl # - If neither `--with-linux` nor `--with-linux-obj` were defined
365dnl #   autodetection is used:
366dnl #
367dnl #   - `/lib/modules/$(uname -r)/{source,build}` respectively, if exist.
368dnl #
369dnl #   - If only `/lib/modules/$(uname -r)/build` exists, it is assumed
370dnl #     to be both source and build directory.
371dnl #
372dnl #   - The first directory in `/lib/modules` with the highest version
373dnl #     number according to `sort -V` which contains both `source` and
374dnl #     `build` symlinks/directories. If module directory contains only
375dnl #     `build` component, it is assumed to be both source and build
376dnl #     directory.
377dnl #
378dnl #   - Last resort: the first directory matching `/usr/src/kernels/*`
379dnl #     and `/usr/src/linux-*` with the highest version number according
380dnl #     to `sort -V` is assumed to be both source and build directory.
381dnl #
382AC_DEFUN([ZFS_AC_KERNEL], [
383	AC_ARG_WITH([linux],
384		AS_HELP_STRING([--with-linux=PATH],
385		[Path to kernel source]),
386		[kernelsrc="$withval"])
387
388	AC_ARG_WITH(linux-obj,
389		AS_HELP_STRING([--with-linux-obj=PATH],
390		[Path to kernel build objects]),
391		[kernelbuild="$withval"])
392
393	AC_MSG_CHECKING([kernel source and build directories])
394	AS_IF([test -n "$kernelsrc" && test -z "$kernelbuild"], [
395		kernelbuild="$kernelsrc"
396	], [test -z "$kernelsrc"], [
397		AS_IF([test -e "/lib/modules/$(uname -r)/source" && \
398		       test -e "/lib/modules/$(uname -r)/build"], [
399			src="/lib/modules/$(uname -r)/source"
400			build="/lib/modules/$(uname -r)/build"
401		], [test -e "/lib/modules/$(uname -r)/build"], [
402			build="/lib/modules/$(uname -r)/build"
403			src="$build"
404		], [
405			src=
406
407			for d in $(ls -1d /lib/modules/* 2>/dev/null | sort -Vr); do
408				if test -e "$d/source" && test -e "$d/build"; then
409					src="$d/source"
410					build="$d/build"
411					break
412				fi
413
414				if test -e "$d/build"; then
415					src="$d/build"
416					build="$d/build"
417					break
418				fi
419			done
420
421			# the least reliable method
422			if test -z "$src"; then
423				src=$(ls -1d /usr/src/kernels/* /usr/src/linux-* \
424				      2>/dev/null | grep -v obj | sort -Vr | head -1)
425				build="$src"
426			fi
427		])
428
429		AS_IF([test -n "$src" && test -e "$src"], [
430			kernelsrc=$(readlink -e "$src")
431		], [
432			kernelsrc="[Not found]"
433		])
434		AS_IF([test -n "$build" && test -e "$build"], [
435			kernelbuild=$(readlink -e "$build")
436		], [
437			kernelbuild="[Not found]"
438		])
439	], [
440		AS_IF([test "$kernelsrc" = "NONE"], [
441			kernsrcver=NONE
442		])
443		withlinux=yes
444	])
445
446	AC_MSG_RESULT([done])
447	AC_MSG_CHECKING([kernel source directory])
448	AC_MSG_RESULT([$kernelsrc])
449	AC_MSG_CHECKING([kernel build directory])
450	AC_MSG_RESULT([$kernelbuild])
451	AS_IF([test ! -d "$kernelsrc" || test ! -d "$kernelbuild"], [
452		AC_MSG_ERROR([
453	*** Please make sure the kernel devel package for your distribution
454	*** is installed and then try again.  If that fails, you can specify the
455	*** location of the kernel source and build with the '--with-linux=PATH' and
456	*** '--with-linux-obj=PATH' options respectively.])
457	])
458
459	AC_MSG_CHECKING([kernel source version])
460	utsrelease1=$kernelbuild/include/linux/version.h
461	utsrelease2=$kernelbuild/include/linux/utsrelease.h
462	utsrelease3=$kernelbuild/include/generated/utsrelease.h
463	AS_IF([test -r $utsrelease1 && grep -qF UTS_RELEASE $utsrelease1], [
464		utsrelease=$utsrelease1
465	], [test -r $utsrelease2 && grep -qF UTS_RELEASE $utsrelease2], [
466		utsrelease=$utsrelease2
467	], [test -r $utsrelease3 && grep -qF UTS_RELEASE $utsrelease3], [
468		utsrelease=$utsrelease3
469	])
470
471	AS_IF([test -n "$utsrelease"], [
472		kernsrcver=$($AWK '/UTS_RELEASE/ { gsub(/"/, "", $[3]); print $[3] }' $utsrelease)
473		AS_IF([test -z "$kernsrcver"], [
474			AC_MSG_RESULT([Not found])
475			AC_MSG_ERROR([
476	*** Cannot determine kernel version.
477			])
478		])
479	], [
480		AC_MSG_RESULT([Not found])
481		if test "x$enable_linux_builtin" != xyes; then
482			AC_MSG_ERROR([
483	*** Cannot find UTS_RELEASE definition.
484			])
485		else
486			AC_MSG_ERROR([
487	*** Cannot find UTS_RELEASE definition.
488	*** Please run 'make prepare' inside the kernel source tree.])
489		fi
490	])
491
492	AC_MSG_RESULT([$kernsrcver])
493
494	AS_VERSION_COMPARE([$kernsrcver], [$ZFS_META_KVER_MIN], [
495		 AC_MSG_ERROR([
496	*** Cannot build against kernel version $kernsrcver.
497	*** The minimum supported kernel version is $ZFS_META_KVER_MIN.
498		])
499	])
500
501	LINUX=${kernelsrc}
502	LINUX_OBJ=${kernelbuild}
503	LINUX_VERSION=${kernsrcver}
504
505	AC_SUBST(LINUX)
506	AC_SUBST(LINUX_OBJ)
507	AC_SUBST(LINUX_VERSION)
508])
509
510dnl #
511dnl # Detect the QAT module to be built against, QAT provides hardware
512dnl # acceleration for data compression:
513dnl #
514dnl # https://01.org/intel-quickassist-technology
515dnl #
516dnl # 1) Download and install QAT driver from the above link
517dnl # 2) Start QAT driver in your system:
518dnl # 	 service qat_service start
519dnl # 3) Enable QAT in ZFS, e.g.:
520dnl # 	 ./configure --with-qat=<qat-driver-path>/QAT1.6
521dnl # 	 make
522dnl # 4) Set GZIP compression in ZFS dataset:
523dnl # 	 zfs set compression = gzip <dataset>
524dnl #
525dnl # Then the data written to this ZFS pool is compressed by QAT accelerator
526dnl # automatically, and de-compressed by QAT when read from the pool.
527dnl #
528dnl # 1) Get QAT hardware statistics with:
529dnl #	 cat /proc/icp_dh895xcc_dev/qat
530dnl # 2) To disable QAT:
531dnl # 	 insmod zfs.ko zfs_qat_disable=1
532dnl #
533AC_DEFUN([ZFS_AC_QAT], [
534	AC_ARG_WITH([qat],
535		AS_HELP_STRING([--with-qat=PATH],
536		[Path to qat source]),
537		AS_IF([test "$withval" = "yes"],
538			AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
539			[qatsrc="$withval"]))
540
541	AC_ARG_WITH([qat-obj],
542		AS_HELP_STRING([--with-qat-obj=PATH],
543		[Path to qat build objects]),
544		[qatbuild="$withval"])
545
546	AS_IF([test ! -z "${qatsrc}"], [
547		AC_MSG_CHECKING([qat source directory])
548		AC_MSG_RESULT([$qatsrc])
549		QAT_SRC="${qatsrc}/quickassist"
550		AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
551			AC_MSG_ERROR([
552	*** Please make sure the qat driver package is installed
553	*** and specify the location of the qat source with the
554	*** '--with-qat=PATH' option then try again. Failed to
555	*** find cpa.h in:
556	${QAT_SRC}/include])
557		])
558	])
559
560	AS_IF([test ! -z "${qatsrc}"], [
561		AC_MSG_CHECKING([qat build directory])
562		AS_IF([test -z "$qatbuild"], [
563			qatbuild="${qatsrc}/build"
564		])
565
566		AC_MSG_RESULT([$qatbuild])
567		QAT_OBJ=${qatbuild}
568		AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
569			AC_MSG_ERROR([
570	*** Please make sure the qat driver is installed then try again.
571	*** Failed to find icp_qa_al.ko or qat_api.ko in:
572	$QAT_OBJ])
573		])
574
575		AC_SUBST(QAT_SRC)
576		AC_SUBST(QAT_OBJ)
577
578		AC_DEFINE(HAVE_QAT, 1,
579		[qat is enabled and existed])
580	])
581
582	dnl #
583	dnl # Detect the name used for the QAT Module.symvers file.
584	dnl #
585	AS_IF([test ! -z "${qatsrc}"], [
586		AC_MSG_CHECKING([qat file for module symbols])
587		QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
588
589		AS_IF([test -r $QAT_SYMBOLS], [
590			AC_MSG_RESULT([$QAT_SYMBOLS])
591			AC_SUBST(QAT_SYMBOLS)
592		],[
593			AC_MSG_ERROR([
594	*** Please make sure the qat driver is installed then try again.
595	*** Failed to find Module.symvers in:
596	$QAT_SYMBOLS
597			])
598		])
599	])
600])
601
602dnl #
603dnl # ZFS_LINUX_CONFTEST_H
604dnl #
605AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
606test -d build/$2 || mkdir -p build/$2
607cat - <<_ACEOF >build/$2/$2.h
608$1
609_ACEOF
610])
611
612dnl #
613dnl # ZFS_LINUX_CONFTEST_C
614dnl #
615AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
616test -d build/$2 || mkdir -p build/$2
617cat confdefs.h - <<_ACEOF >build/$2/$2.c
618$1
619_ACEOF
620])
621
622dnl #
623dnl # ZFS_LINUX_CONFTEST_MAKEFILE
624dnl #
625dnl # $1 - test case name
626dnl # $2 - add to top-level Makefile
627dnl # $3 - additional build flags
628dnl #
629AC_DEFUN([ZFS_LINUX_CONFTEST_MAKEFILE], [
630	test -d build || mkdir -p build
631	test -d build/$1 || mkdir -p build/$1
632
633	file=build/$1/Makefile
634
635	dnl # Example command line to manually build source.
636	cat - <<_ACEOF >$file
637# Example command line to manually build source
638# make modules -C $LINUX_OBJ $ARCH_UM M=$PWD/build/$1
639
640ccflags-y := -Werror $FRAME_LARGER_THAN
641_ACEOF
642
643	dnl # Additional custom CFLAGS as requested.
644	m4_ifval($3, [echo "ccflags-y += $3" >>$file], [])
645
646	dnl # Test case source
647	echo "obj-m := $1.o" >>$file
648
649	AS_IF([test "x$2" = "xyes"], [echo "obj-m += $1/" >>build/Makefile], [])
650])
651
652dnl #
653dnl # ZFS_LINUX_TEST_PROGRAM(C)([PROLOGUE], [BODY])
654dnl #
655m4_define([ZFS_LINUX_TEST_PROGRAM], [
656#include <linux/module.h>
657$1
658
659int
660main (void)
661{
662$2
663	;
664	return 0;
665}
666
667MODULE_DESCRIPTION("conftest");
668MODULE_AUTHOR(ZFS_META_AUTHOR);
669MODULE_VERSION(ZFS_META_VERSION "-" ZFS_META_RELEASE);
670MODULE_LICENSE($3);
671])
672
673dnl #
674dnl # ZFS_LINUX_TEST_REMOVE
675dnl #
676dnl # Removes the specified test source and results.
677dnl #
678AC_DEFUN([ZFS_LINUX_TEST_REMOVE], [
679	test -d build/$1 && rm -Rf build/$1
680	test -f build/Makefile && sed '/$1/d' build/Makefile
681])
682
683dnl #
684dnl # ZFS_LINUX_COMPILE
685dnl #
686dnl # $1 - build dir
687dnl # $2 - test command
688dnl # $3 - pass command
689dnl # $4 - fail command
690dnl # $5 - set KBUILD_MODPOST_NOFINAL='yes'
691dnl # $6 - set KBUILD_MODPOST_WARN='yes'
692dnl #
693dnl # Used internally by ZFS_LINUX_TEST_{COMPILE,MODPOST}
694dnl #
695AC_DEFUN([ZFS_LINUX_COMPILE], [
696	AC_ARG_VAR([KERNEL_CC], [C compiler for
697		building kernel modules])
698	AC_ARG_VAR([KERNEL_LD], [Linker for
699		building kernel modules])
700	AC_ARG_VAR([KERNEL_LLVM], [Binary option to
701		build kernel modules with LLVM/CLANG toolchain])
702	AC_TRY_COMMAND([
703	    KBUILD_MODPOST_NOFINAL="$5" KBUILD_MODPOST_WARN="$6"
704	    make modules -k -j$TEST_JOBS ${KERNEL_CC:+CC=$KERNEL_CC}
705	    ${KERNEL_LD:+LD=$KERNEL_LD} ${KERNEL_LLVM:+LLVM=$KERNEL_LLVM}
706	    CONFIG_MODULES=y CFLAGS_MODULE=-DCONFIG_MODULES
707	    -C $LINUX_OBJ $ARCH_UM M=$PWD/$1 >$1/build.log 2>&1])
708	AS_IF([AC_TRY_COMMAND([$2])], [$3], [$4])
709])
710
711dnl #
712dnl # ZFS_LINUX_TEST_COMPILE
713dnl #
714dnl # Perform a full compile excluding the final modpost phase.
715dnl #
716AC_DEFUN([ZFS_LINUX_TEST_COMPILE], [
717	ZFS_LINUX_COMPILE([$2], [test -f $2/build.log], [
718		mv $2/Makefile $2/Makefile.compile.$1
719		mv $2/build.log $2/build.log.$1
720	],[
721	        AC_MSG_ERROR([
722        *** Unable to compile test source to determine kernel interfaces.])
723	], [yes], [])
724])
725
726dnl #
727dnl # ZFS_LINUX_TEST_MODPOST
728dnl #
729dnl # Perform a full compile including the modpost phase.  This may
730dnl # be an incremental build if the objects have already been built.
731dnl #
732AC_DEFUN([ZFS_LINUX_TEST_MODPOST], [
733	ZFS_LINUX_COMPILE([$2], [test -f $2/build.log], [
734		mv $2/Makefile $2/Makefile.modpost.$1
735		cat $2/build.log >>build/build.log.$1
736	],[
737	        AC_MSG_ERROR([
738        *** Unable to modpost test source to determine kernel interfaces.])
739	], [], [yes])
740])
741
742dnl #
743dnl # Perform the compilation of the test cases in two phases.
744dnl #
745dnl # Phase 1) attempt to build the object files for all of the tests
746dnl #          defined by the ZFS_LINUX_TEST_SRC macro.  But do not
747dnl #          perform the final modpost stage.
748dnl #
749dnl # Phase 2) disable all tests which failed the initial compilation,
750dnl #          then invoke the final modpost step for the remaining tests.
751dnl #
752dnl # This allows us efficiently build the test cases in parallel while
753dnl # remaining resilient to build failures which are expected when
754dnl # detecting the available kernel interfaces.
755dnl #
756dnl # The maximum allowed parallelism can be controlled by setting the
757dnl # TEST_JOBS environment variable.  Otherwise, it default to $(nproc).
758dnl #
759AC_DEFUN([ZFS_LINUX_TEST_COMPILE_ALL], [
760	dnl # Phase 1 - Compilation only, final linking is skipped.
761	ZFS_LINUX_TEST_COMPILE([$1], [build])
762
763	dnl #
764	dnl # Phase 2 - When building external modules disable test cases
765	dnl # which failed to compile and invoke modpost to verify the
766	dnl # final linking.
767	dnl #
768	dnl # Test names suffixed with '_license' call modpost independently
769	dnl # to ensure that a single incompatibility does not result in the
770	dnl # modpost phase exiting early.  This check is not performed on
771	dnl # every symbol since the majority are compatible and doing so
772	dnl # would significantly slow down this phase.
773	dnl #
774	dnl # When configuring for builtin (--enable-linux-builtin)
775	dnl # fake the linking step artificially create the expected .ko
776	dnl # files for tests which did compile.  This is required for
777	dnl # kernels which do not have loadable module support or have
778	dnl # not yet been built.
779	dnl #
780	AS_IF([test "x$enable_linux_builtin" = "xno"], [
781		for dir in $(awk '/^obj-m/ { print [$]3 }' \
782		    build/Makefile.compile.$1); do
783			name=${dir%/}
784			AS_IF([test -f build/$name/$name.o], [
785				AS_IF([test "${name##*_}" = "license"], [
786					ZFS_LINUX_TEST_MODPOST([$1],
787					    [build/$name])
788					echo "obj-n += $dir" >>build/Makefile
789				], [
790					echo "obj-m += $dir" >>build/Makefile
791				])
792			], [
793				echo "obj-n += $dir" >>build/Makefile
794			])
795		done
796
797		ZFS_LINUX_TEST_MODPOST([$1], [build])
798	], [
799		for dir in $(awk '/^obj-m/ { print [$]3 }' \
800		    build/Makefile.compile.$1); do
801			name=${dir%/}
802			AS_IF([test -f build/$name/$name.o], [
803				touch build/$name/$name.ko
804			])
805		done
806	])
807])
808
809dnl #
810dnl # ZFS_LINUX_TEST_SRC
811dnl #
812dnl # $1 - name
813dnl # $2 - global
814dnl # $3 - source
815dnl # $4 - extra cflags
816dnl # $5 - check license-compatibility
817dnl #
818dnl # Check if the test source is buildable at all and then if it is
819dnl # license compatible.
820dnl #
821dnl # N.B because all of the test cases are compiled in parallel they
822dnl # must never depend on the results of previous tests.  Each test
823dnl # needs to be entirely independent.
824dnl #
825AC_DEFUN([ZFS_LINUX_TEST_SRC], [
826	ZFS_LINUX_CONFTEST_C([ZFS_LINUX_TEST_PROGRAM([[$2]], [[$3]],
827	    [["Dual BSD/GPL"]])], [$1])
828	ZFS_LINUX_CONFTEST_MAKEFILE([$1], [yes], [$4])
829
830	AS_IF([ test -n "$5" ], [
831		ZFS_LINUX_CONFTEST_C([ZFS_LINUX_TEST_PROGRAM(
832		    [[$2]], [[$3]], [[$5]])], [$1_license])
833		ZFS_LINUX_CONFTEST_MAKEFILE([$1_license], [yes], [$4])
834	])
835])
836
837dnl #
838dnl # ZFS_LINUX_TEST_RESULT
839dnl #
840dnl # $1 - name of a test source (ZFS_LINUX_TEST_SRC)
841dnl # $2 - run on success (valid .ko generated)
842dnl # $3 - run on failure (unable to compile)
843dnl #
844AC_DEFUN([ZFS_LINUX_TEST_RESULT], [
845	AS_IF([test -d build/$1], [
846		AS_IF([test -f build/$1/$1.ko], [$2], [$3])
847	], [
848		AC_MSG_ERROR([
849	*** No matching source for the "$1" test, check that
850	*** both the test source and result macros refer to the same name.
851		])
852	])
853])
854
855dnl #
856dnl # ZFS_LINUX_TEST_ERROR
857dnl #
858dnl # Generic error message which can be used when none of the expected
859dnl # kernel interfaces were detected.
860dnl #
861AC_DEFUN([ZFS_LINUX_TEST_ERROR], [
862	AC_MSG_ERROR([
863	*** None of the expected "$1" interfaces were detected.
864	*** This may be because your kernel version is newer than what is
865	*** supported, or you are using a patched custom kernel with
866	*** incompatible modifications.
867	***
868	*** ZFS Version: $ZFS_META_ALIAS
869	*** Compatible Kernels: $ZFS_META_KVER_MIN - $ZFS_META_KVER_MAX
870	])
871])
872
873dnl #
874dnl # ZFS_LINUX_TEST_RESULT_SYMBOL
875dnl #
876dnl # Like ZFS_LINUX_TEST_RESULT except ZFS_CHECK_SYMBOL_EXPORT is called to
877dnl # verify symbol exports, unless --enable-linux-builtin was provided to
878dnl # configure.
879dnl #
880AC_DEFUN([ZFS_LINUX_TEST_RESULT_SYMBOL], [
881	AS_IF([ ! test -f build/$1/$1.ko], [
882		$5
883	], [
884		AS_IF([test "x$enable_linux_builtin" != "xyes"], [
885			ZFS_CHECK_SYMBOL_EXPORT([$2], [$3], [$4], [$5])
886		], [
887			$4
888		])
889	])
890])
891
892dnl #
893dnl # ZFS_LINUX_COMPILE_IFELSE
894dnl #
895AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
896	ZFS_LINUX_TEST_REMOVE([conftest])
897
898	m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1], [conftest])])
899	m4_ifvaln([$5], [ZFS_LINUX_CONFTEST_H([$5], [conftest])],
900	    [ZFS_LINUX_CONFTEST_H([], [conftest])])
901
902	ZFS_LINUX_CONFTEST_MAKEFILE([conftest], [no],
903	    [m4_ifvaln([$5], [-I$PWD/build/conftest], [])])
904	ZFS_LINUX_COMPILE([build/conftest], [$2], [$3], [$4], [], [])
905])
906
907dnl #
908dnl # ZFS_LINUX_TRY_COMPILE
909dnl #
910dnl # $1 - global
911dnl # $2 - source
912dnl # $3 - run on success (valid .ko generated)
913dnl # $4 - run on failure (unable to compile)
914dnl #
915dnl # When configuring as builtin (--enable-linux-builtin) for kernels
916dnl # without loadable module support (CONFIG_MODULES=n) only the object
917dnl # file is created.  See ZFS_LINUX_TEST_COMPILE_ALL for details.
918dnl #
919AC_DEFUN([ZFS_LINUX_TRY_COMPILE], [
920	AS_IF([test "x$enable_linux_builtin" = "xyes"], [
921		ZFS_LINUX_COMPILE_IFELSE(
922		    [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
923		    [[ZFS_META_LICENSE]])],
924		    [test -f build/conftest/conftest.o], [$3], [$4])
925	], [
926		ZFS_LINUX_COMPILE_IFELSE(
927		    [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
928		    [[ZFS_META_LICENSE]])],
929		    [test -f build/conftest/conftest.ko], [$3], [$4])
930	])
931])
932
933dnl #
934dnl # ZFS_CHECK_SYMBOL_EXPORT
935dnl #
936dnl # Check if a symbol is exported on not by consulting the symbols
937dnl # file, or optionally the source code.
938dnl #
939AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
940	grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
941		$LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
942	rc=$?
943	if test $rc -ne 0; then
944		export=0
945		for file in $2; do
946			grep -q -E "EXPORT_SYMBOL.*($1)" \
947				"$LINUX/$file" 2>/dev/null
948			rc=$?
949			if test $rc -eq 0; then
950				export=1
951				break;
952			fi
953		done
954		if test $export -eq 0; then :
955			$4
956		else :
957			$3
958		fi
959	else :
960		$3
961	fi
962])
963
964dnl #
965dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
966dnl #
967dnl # Like ZFS_LINUX_TRY_COMPILER except ZFS_CHECK_SYMBOL_EXPORT is called
968dnl # to verify symbol exports, unless --enable-linux-builtin was provided
969dnl # to configure.
970dnl #
971AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
972	ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
973	if test $rc -ne 0; then :
974		$6
975	else
976		if test "x$enable_linux_builtin" != xyes; then
977			ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
978		fi
979		if test $rc -ne 0; then :
980			$6
981		else :
982			$5
983		fi
984	fi
985])
986
987dnl #
988dnl # ZFS_LINUX_TRY_COMPILE_HEADER
989dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
990dnl # provided via the fifth parameter
991dnl #
992AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER], [
993	AS_IF([test "x$enable_linux_builtin" = "xyes"], [
994		ZFS_LINUX_COMPILE_IFELSE(
995		    [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
996		    [[ZFS_META_LICENSE]])],
997		    [test -f build/conftest/conftest.o], [$3], [$4], [$5])
998	], [
999		ZFS_LINUX_COMPILE_IFELSE(
1000		    [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
1001		    [[ZFS_META_LICENSE]])],
1002		    [test -f build/conftest/conftest.ko], [$3], [$4], [$5])
1003	])
1004])
1005
1006dnl #
1007dnl # AS_VERSION_COMPARE_LE
1008dnl # like AS_VERSION_COMPARE_LE, but runs $3 if (and only if) $1 <= $2
1009dnl # AS_VERSION_COMPARE_LE (version-1, version-2, [action-if-less-or-equal], [action-if-greater])
1010dnl #
1011AC_DEFUN([AS_VERSION_COMPARE_LE], [
1012	AS_VERSION_COMPARE([$1], [$2], [$3], [$3], [$4])
1013])
1014
1015dnl #
1016dnl # ZFS_LINUX_REQUIRE_API
1017dnl # like ZFS_LINUX_TEST_ERROR, except only fails if the kernel is
1018dnl # at least some specified version.
1019dnl #
1020AC_DEFUN([ZFS_LINUX_REQUIRE_API], [
1021	AS_VERSION_COMPARE_LE([$2], [$kernsrcver], [
1022		AC_MSG_ERROR([
1023		*** None of the expected "$1" interfaces were detected. This
1024		*** interface is expected for kernels version "$2" and above.
1025		*** This may be because your kernel version is newer than what is
1026		*** supported, or you are using a patched custom kernel with
1027		*** incompatible modifications.  Newer kernels may have incompatible
1028		*** APIs.
1029		***
1030		*** ZFS Version: $ZFS_META_ALIAS
1031		*** Compatible Kernels: $ZFS_META_KVER_MIN - $ZFS_META_KVER_MAX
1032		])
1033	], [
1034		AC_MSG_RESULT(no)
1035	])
1036])
1037