1add_custom_command(
2  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
3  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lldb.py
4  DEPENDS ${SWIG_SOURCES}
5  DEPENDS ${SWIG_INTERFACES}
6  DEPENDS ${SWIG_HEADERS}
7  COMMAND ${SWIG_EXECUTABLE}
8      ${SWIG_COMMON_FLAGS}
9      -I${CMAKE_CURRENT_SOURCE_DIR}
10      -c++
11      -shadow
12      -python
13      -py3
14      -threads
15      -outdir ${CMAKE_CURRENT_BINARY_DIR}
16      -o ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
17      ${CMAKE_CURRENT_SOURCE_DIR}/python.swig
18  VERBATIM
19  COMMENT "Building LLDB Python wrapper")
20
21add_custom_target(swig_wrapper_python ALL DEPENDS
22  ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
23  ${CMAKE_CURRENT_BINARY_DIR}/lldb.py
24)
25
26function(create_python_package swig_target working_dir pkg_dir)
27  cmake_parse_arguments(ARG "NOINIT" "" "FILES" ${ARGN})
28  if(ARG_FILES)
29    set(copy_cmd COMMAND ${CMAKE_COMMAND} -E copy ${ARG_FILES} ${pkg_dir})
30  endif()
31  if(NOT ARG_NOINIT)
32    set(init_cmd COMMAND ${Python3_EXECUTABLE}
33        "${LLDB_SOURCE_DIR}/bindings/python/createPythonInit.py"
34        "${pkg_dir}" ${ARG_FILES})
35  endif()
36  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
37    COMMAND ${CMAKE_COMMAND} -E make_directory ${pkg_dir}
38    ${copy_cmd}
39    ${init_cmd}
40    WORKING_DIRECTORY ${working_dir})
41endfunction()
42
43function(create_relative_symlink swig_target dest_file output_dir output_name)
44  get_filename_component(dest_file ${dest_file} ABSOLUTE)
45  get_filename_component(output_dir ${output_dir} ABSOLUTE)
46  file(RELATIVE_PATH rel_dest_file ${output_dir} ${dest_file})
47  if(CMAKE_HOST_UNIX)
48    set(LLVM_LINK_OR_COPY create_symlink)
49  else()
50    set(LLVM_LINK_OR_COPY copy)
51  endif()
52  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
53    COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} ${rel_dest_file} ${output_name}
54    WORKING_DIRECTORY ${output_dir})
55endfunction()
56
57function(finish_swig_python swig_target lldb_python_bindings_dir lldb_python_target_dir)
58  # Add a Post-Build Event to copy over Python files and create the symlink to
59  # liblldb.so for the Python API(hardlink on Windows).
60  add_custom_target(${swig_target} ALL VERBATIM
61    COMMAND ${CMAKE_COMMAND} -E make_directory ${lldb_python_target_dir}
62    DEPENDS ${lldb_python_bindings_dir}/lldb.py
63    COMMENT "Python script sym-linking LLDB Python API")
64
65  if(NOT LLDB_USE_SYSTEM_SIX)
66    add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
67      COMMAND ${CMAKE_COMMAND} -E copy
68        "${LLDB_SOURCE_DIR}/third_party/Python/module/six/six.py"
69        "${lldb_python_target_dir}/../six.py")
70  endif()
71
72  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
73    COMMAND ${CMAKE_COMMAND} -E copy
74      "${lldb_python_bindings_dir}/lldb.py"
75      "${lldb_python_target_dir}/__init__.py")
76
77  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
78    COMMAND ${CMAKE_COMMAND} -E copy
79      "${LLDB_SOURCE_DIR}/source/Interpreter/embedded_interpreter.py"
80      "${lldb_python_target_dir}")
81
82  # Distribute the examples as python packages.
83  create_python_package(
84    ${swig_target}
85    ${lldb_python_target_dir}
86    "formatters/cpp"
87    FILES "${LLDB_SOURCE_DIR}/examples/synthetic/gnu_libstdcpp.py"
88          "${LLDB_SOURCE_DIR}/examples/synthetic/libcxx.py")
89
90  create_python_package(
91    ${swig_target}
92    ${lldb_python_target_dir}
93    "formatters"
94    FILES "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/cache.py"
95          "${LLDB_SOURCE_DIR}/examples/summaries/synth.py"
96          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/metrics.py"
97          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/attrib_fromdict.py"
98          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/Logger.py")
99
100  create_python_package(
101    ${swig_target}
102    ${lldb_python_target_dir}
103    "utils"
104    FILES "${LLDB_SOURCE_DIR}/examples/python/in_call_stack.py"
105          "${LLDB_SOURCE_DIR}/examples/python/symbolication.py")
106
107  create_python_package(
108    ${swig_target}
109    ${lldb_python_target_dir}
110    "plugins"
111    FILES
112    "${LLDB_SOURCE_DIR}/examples/python/scripted_process/scripted_process.py")
113
114  if(APPLE)
115    create_python_package(
116      ${swig_target}
117      ${lldb_python_target_dir} "macosx"
118      FILES "${LLDB_SOURCE_DIR}/examples/python/crashlog.py"
119            "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap.py")
120
121    create_python_package(
122      ${swig_target}
123      ${lldb_python_target_dir} "macosx/heap"
124      FILES "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap/heap_find.cpp"
125            "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap/Makefile"
126            NOINIT)
127
128    create_python_package(
129      ${swig_target}
130      ${lldb_python_target_dir} "diagnose"
131      FILES "${LLDB_SOURCE_DIR}/examples/python/diagnose_unwind.py"
132            "${LLDB_SOURCE_DIR}/examples/python/diagnose_nsstring.py")
133  endif()
134
135  if(LLDB_BUILD_FRAMEWORK)
136    set(LIBLLDB_SYMLINK_DEST "${LLDB_FRAMEWORK_ABSOLUTE_BUILD_DIR}/LLDB.framework/LLDB")
137  else()
138    set(LIBLLDB_SYMLINK_DEST "${LLVM_SHLIB_OUTPUT_INTDIR}/liblldb${CMAKE_SHARED_LIBRARY_SUFFIX}")
139  endif()
140  if(WIN32)
141    if(CMAKE_BUILD_TYPE STREQUAL Debug)
142      set(LIBLLDB_SYMLINK_OUTPUT_FILE "_lldb_d.pyd")
143    else()
144      set(LIBLLDB_SYMLINK_OUTPUT_FILE "_lldb.pyd")
145    endif()
146  else()
147    set(LIBLLDB_SYMLINK_OUTPUT_FILE "_lldb.so")
148  endif()
149  create_relative_symlink(${swig_target} ${LIBLLDB_SYMLINK_DEST}
150                          ${lldb_python_target_dir} ${LIBLLDB_SYMLINK_OUTPUT_FILE})
151
152  if(NOT LLDB_BUILD_FRAMEWORK)
153    set(LLDB_ARGDUMPER_FILENAME "lldb-argdumper${CMAKE_EXECUTABLE_SUFFIX}")
154    create_relative_symlink(${swig_target} "${LLVM_RUNTIME_OUTPUT_INTDIR}/${LLDB_ARGDUMPER_FILENAME}"
155                            ${lldb_python_target_dir} ${LLDB_ARGDUMPER_FILENAME})
156  endif()
157
158  add_dependencies(${swig_target} swig_wrapper_python liblldb lldb-argdumper)
159  set_target_properties(${swig_target} swig_wrapper_python PROPERTIES FOLDER "lldb misc")
160
161  # Ensure we do the python post-build step when building lldb.
162  add_dependencies(lldb ${swig_target})
163
164  # Install the LLDB python module
165  if(LLDB_BUILD_FRAMEWORK)
166    set(LLDB_PYTHON_INSTALL_PATH ${LLDB_FRAMEWORK_INSTALL_DIR}/LLDB.framework/Resources/Python)
167  else()
168    set(LLDB_PYTHON_INSTALL_PATH ${LLDB_PYTHON_RELATIVE_PATH})
169  endif()
170  if (NOT CMAKE_CFG_INTDIR STREQUAL  ".")
171    string(REPLACE ${CMAKE_CFG_INTDIR} "\$\{CMAKE_INSTALL_CONFIG_NAME\}" LLDB_PYTHON_INSTALL_PATH ${LLDB_PYTHON_INSTALL_PATH})
172    string(REPLACE ${CMAKE_CFG_INTDIR} "\$\{CMAKE_INSTALL_CONFIG_NAME\}" lldb_python_target_dir ${lldb_python_target_dir})
173  endif()
174  set(python_scripts_target "${swig_target}-scripts")
175  set(python_scripts_install_target "install-${python_scripts_target}")
176  add_custom_target(${python_scripts_target})
177  add_dependencies(${python_scripts_target} ${swig_target})
178  install(DIRECTORY ${lldb_python_target_dir}/../
179          DESTINATION ${LLDB_PYTHON_INSTALL_PATH}
180          COMPONENT ${python_scripts_target})
181  if (NOT LLVM_ENABLE_IDE)
182    add_llvm_install_targets(${python_scripts_install_target}
183                             COMPONENT ${python_scripts_target}
184                             DEPENDS ${python_scripts_target})
185  endif()
186
187  # Add a Post-Build Event to copy the custom Python DLL to the lldb binaries dir so that Windows can find it when launching
188  # lldb.exe or any other executables that were linked with liblldb.
189  if (WIN32 AND NOT "${PYTHON_DLL}" STREQUAL "")
190    # When using the Visual Studio CMake generator the lldb binaries end up in Release/bin, Debug/bin etc.
191    file(TO_NATIVE_PATH "${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin" LLDB_BIN_DIR)
192    file(TO_NATIVE_PATH "${PYTHON_DLL}" PYTHON_DLL_NATIVE_PATH)
193    add_custom_command(
194      TARGET ${swig_target}
195      POST_BUILD
196      COMMAND ${CMAKE_COMMAND} -E copy ${PYTHON_DLL_NATIVE_PATH} ${LLDB_BIN_DIR} VERBATIM
197      COMMENT "Copying Python DLL to LLDB binaries directory.")
198  endif()
199endfunction()
200