xref: /linux/tools/memory-model/linux-kernel.cat (revision 52338415) 
1// SPDX-License-Identifier: GPL-2.0+
2(*
3 * Copyright (C) 2015 Jade Alglave <j.alglave@ucl.ac.uk>,
4 * Copyright (C) 2016 Luc Maranget <luc.maranget@inria.fr> for Inria
5 * Copyright (C) 2017 Alan Stern <stern@rowland.harvard.edu>,
6 *                    Andrea Parri <parri.andrea@gmail.com>
7 *
8 * An earlier version of this file appeared in the companion webpage for
9 * "Frightening small children and disconcerting grown-ups: Concurrency
10 * in the Linux kernel" by Alglave, Maranget, McKenney, Parri, and Stern,
11 * which appeared in ASPLOS 2018.
12 *)
13
14"Linux-kernel memory consistency model"
15
16(*
17 * File "lock.cat" handles locks and is experimental.
18 * It can be replaced by include "cos.cat" for tests that do not use locks.
19 *)
20
21include "lock.cat"
22
23(*******************)
24(* Basic relations *)
25(*******************)
26
27(* Release Acquire *)
28let acq-po = [Acquire] ; po ; [M]
29let po-rel = [M] ; po ; [Release]
30let po-unlock-rf-lock-po = po ; [UL] ; rf ; [LKR] ; po
31
32(* Fences *)
33let R4rmb = R \ Noreturn	(* Reads for which rmb works *)
34let rmb = [R4rmb] ; fencerel(Rmb) ; [R4rmb]
35let wmb = [W] ; fencerel(Wmb) ; [W]
36let mb = ([M] ; fencerel(Mb) ; [M]) |
37	([M] ; fencerel(Before-atomic) ; [RMW] ; po? ; [M]) |
38	([M] ; po? ; [RMW] ; fencerel(After-atomic) ; [M]) |
39	([M] ; po? ; [LKW] ; fencerel(After-spinlock) ; [M]) |
40	([M] ; po ; [UL] ; (co | po) ; [LKW] ;
41		fencerel(After-unlock-lock) ; [M])
42let gp = po ; [Sync-rcu | Sync-srcu] ; po?
43let strong-fence = mb | gp
44
45let nonrw-fence = strong-fence | po-rel | acq-po
46let fence = nonrw-fence | wmb | rmb
47let barrier = fencerel(Barrier | Rmb | Wmb | Mb | Sync-rcu | Sync-srcu |
48		Before-atomic | After-atomic | Acquire | Release |
49		Rcu-lock | Rcu-unlock | Srcu-lock | Srcu-unlock) |
50	(po ; [Release]) | ([Acquire] ; po)
51
52(**********************************)
53(* Fundamental coherence ordering *)
54(**********************************)
55
56(* Sequential Consistency Per Variable *)
57let com = rf | co | fr
58acyclic po-loc | com as coherence
59
60(* Atomic Read-Modify-Write *)
61empty rmw & (fre ; coe) as atomic
62
63(**********************************)
64(* Instruction execution ordering *)
65(**********************************)
66
67(* Preserved Program Order *)
68let dep = addr | data
69let rwdep = (dep | ctrl) ; [W]
70let overwrite = co | fr
71let to-w = rwdep | (overwrite & int) | (addr ; [Plain] ; wmb)
72let to-r = addr | (dep ; [Marked] ; rfi)
73let ppo = to-r | to-w | fence | (po-unlock-rf-lock-po & int)
74
75(* Propagation: Ordering from release operations and strong fences. *)
76let A-cumul(r) = (rfe ; [Marked])? ; r
77let cumul-fence = [Marked] ; (A-cumul(strong-fence | po-rel) | wmb |
78	po-unlock-rf-lock-po) ; [Marked]
79let prop = [Marked] ; (overwrite & ext)? ; cumul-fence* ;
80	[Marked] ; rfe? ; [Marked]
81
82(*
83 * Happens Before: Ordering from the passage of time.
84 * No fences needed here for prop because relation confined to one process.
85 *)
86let hb = [Marked] ; (ppo | rfe | ((prop \ id) & int)) ; [Marked]
87acyclic hb as happens-before
88
89(****************************************)
90(* Write and fence propagation ordering *)
91(****************************************)
92
93(* Propagation: Each non-rf link needs a strong fence. *)
94let pb = prop ; strong-fence ; hb* ; [Marked]
95acyclic pb as propagation
96
97(*******)
98(* RCU *)
99(*******)
100
101(*
102 * Effects of read-side critical sections proceed from the rcu_read_unlock()
103 * or srcu_read_unlock() backwards on the one hand, and from the
104 * rcu_read_lock() or srcu_read_lock() forwards on the other hand.
105 *
106 * In the definition of rcu-fence below, the po term at the left-hand side
107 * of each disjunct and the po? term at the right-hand end have been factored
108 * out.  They have been moved into the definitions of rcu-link and rb.
109 * This was necessary in order to apply the "& loc" tests correctly.
110 *)
111let rcu-gp = [Sync-rcu]		(* Compare with gp *)
112let srcu-gp = [Sync-srcu]
113let rcu-rscsi = rcu-rscs^-1
114let srcu-rscsi = srcu-rscs^-1
115
116(*
117 * The synchronize_rcu() strong fence is special in that it can order not
118 * one but two non-rf relations, but only in conjunction with an RCU
119 * read-side critical section.
120 *)
121let rcu-link = po? ; hb* ; pb* ; prop ; po
122
123(*
124 * Any sequence containing at least as many grace periods as RCU read-side
125 * critical sections (joined by rcu-link) induces order like a generalized
126 * inter-CPU strong fence.
127 * Likewise for SRCU grace periods and read-side critical sections, provided
128 * the synchronize_srcu() and srcu_read_[un]lock() calls refer to the same
129 * struct srcu_struct location.
130 *)
131let rec rcu-order = rcu-gp | srcu-gp |
132	(rcu-gp ; rcu-link ; rcu-rscsi) |
133	((srcu-gp ; rcu-link ; srcu-rscsi) & loc) |
134	(rcu-rscsi ; rcu-link ; rcu-gp) |
135	((srcu-rscsi ; rcu-link ; srcu-gp) & loc) |
136	(rcu-gp ; rcu-link ; rcu-order ; rcu-link ; rcu-rscsi) |
137	((srcu-gp ; rcu-link ; rcu-order ; rcu-link ; srcu-rscsi) & loc) |
138	(rcu-rscsi ; rcu-link ; rcu-order ; rcu-link ; rcu-gp) |
139	((srcu-rscsi ; rcu-link ; rcu-order ; rcu-link ; srcu-gp) & loc) |
140	(rcu-order ; rcu-link ; rcu-order)
141let rcu-fence = po ; rcu-order ; po?
142let fence = fence | rcu-fence
143let strong-fence = strong-fence | rcu-fence
144
145(* rb orders instructions just as pb does *)
146let rb = prop ; rcu-fence ; hb* ; pb* ; [Marked]
147
148irreflexive rb as rcu
149
150(*
151 * The happens-before, propagation, and rcu constraints are all
152 * expressions of temporal ordering.  They could be replaced by
153 * a single constraint on an "executes-before" relation, xb:
154 *
155 * let xb = hb | pb | rb
156 * acyclic xb as executes-before
157 *)
158
159(*********************************)
160(* Plain accesses and data races *)
161(*********************************)
162
163(* Warn about plain writes and marked accesses in the same region *)
164let mixed-accesses = ([Plain & W] ; (po-loc \ barrier) ; [Marked]) |
165	([Marked] ; (po-loc \ barrier) ; [Plain & W])
166flag ~empty mixed-accesses as mixed-accesses
167
168(* Executes-before and visibility *)
169let xbstar = (hb | pb | rb)*
170let vis = cumul-fence* ; rfe? ; [Marked] ;
171	((strong-fence ; [Marked] ; xbstar) | (xbstar & int))
172
173(* Boundaries for lifetimes of plain accesses *)
174let w-pre-bounded = [Marked] ; (addr | fence)?
175let r-pre-bounded = [Marked] ; (addr | nonrw-fence |
176	([R4rmb] ; fencerel(Rmb) ; [~Noreturn]))?
177let w-post-bounded = fence? ; [Marked]
178let r-post-bounded = (nonrw-fence | ([~Noreturn] ; fencerel(Rmb) ; [R4rmb]))? ;
179	[Marked]
180
181(* Visibility and executes-before for plain accesses *)
182let ww-vis = fence | (strong-fence ; xbstar ; w-pre-bounded) |
183	(w-post-bounded ; vis ; w-pre-bounded)
184let wr-vis = fence | (strong-fence ; xbstar ; r-pre-bounded) |
185	(w-post-bounded ; vis ; r-pre-bounded)
186let rw-xbstar = fence | (r-post-bounded ; xbstar ; w-pre-bounded)
187
188(* Potential races *)
189let pre-race = ext & ((Plain * M) | ((M \ IW) * Plain))
190
191(* Coherence requirements for plain accesses *)
192let wr-incoh = pre-race & rf & rw-xbstar^-1
193let rw-incoh = pre-race & fr & wr-vis^-1
194let ww-incoh = pre-race & co & ww-vis^-1
195empty (wr-incoh | rw-incoh | ww-incoh) as plain-coherence
196
197(* Actual races *)
198let ww-nonrace = ww-vis & ((Marked * W) | rw-xbstar) & ((W * Marked) | wr-vis)
199let ww-race = (pre-race & co) \ ww-nonrace
200let wr-race = (pre-race & (co? ; rf)) \ wr-vis
201let rw-race = (pre-race & fr) \ rw-xbstar
202
203flag ~empty (ww-race | wr-race | rw-race) as data-race
204