xref: /netbsd/sys/arch/mipsco/conf/stand.ldscript (revision bf9ec67e) 
1/*	$NetBSD: stand.ldscript,v 1.2 2001/12/04 17:56:36 wiz Exp $	*/
2
3/*  ldscript for NetBSD/mipsco standalone bootstraps */
4OUTPUT_FORMAT("elf32-bigmips", "elf32-bigmips", "elf32-littlemips")
5OUTPUT_ARCH(mips)
6ENTRY(_start)
7SECTIONS
8{
9  /*  Read-only sections, merged into text segment.  Assumes the
10      kernel Makefile sets the start address via -Ttext.  */
11  .text      :
12  {
13    _ftext = . ;
14    *(.text)
15    *(.gnu.warning)
16  } =0
17  _etext = .;
18  PROVIDE (etext = .);
19  .rodata    : { *(.rodata)  }
20  .data    :
21  {
22    _fdata = . ;
23    *(.data)
24    CONSTRUCTORS
25  }
26  _gp = ALIGN(16);
27  .lit8 : { *(.lit8) }
28  .lit4 : { *(.lit4) }
29  .sdata     : { *(.sdata) }
30  _edata  =  .;
31  PROVIDE (edata = .);
32  __bss_start = .;
33  _fbss = .;
34  .bss       :
35  {
36   *(.bss)
37   *(COMMON)
38   *(.sbss)
39   *(.scommon)
40  }
41  _end = . ;
42  PROVIDE (end = .);
43
44  /*
45   * Depending on the nuber of sections and their relative position
46   * the Mips PROM firmware incorrectly loads the image into memory
47   * 8 bytes higher than expected.  If this happens change the following
48   * definition from .reginfo to /DISCARD/ to remove the section
49   */
50
51  .reginfo : { *(.reginfo) }
52}
53