1# Build for the experimental deadlock detector runtime library.
2
3include_directories(../..)
4
5set(DD_CFLAGS ${SANITIZER_COMMON_CFLAGS})
6append_rtti_flag(OFF DD_CFLAGS)
7
8set(DD_SOURCES
9  dd_rtl.cpp
10  dd_interceptors.cpp
11  )
12
13set(DD_LINKLIBS ${SANITIZER_CXX_ABI_LIBRARIES} ${SANITIZER_COMMON_LINK_LIBS})
14
15append_list_if(COMPILER_RT_HAS_LIBDL dl DD_LINKLIBS)
16append_list_if(COMPILER_RT_HAS_LIBRT rt DD_LINKLIBS)
17append_list_if(COMPILER_RT_HAS_LIBPTHREAD pthread DD_LINKLIBS)
18
19add_custom_target(dd)
20set_target_properties(dd PROPERTIES FOLDER "Compiler-RT Misc")
21
22# Deadlock detector is currently supported on 64-bit Linux only.
23if(CAN_TARGET_x86_64 AND UNIX AND NOT APPLE AND NOT ANDROID)
24  set(arch "x86_64")
25  add_compiler_rt_runtime(clang_rt.dd
26    STATIC
27    ARCHS ${arch}
28    SOURCES ${DD_SOURCES}
29            $<TARGET_OBJECTS:RTInterception.${arch}>
30            $<TARGET_OBJECTS:RTSanitizerCommon.${arch}>
31            $<TARGET_OBJECTS:RTSanitizerCommonLibc.${arch}>
32    CFLAGS ${DD_CFLAGS}
33    PARENT_TARGET dd)
34
35  add_compiler_rt_object_libraries(RTDD
36    ARCHS ${arch}
37    SOURCES ${DD_SOURCES} CFLAGS ${DD_CFLAGS})
38
39  add_compiler_rt_runtime(clang_rt.dyndd
40    SHARED
41    ARCHS ${arch}
42    SOURCES $<TARGET_OBJECTS:RTDD.${arch}>
43            $<TARGET_OBJECTS:RTInterception.${arch}>
44            $<TARGET_OBJECTS:RTSanitizerCommon.${arch}>
45            $<TARGET_OBJECTS:RTSanitizerCommonLibc.${arch}>
46            $<TARGET_OBJECTS:RTSanitizerCommonSymbolizer.${arch}>
47    LINK_FLAGS ${SANITIZER_COMMON_LINK_FLAGS}
48    LINK_LIBS ${DD_LINKLIBS}
49    PARENT_TARGET dd)
50endif()
51
52add_dependencies(compiler-rt dd)
53