1#!/usr/bin/perl -w
2
3BEGIN {
4    unshift @INC, 't/lib';
5}
6chdir 't';
7
8use Test::More;
9use ExtUtils::MakeMaker;
10use File::Temp qw[tempfile];
11
12my $Has_Version = eval 'require version; "version"->import; 1';
13
14# "undef" - means we expect "undef", undef - eval should be never called for this string
15my %versions = (q[$VERSION = '1.00']            => '1.00',
16                q[*VERSION = \'1.01']           => '1.01',
17                q[($VERSION) = q$Revision: 32208 $ =~ /(\d+)/g;] => 32208,
18                q[$FOO::VERSION = '1.10';]      => '1.10',
19                q[*FOO::VERSION = \'1.11';]     => '1.11',
20                '$VERSION = 0.02'               => 0.02,
21                '$VERSION = 0.0'                => 0.0,
22                '$VERSION = -1.0'               => -1.0,
23                '$VERSION = undef'              => 'undef',
24                '$wibble  = 1.0'                => undef,
25                q[my $VERSION = '1.01']         => 'undef',
26                q[local $VERSION = '1.02']      => 'undef',
27                q[local $FOO::VERSION = '1.30'] => 'undef',
28                q[if( $Foo::VERSION >= 3.00 ) {]=> 'undef',
29                q[our $VERSION = '1.23';]       => '1.23',
30                q[$CGI::VERSION='3.63']         => '3.63',
31                q[$VERSION = "1.627"; # ==> ALSO update the version in the pod text below!] => '1.627',
32                q[BEGIN { our $VERSION = '1.23' }]       => '1.23',
33
34                '$Something::VERSION == 1.0'    => undef,
35                '$Something::VERSION <= 1.0'    => undef,
36                '$Something::VERSION >= 1.0'    => undef,
37                '$Something::VERSION != 1.0'    => undef,
38                'my $meta_coder = ($JSON::XS::VERSION >= 1.4) ?' => undef,
39
40                qq[\$Something::VERSION == 1.0\n\$VERSION = 2.3\n]                     => '2.3',
41                qq[\$Something::VERSION == 1.0\n\$VERSION = 2.3\n\$VERSION = 4.5\n]    => '2.3',
42
43                '$VERSION = sprintf("%d.%03d", q$Revision: 3.74 $ =~ /(\d+)\.(\d+)/);' => '3.074',
44                '$VERSION = substr(q$Revision: 2.8 $, 10) + 2 . "";'                   => '4.8',
45                q[our $VERSION = do { my @r = ( q$Revision: 2.7 $ =~ /\d+/g ); sprintf "%d." . "%02d" x $#r, @r };] => '2.07', # Fucking seriously?
46                'elsif ( $Something::VERSION >= 1.99 )' => undef,
47
48               );
49
50if( $Has_Version ) {
51    $versions{q[use version; $VERSION = qv("1.2.3");]} = qv("1.2.3");
52    $versions{q[$VERSION = qv("1.2.3")]}               = qv("1.2.3");
53    $versions{q[$VERSION = v1.2.3]} = 'v1.2.3';
54}
55
56if( "$]" >= 5.011001 ) {
57    $versions{'package Foo 1.23;'         } = '1.23';
58    $versions{'package Foo::Bar 1.23;'    } = '1.23';
59    $versions{'package Foo v1.2.3;'       } = 'v1.2.3';
60    $versions{'package Foo::Bar v1.2.3;'  } = 'v1.2.3';
61    $versions{' package Foo::Bar 1.23 ;'  } = '1.23';
62    $versions{"package Foo'Bar 1.23;"     } = '1.23';
63    $versions{"package Foo::Bar 1.2.3;"   } = '1.2.3';
64    $versions{'package Foo 1.230;'        } = '1.230';
65    $versions{'package Foo 1.23_01;'      } = '1.23_01';
66    $versions{'package Foo v1.23_01;'     } = 'v1.23_01';
67    $versions{q["package Foo 1.23"]}        = 'undef';
68    $versions{<<'END'}                      = '1.23';
69package Foo 1.23;
70our $VERSION = 2.34;
71END
72
73    $versions{<<'END'}                      = '2.34';
74our $VERSION = 2.34;
75package Foo 1.23;
76END
77
78    $versions{<<'END'}                      = '2.34';
79package Foo::100;
80our $VERSION = 2.34;
81END
82}
83
84if( "$]" >= 5.014 ) {
85    $versions{'package Foo 1.23 { }'         } = '1.23';
86    $versions{'package Foo::Bar 1.23 { }'    } = '1.23';
87    $versions{'package Foo v1.2.3 { }'       } = 'v1.2.3';
88    $versions{'package Foo::Bar v1.2.3 { }'  } = 'v1.2.3';
89    $versions{' package Foo::Bar 1.23 { }'   } = '1.23';
90    $versions{"package Foo'Bar 1.23 { }"     } = '1.23';
91    $versions{"package Foo::Bar 1.2.3 { }"   } = '1.2.3';
92    $versions{'package Foo 1.230 { }'        } = '1.230';
93    $versions{'package Foo 1.23_01 { }'      } = '1.23_01';
94    $versions{'package Foo v1.23_01 { }'     } = 'v1.23_01';
95    $versions{<<'END'}                      = '1.23';
96package Foo 1.23 {
97our $VERSION = 2.34;
98}
99END
100
101    $versions{<<'END'}                      = '2.34';
102our $VERSION = 2.34;
103package Foo 1.23 { }
104END
105
106    $versions{<<'END'}                      = '2.34';
107package Foo::100 {
108our $VERSION = 2.34;
109}
110END
111}
112
113if ( "$]" < 5.012 ) {
114  delete $versions{'$VERSION = -1.0'};
115}
116
117plan tests => (3 * keys %versions) + 4 + grep { !defined} (values %versions);
118
119for my $code ( sort keys %versions ) {
120    my $expect = $versions{$code};
121    (my $label = $code) =~ s/\n/\\n/g;
122    my $warnings = "";
123    local $SIG{__WARN__} = sub { $warnings .= "@_\n"; };
124	if (defined $expect) {
125		is( parse_version_string($code), $expect, $label );
126	} else {
127		my $is_called = 0;
128		no warnings qw[redefine once];
129		local *MM::get_version = sub {
130			$is_called = 1;
131		};
132		ok !$is_called;
133		is( parse_version_string($code), 'undef', $label );
134	}
135    is($warnings, '', "$label does not cause warnings");
136}
137
138
139sub parse_version_string {
140    my $code = shift;
141
142    my ($fh,$file) = tempfile( DIR => '.', UNLINK => 1 );
143    print $fh "$code\n";
144    close $fh;
145
146    $_ = 'foo';
147    my $version = MM->parse_version( $file );
148    is( $_, 'foo', '$_ not leaked by parse_version' );
149
150    return $version;
151}
152
153
154# This is a specific test to see if a version subroutine in the $VERSION
155# declaration confuses later calls to the version class.
156# [rt.cpan.org 30747]
157SKIP: {
158    skip "need version.pm", 4 unless $Has_Version;
159    is parse_version_string(q[ $VERSION = '1.00'; sub version { $VERSION } ]),
160       '1.00', "eval 'sub version {...} in version string";
161    is parse_version_string(q[ use version; $VERSION = version->new("1.2.3") ]),
162       qv("1.2.3"), "version.pm not confused by version sub";
163}
164