1add_custom_command(
2  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
3  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lldb.py
4  DEPENDS ${SWIG_SOURCES}
5  DEPENDS ${SWIG_INTERFACES}
6  DEPENDS ${SWIG_HEADERS}
7  COMMAND ${SWIG_EXECUTABLE}
8      ${SWIG_COMMON_FLAGS}
9      -I${CMAKE_CURRENT_SOURCE_DIR}
10      -c++
11      -shadow
12      -python
13      -py3
14      -threads
15      -outdir ${CMAKE_CURRENT_BINARY_DIR}
16      -o ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
17      ${CMAKE_CURRENT_SOURCE_DIR}/python.swig
18  VERBATIM
19  COMMENT "Building LLDB Python wrapper")
20
21add_custom_target(swig_wrapper_python ALL DEPENDS
22  ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
23  ${CMAKE_CURRENT_BINARY_DIR}/lldb.py
24)
25
26if (NOT WIN32)
27add_custom_command(
28  OUTPUT  ${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb-python
29  VERBATIM
30  COMMAND ${CMAKE_COMMAND} -E copy lldb-python ${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb-python
31  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
32)
33add_custom_target(lldb-python-wrapper ALL DEPENDS
34  ${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb-python
35)
36endif()
37
38function(create_python_package swig_target working_dir pkg_dir)
39  cmake_parse_arguments(ARG "NOINIT" "" "FILES" ${ARGN})
40  if(ARG_FILES)
41    set(copy_cmd COMMAND ${CMAKE_COMMAND} -E copy ${ARG_FILES} ${pkg_dir})
42  endif()
43  if(NOT ARG_NOINIT)
44    set(init_cmd COMMAND ${Python3_EXECUTABLE}
45        "${LLDB_SOURCE_DIR}/bindings/python/createPythonInit.py"
46        "${pkg_dir}" ${ARG_FILES})
47  endif()
48  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
49    COMMAND ${CMAKE_COMMAND} -E make_directory ${pkg_dir}
50    ${copy_cmd}
51    ${init_cmd}
52    WORKING_DIRECTORY ${working_dir})
53endfunction()
54
55function(finish_swig_python swig_target lldb_python_bindings_dir lldb_python_target_dir)
56  # Add a Post-Build Event to copy over Python files and create the symlink to
57  # liblldb.so for the Python API(hardlink on Windows).
58  add_custom_target(${swig_target} ALL VERBATIM
59    COMMAND ${CMAKE_COMMAND} -E make_directory ${lldb_python_target_dir}
60    DEPENDS ${lldb_python_bindings_dir}/lldb.py
61    COMMENT "Python script sym-linking LLDB Python API")
62
63  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
64    COMMAND ${CMAKE_COMMAND} -E copy
65      "${lldb_python_bindings_dir}/lldb.py"
66      "${lldb_python_target_dir}/__init__.py")
67
68  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
69    COMMAND ${CMAKE_COMMAND} -E copy
70      "${LLDB_SOURCE_DIR}/source/Interpreter/embedded_interpreter.py"
71      "${lldb_python_target_dir}")
72
73  # Distribute the examples as python packages.
74  create_python_package(
75    ${swig_target}
76    ${lldb_python_target_dir}
77    "formatters/cpp"
78    FILES "${LLDB_SOURCE_DIR}/examples/synthetic/gnu_libstdcpp.py"
79          "${LLDB_SOURCE_DIR}/examples/synthetic/libcxx.py")
80
81  create_python_package(
82    ${swig_target}
83    ${lldb_python_target_dir}
84    "formatters"
85    FILES "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/cache.py"
86          "${LLDB_SOURCE_DIR}/examples/summaries/synth.py"
87          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/metrics.py"
88          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/attrib_fromdict.py"
89          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/Logger.py")
90
91  create_python_package(
92    ${swig_target}
93    ${lldb_python_target_dir}
94    "utils"
95    FILES "${LLDB_SOURCE_DIR}/examples/python/in_call_stack.py"
96          "${LLDB_SOURCE_DIR}/examples/python/symbolication.py")
97
98  create_python_package(
99    ${swig_target}
100    ${lldb_python_target_dir}
101    "plugins"
102    FILES
103    "${LLDB_SOURCE_DIR}/examples/python/scripted_process/scripted_process.py")
104
105  create_python_package(
106    ${swig_target}
107    ${lldb_python_target_dir}
108    "plugins"
109    FILES
110    "${LLDB_SOURCE_DIR}/examples/python/scripted_process/scripted_platform.py")
111
112  if(APPLE)
113    create_python_package(
114      ${swig_target}
115      ${lldb_python_target_dir} "macosx"
116      FILES "${LLDB_SOURCE_DIR}/examples/python/crashlog.py"
117            "${LLDB_SOURCE_DIR}/examples/python/scripted_process/crashlog_scripted_process.py"
118            "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap.py")
119
120    create_python_package(
121      ${swig_target}
122      ${lldb_python_target_dir} "macosx/heap"
123      FILES "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap/heap_find.cpp"
124            "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap/Makefile"
125            NOINIT)
126
127    create_python_package(
128      ${swig_target}
129      ${lldb_python_target_dir} "diagnose"
130      FILES "${LLDB_SOURCE_DIR}/examples/python/diagnose_unwind.py"
131            "${LLDB_SOURCE_DIR}/examples/python/diagnose_nsstring.py")
132  endif()
133
134  if(LLDB_BUILD_FRAMEWORK)
135    set(LIBLLDB_SYMLINK_DEST "${LLDB_FRAMEWORK_ABSOLUTE_BUILD_DIR}/LLDB.framework/LLDB")
136  else()
137    set(LIBLLDB_SYMLINK_DEST "${LLVM_SHLIB_OUTPUT_INTDIR}/liblldb${CMAKE_SHARED_LIBRARY_SUFFIX}")
138  endif()
139  set(LIBLLDB_SYMLINK_OUTPUT_FILE "_lldb${LLDB_PYTHON_EXT_SUFFIX}")
140  create_relative_symlink(${swig_target} ${LIBLLDB_SYMLINK_DEST}
141                          ${lldb_python_target_dir} ${LIBLLDB_SYMLINK_OUTPUT_FILE})
142
143
144  if (NOT WIN32)
145  add_dependencies(${swig_target} lldb-python-wrapper)
146  endif()
147
148  if(NOT LLDB_BUILD_FRAMEWORK)
149    set(LLDB_ARGDUMPER_FILENAME "lldb-argdumper${CMAKE_EXECUTABLE_SUFFIX}")
150    create_relative_symlink(${swig_target} "${LLVM_RUNTIME_OUTPUT_INTDIR}/${LLDB_ARGDUMPER_FILENAME}"
151                            ${lldb_python_target_dir} ${LLDB_ARGDUMPER_FILENAME})
152  endif()
153
154  add_dependencies(${swig_target} swig_wrapper_python liblldb lldb-argdumper)
155  set_target_properties(${swig_target} swig_wrapper_python PROPERTIES FOLDER "lldb misc")
156
157  # Ensure we do the python post-build step when building lldb.
158  add_dependencies(lldb ${swig_target})
159
160  # Install the LLDB python module
161  if(LLDB_BUILD_FRAMEWORK)
162    set(LLDB_PYTHON_INSTALL_PATH ${LLDB_FRAMEWORK_INSTALL_DIR}/LLDB.framework/Versions/${LLDB_FRAMEWORK_VERSION}/Resources/Python)
163  else()
164    set(LLDB_PYTHON_INSTALL_PATH ${LLDB_PYTHON_RELATIVE_PATH})
165  endif()
166  if (NOT CMAKE_CFG_INTDIR STREQUAL  ".")
167    string(REPLACE ${CMAKE_CFG_INTDIR} "\$\{CMAKE_INSTALL_CONFIG_NAME\}" LLDB_PYTHON_INSTALL_PATH ${LLDB_PYTHON_INSTALL_PATH})
168    string(REPLACE ${CMAKE_CFG_INTDIR} "\$\{CMAKE_INSTALL_CONFIG_NAME\}" lldb_python_target_dir ${lldb_python_target_dir})
169  endif()
170  set(python_scripts_target "${swig_target}-scripts")
171  set(python_scripts_install_target "install-${python_scripts_target}")
172  add_custom_target(${python_scripts_target})
173  add_dependencies(${python_scripts_target} ${swig_target})
174  install(DIRECTORY ${lldb_python_target_dir}/../
175          DESTINATION ${LLDB_PYTHON_INSTALL_PATH}
176          COMPONENT ${python_scripts_target})
177  if (NOT LLVM_ENABLE_IDE)
178    add_llvm_install_targets(${python_scripts_install_target}
179                             COMPONENT ${python_scripts_target}
180                             DEPENDS ${python_scripts_target})
181  endif()
182
183  # Add a Post-Build Event to copy the custom Python DLL to the lldb binaries dir so that Windows can find it when launching
184  # lldb.exe or any other executables that were linked with liblldb.
185  if (WIN32 AND NOT "${PYTHON_DLL}" STREQUAL "")
186    # When using the Visual Studio CMake generator the lldb binaries end up in Release/bin, Debug/bin etc.
187    file(TO_NATIVE_PATH "${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin" LLDB_BIN_DIR)
188    file(TO_NATIVE_PATH "${PYTHON_DLL}" PYTHON_DLL_NATIVE_PATH)
189    add_custom_command(
190      TARGET ${swig_target}
191      POST_BUILD
192      COMMAND ${CMAKE_COMMAND} -E copy ${PYTHON_DLL_NATIVE_PATH} ${LLDB_BIN_DIR} VERBATIM
193      COMMENT "Copying Python DLL to LLDB binaries directory.")
194  endif()
195endfunction()
196