xref: /linux/arch/arm/boot/compressed/vmlinux.lds.S (revision 44f57d78) 
1/* SPDX-License-Identifier: GPL-2.0-only */
2/*
3 *  Copyright (C) 2000 Russell King
4 */
5
6#ifdef CONFIG_CPU_ENDIAN_BE8
7#define ZIMAGE_MAGIC(x) ( (((x) >> 24) & 0x000000ff) | \
8			  (((x) >>  8) & 0x0000ff00) | \
9			  (((x) <<  8) & 0x00ff0000) | \
10			  (((x) << 24) & 0xff000000) )
11#else
12#define ZIMAGE_MAGIC(x) (x)
13#endif
14
15OUTPUT_ARCH(arm)
16ENTRY(_start)
17SECTIONS
18{
19  /DISCARD/ : {
20    *(.ARM.exidx*)
21    *(.ARM.extab*)
22    /*
23     * Discard any r/w data - this produces a link error if we have any,
24     * which is required for PIC decompression.  Local data generates
25     * GOTOFF relocations, which prevents it being relocated independently
26     * of the text/got segments.
27     */
28    *(.data)
29  }
30
31  . = TEXT_START;
32  _text = .;
33
34  .text : {
35    _start = .;
36    *(.start)
37    *(.text)
38    *(.text.*)
39    *(.fixup)
40    *(.gnu.warning)
41    *(.glue_7t)
42    *(.glue_7)
43  }
44  .table : ALIGN(4) {
45    _table_start = .;
46    LONG(ZIMAGE_MAGIC(2))
47    LONG(ZIMAGE_MAGIC(0x5a534c4b))
48    LONG(ZIMAGE_MAGIC(__piggy_size_addr - _start))
49    LONG(ZIMAGE_MAGIC(_kernel_bss_size))
50    LONG(0)
51    _table_end = .;
52  }
53  .rodata : {
54    *(.rodata)
55    *(.rodata.*)
56    *(.data.rel.ro)
57  }
58  .piggydata : {
59    *(.piggydata)
60    __piggy_size_addr = . - 4;
61  }
62
63  . = ALIGN(4);
64  _etext = .;
65
66  .got.plt		: { *(.got.plt) }
67  _got_start = .;
68  .got			: { *(.got) }
69  _got_end = .;
70
71  /* ensure the zImage file size is always a multiple of 64 bits */
72  /* (without a dummy byte, ld just ignores the empty section) */
73  .pad			: { BYTE(0); . = ALIGN(8); }
74
75#ifdef CONFIG_EFI_STUB
76  .data : ALIGN(4096) {
77    __pecoff_data_start = .;
78    /*
79     * The EFI stub always executes from RAM, and runs strictly before the
80     * decompressor, so we can make an exception for its r/w data, and keep it
81     */
82    *(.data.efistub)
83    __pecoff_data_end = .;
84
85    /*
86     * PE/COFF mandates a file size which is a multiple of 512 bytes if the
87     * section size equals or exceeds 4 KB
88     */
89    . = ALIGN(512);
90  }
91  __pecoff_data_rawsize = . - ADDR(.data);
92#endif
93
94  _edata = .;
95
96  /*
97   * The image_end section appears after any additional loadable sections
98   * that the linker may decide to insert in the binary image.  Having
99   * this symbol allows further debug in the near future.
100   */
101  .image_end (NOLOAD) : {
102    /*
103     * EFI requires that the image is aligned to 512 bytes, and appended
104     * DTB requires that we know where the end of the image is.  Ensure
105     * that both are satisfied by ensuring that there are no additional
106     * sections emitted into the decompressor image.
107     */
108    _edata_real = .;
109  }
110
111  _magic_sig = ZIMAGE_MAGIC(0x016f2818);
112  _magic_start = ZIMAGE_MAGIC(_start);
113  _magic_end = ZIMAGE_MAGIC(_edata);
114  _magic_table = ZIMAGE_MAGIC(_table_start - _start);
115
116  . = BSS_START;
117  __bss_start = .;
118  .bss			: { *(.bss) }
119  _end = .;
120
121  . = ALIGN(8);		/* the stack must be 64-bit aligned */
122  .stack		: { *(.stack) }
123
124  PROVIDE(__pecoff_data_size = ALIGN(512) - ADDR(.data));
125  PROVIDE(__pecoff_end = ALIGN(512));
126
127  .stab 0		: { *(.stab) }
128  .stabstr 0		: { *(.stabstr) }
129  .stab.excl 0		: { *(.stab.excl) }
130  .stab.exclstr 0	: { *(.stab.exclstr) }
131  .stab.index 0		: { *(.stab.index) }
132  .stab.indexstr 0	: { *(.stab.indexstr) }
133  .comment 0		: { *(.comment) }
134}
135ASSERT(_edata_real == _edata, "error: zImage file size is incorrect");
136