xref: /linux/arch/um/kernel/uml.lds.S (revision 0be3ff0c) 
1/* SPDX-License-Identifier: GPL-2.0 */
2#include <asm/vmlinux.lds.h>
3#include <asm/page.h>
4
5OUTPUT_FORMAT(ELF_FORMAT)
6OUTPUT_ARCH(ELF_ARCH)
7ENTRY(_start)
8jiffies = jiffies_64;
9
10VERSION {
11  {
12    local: *;
13  };
14}
15
16SECTIONS
17{
18  /* This must contain the right address - not quite the default ELF one.*/
19  PROVIDE (__executable_start = START);
20  /* Static binaries stick stuff here, like the sigreturn trampoline,
21   * invisibly to objdump.  So, just make __binary_start equal to the very
22   * beginning of the executable, and if there are unmapped pages after this,
23   * they are forever unusable.
24   */
25  __binary_start = START;
26
27  . = START + SIZEOF_HEADERS;
28  . = ALIGN(PAGE_SIZE);
29
30  _text = .;
31  INIT_TEXT_SECTION(0)
32
33  .text      :
34  {
35    _stext = .;
36    TEXT_TEXT
37    SCHED_TEXT
38    CPUIDLE_TEXT
39    LOCK_TEXT
40    IRQENTRY_TEXT
41    SOFTIRQENTRY_TEXT
42    *(.fixup)
43    /* .gnu.warning sections are handled specially by elf32.em.  */
44    *(.gnu.warning)
45    *(.gnu.linkonce.t*)
46  }
47
48  . = ALIGN(PAGE_SIZE);
49  .syscall_stub : {
50	__syscall_stub_start = .;
51	*(.__syscall_stub*)
52	__syscall_stub_end = .;
53  }
54
55  /*
56   * These are needed even in a static link, even if they wind up being empty.
57   * Newer glibc needs these __rel{,a}_iplt_{start,end} symbols.
58   */
59  .rel.plt : {
60	*(.rel.plt)
61	PROVIDE_HIDDEN(__rel_iplt_start = .);
62	*(.rel.iplt)
63	PROVIDE_HIDDEN(__rel_iplt_end = .);
64  }
65  .rela.plt : {
66	*(.rela.plt)
67	PROVIDE_HIDDEN(__rela_iplt_start = .);
68	*(.rela.iplt)
69	PROVIDE_HIDDEN(__rela_iplt_end = .);
70  }
71
72  #include <asm/common.lds.S>
73
74  __init_begin = .;
75  init.data : { INIT_DATA }
76  __init_end = .;
77
78  .data    :
79  {
80    INIT_TASK_DATA(KERNEL_STACK_SIZE)
81    . = ALIGN(KERNEL_STACK_SIZE);
82    *(.data..init_irqstack)
83    DATA_DATA
84    *(.gnu.linkonce.d*)
85    CONSTRUCTORS
86  }
87  .data1   : { *(.data1) }
88  .ctors         :
89  {
90    *(.ctors)
91  }
92  .dtors         :
93  {
94    *(.dtors)
95  }
96
97  .got           : { *(.got.plt) *(.got) }
98  .dynamic       : { *(.dynamic) }
99  .tdata	  : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
100  .tbss		  : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
101  /* We want the small data sections together, so single-instruction offsets
102     can access them all, and initialized data all before uninitialized, so
103     we can shorten the on-disk segment size.  */
104  .sdata     : { *(.sdata) }
105  _edata  =  .;
106  PROVIDE (edata = .);
107  . = ALIGN(PAGE_SIZE);
108  __bss_start = .;
109  PROVIDE(_bss_start = .);
110  SBSS(0)
111  BSS(0)
112   __bss_stop = .;
113  _end = .;
114  PROVIDE (end = .);
115
116  STABS_DEBUG
117  DWARF_DEBUG
118  ELF_DETAILS
119
120  DISCARDS
121}
122