xref: /netbsd/sys/arch/sparc64/conf/kern.ldscript (revision bf9ec67e) 
1/*	$NetBSD: kern.ldscript,v 1.4 2002/05/16 01:01:41 thorpej Exp $	*/
2
3/*
4 * Kernel linker script for NetBSD/sparc64.  This script is based on
5 * elf64_sparc.xn, but puts _etext after all of the read-only sections.
6 */
7OUTPUT_FORMAT("elf64-sparc", "elf64-sparc",
8	      "elf64-sparc")
9OUTPUT_ARCH(sparc:v9)
10ENTRY(_start)
11SEARCH_DIR(/usr/lib);
12/* Do we need any of these for elf?
13   __DYNAMIC = 0;    */
14SECTIONS
15{
16  /* Read-only sections, merged into text segment: */
17  . = 0x100000 + SIZEOF_HEADERS;
18  .interp     : { *(.interp) 	}
19  .hash          : { *(.hash)		}
20  .dynsym        : { *(.dynsym)		}
21  .dynstr        : { *(.dynstr)		}
22  .gnu.version   : { *(.gnu.version)	}
23  .gnu.version_d   : { *(.gnu.version_d)	}
24  .gnu.version_r   : { *(.gnu.version_r)	}
25  .rel.text      :
26    { *(.rel.text) *(.rel.gnu.linkonce.t*) }
27  .rela.text     :
28    { *(.rela.text) *(.rela.gnu.linkonce.t*) }
29  .rel.data      :
30    { *(.rel.data) *(.rel.gnu.linkonce.d*) }
31  .rela.data     :
32    { *(.rela.data) *(.rela.gnu.linkonce.d*) }
33  .rel.rodata    :
34    { *(.rel.rodata) *(.rel.gnu.linkonce.r*) }
35  .rela.rodata   :
36    { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
37  .rel.got       : { *(.rel.got)		}
38  .rela.got      : { *(.rela.got)		}
39  .rel.ctors     : { *(.rel.ctors)	}
40  .rela.ctors    : { *(.rela.ctors)	}
41  .rel.dtors     : { *(.rel.dtors)	}
42  .rela.dtors    : { *(.rela.dtors)	}
43  .rel.init      : { *(.rel.init)	}
44  .rela.init     : { *(.rela.init)	}
45  .rel.fini      : { *(.rel.fini)	}
46  .rela.fini     : { *(.rela.fini)	}
47  .rel.bss       : { *(.rel.bss)		}
48  .rela.bss      : { *(.rela.bss)		}
49  .rel.plt       : { *(.rel.plt)		}
50  .rela.plt      : { *(.rela.plt)		}
51  .init          : { *(.init)	} =0x01000000
52  .text      :
53  {
54    *(.text)
55    *(.stub)
56    /* .gnu.warning sections are handled specially by elf32.em.  */
57    *(.gnu.warning)
58    *(.gnu.linkonce.t*)
59  } =0x01000000
60  .fini      : { *(.fini)    } =0x01000000
61  .rodata    : { *(.rodata) *(.gnu.linkonce.r*) }
62  .rodata1   : { *(.rodata1) }
63  _etext = .;
64  PROVIDE (etext = .);
65  /* Adjust the address for the data segment.  We want to adjust up to
66     the same address within the page on the next page up.  */
67  . = ALIGN(0x100000) + (. & (0x100000 - 1));
68  kernel_data_start = .;
69  .data    :
70  {
71    *(.data)
72    *(.gnu.linkonce.d*)
73    CONSTRUCTORS
74  }
75  .data1   : { *(.data1) }
76  .ctors         :
77  {
78    *(.ctors)
79  }
80  .dtors         :
81  {
82    *(.dtors)
83  }
84  .plt      : { *(.plt)	}
85  .got           : { *(.got.plt) *(.got) }
86  .dynamic       : { *(.dynamic) }
87  /* We want the small data sections together, so single-instruction offsets
88     can access them all, and initialized data all before uninitialized, so
89     we can shorten the on-disk segment size.  */
90  .sdata     : { *(.sdata) }
91  _edata  =  .;
92  PROVIDE (edata = .);
93  __bss_start = .;
94  .sbss      : { *(.sbss) *(.scommon) }
95  .bss       :
96  {
97   *(.dynbss)
98   *(.bss)
99   *(COMMON)
100  }
101  . = ALIGN(64 / 8);
102  _end = . ;
103  PROVIDE (end = .);
104  /* Stabs debugging sections.  */
105  .stab 0 : { *(.stab) }
106  .stabstr 0 : { *(.stabstr) }
107  .stab.excl 0 : { *(.stab.excl) }
108  .stab.exclstr 0 : { *(.stab.exclstr) }
109  .stab.index 0 : { *(.stab.index) }
110  .stab.indexstr 0 : { *(.stab.indexstr) }
111  .comment 0 : { *(.comment) }
112  /* DWARF debug sections.
113     Symbols in the DWARF debugging sections are relative to the beginning
114     of the section so we begin them at 0.  */
115  /* DWARF 1 */
116  .debug          0 : { *(.debug) }
117  .line           0 : { *(.line) }
118  /* GNU DWARF 1 extensions */
119  .debug_srcinfo  0 : { *(.debug_srcinfo) }
120  .debug_sfnames  0 : { *(.debug_sfnames) }
121  /* DWARF 1.1 and DWARF 2 */
122  .debug_aranges  0 : { *(.debug_aranges) }
123  .debug_pubnames 0 : { *(.debug_pubnames) }
124  /* DWARF 2 */
125  .debug_info     0 : { *(.debug_info) }
126  .debug_abbrev   0 : { *(.debug_abbrev) }
127  .debug_line     0 : { *(.debug_line) }
128  .debug_frame    0 : { *(.debug_frame) }
129  .debug_str      0 : { *(.debug_str) }
130  .debug_loc      0 : { *(.debug_loc) }
131  .debug_macinfo  0 : { *(.debug_macinfo) }
132  /* SGI/MIPS DWARF 2 extensions */
133  .debug_weaknames 0 : { *(.debug_weaknames) }
134  .debug_funcnames 0 : { *(.debug_funcnames) }
135  .debug_typenames 0 : { *(.debug_typenames) }
136  .debug_varnames  0 : { *(.debug_varnames) }
137  /* These must appear regardless of  .  */
138}
139