1#!/usr/bin/perl -w
2
3use strict;
4use warnings;
5
6BEGIN {
7    unshift @INC, 't/lib';
8}
9chdir 't';
10
11use Test::More;
12use ExtUtils::MakeMaker;
13use File::Temp qw[tempfile];
14
15my $Has_Version = eval 'require version; "version"->import; 1';
16
17# "undef" - means we expect "undef", undef - eval should be never called for this string
18my %versions = (q[$VERSION = '1.00']            => '1.00',
19                q[*VERSION = \'1.01']           => '1.01',
20                q[($VERSION) = q$Revision: 32208 $ =~ /(\d+)/g;] => 32208,
21                q[$FOO::VERSION = '1.10';]      => '1.10',
22                q[*FOO::VERSION = \'1.11';]     => '1.11',
23                '$VERSION = 0.02'               => 0.02,
24                '$VERSION = 0.0'                => 0.0,
25                '$VERSION = -1.0'               => 'undef',
26                '$VERSION = undef'              => 'undef',
27                '$wibble  = 1.0'                => undef,
28                q[my $VERSION = '1.01']         => 'undef',
29                q[local $VERSION = '1.02']      => 'undef',
30                q[local $FOO::VERSION = '1.30'] => 'undef',
31                q[if( $Foo::VERSION >= 3.00 ) {]=> undef,
32                q[our $VERSION = '1.23';]       => '1.23',
33                q[$CGI::VERSION='3.63']         => '3.63',
34                q[$VERSION = "1.627"; # ==> ALSO update the version in the pod text below!] => '1.627',
35                q[BEGIN { our $VERSION = '1.23' }]       => '1.23',
36
37                '$Something::VERSION == 1.0'    => undef,
38                '$Something::VERSION <= 1.0'    => undef,
39                '$Something::VERSION >= 1.0'    => undef,
40                '$Something::VERSION != 1.0'    => undef,
41                'my $meta_coder = ($JSON::XS::VERSION >= 1.4) ?' => undef,
42
43                qq[\$Something::VERSION == 1.0\n\$VERSION = 2.3\n]                     => '2.3',
44                qq[\$Something::VERSION == 1.0\n\$VERSION = 2.3\n\$VERSION = 4.5\n]    => '2.3',
45
46                '$VERSION = sprintf("%d.%03d", q$Revision: 3.74 $ =~ /(\d+)\.(\d+)/);' => '3.074',
47                '$VERSION = substr(q$Revision: 2.8 $, 10) + 2 . "";'                   => '4.8',
48                q[our $VERSION = do { my @r = ( q$Revision: 2.7 $ =~ /\d+/g ); sprintf "%d." . "%02d" x $#r, @r };] => '2.07', # Fucking seriously?
49                'elsif ( $Something::VERSION >= 1.99 )' => undef,
50               );
51
52if( $Has_Version ) {
53    $versions{q[use version; $VERSION = qv("1.2.3");]} = qv("1.2.3");
54    $versions{q[$VERSION = qv("1.2.3")]}               = qv("1.2.3");
55    $versions{q[$VERSION = v1.2.3]} = 'v1.2.3';
56}
57
58if( "$]" >= 5.011001 ) {
59    $versions{'package Foo 1.23;'         } = '1.23';
60    $versions{'package Foo::Bar 1.23;'    } = '1.23';
61    $versions{'package Foo v1.2.3;'       } = 'v1.2.3';
62    $versions{'package Foo::Bar v1.2.3;'  } = 'v1.2.3';
63    $versions{' package Foo::Bar 1.23 ;'  } = '1.23';
64    $versions{"package Foo'Bar 1.23;"     } = '1.23';
65    $versions{'package Foo 1.230;'        } = '1.230';
66    $versions{q["package Foo 1.23"]}        = undef;
67    $versions{q[our $VERSION = "1.00 / the fucking fuck";]} = 'undef';
68    $versions{<<'END'}                      = '1.23';
69package Foo 1.23;
70our $VERSION = 2.34;
71END
72
73    $versions{<<'END'}                      = '2.34';
74our $VERSION = 2.34;
75package Foo 1.23;
76END
77
78    $versions{<<'END'}                      = '2.34';
79package Foo::100;
80our $VERSION = 2.34;
81END
82}
83
84if( "$]" >= 5.014 ) {
85    $versions{'package Foo 1.23 { }'         } = '1.23';
86    $versions{'package Foo::Bar 1.23 { }'    } = '1.23';
87    $versions{'package Foo v1.2.3 { }'       } = 'v1.2.3';
88    $versions{'package Foo::Bar v1.2.3 { }'  } = 'v1.2.3';
89    $versions{' package Foo::Bar 1.23 { }'   } = '1.23';
90    $versions{"package Foo'Bar 1.23 { }"     } = '1.23';
91    $versions{'package Foo 1.230 { }'        } = '1.230';
92    $versions{<<'END'}                      = '1.23';
93package Foo 1.23 {
94our $VERSION = 2.34;
95}
96END
97
98    $versions{<<'END'}                      = '2.34';
99our $VERSION = 2.34;
100package Foo 1.23 { }
101END
102
103    $versions{<<'END'}                      = '2.34';
104package Foo::100 {
105our $VERSION = 2.34;
106}
107END
108}
109
110if ( "$]" < 5.012 ) {
111  delete $versions{'$VERSION = -1.0'};
112}
113
114plan tests => (3 * keys %versions) + 4 + grep { !defined} (values %versions);
115
116for my $code ( sort keys %versions ) {
117    my $expect = $versions{$code};
118    (my $label = $code) =~ s/\n/\\n/g;
119    my $warnings = "";
120    local $SIG{__WARN__} = sub { $warnings .= "@_\n"; };
121	if (defined $expect) {
122		is( parse_version_string($code), $expect, $label );
123	} else {
124		my $is_called = 0;
125		no warnings qw[redefine once];
126		local *MM::get_version = sub {
127			$is_called = 1;
128		};
129		ok !$is_called;
130		is( parse_version_string($code), 'undef', $label );
131	}
132    is($warnings, '', "$label does not cause warnings");
133}
134
135
136sub parse_version_string {
137    my $code = shift;
138
139    my ($fh,$file) = tempfile( DIR => '.', UNLINK => 1 );
140    print $fh "$code\n";
141    close $fh;
142
143    $_ = 'foo';
144    my $version = MM->parse_version( $file );
145    is( $_, 'foo', '$_ not leaked by parse_version' );
146
147    return $version;
148}
149
150
151# This is a specific test to see if a version subroutine in the $VERSION
152# declaration confuses later calls to the version class.
153# [rt.cpan.org 30747]
154SKIP: {
155    skip "need version.pm", 4 unless $Has_Version;
156    is parse_version_string(q[ $VERSION = '1.00'; sub version { $VERSION } ]),
157       '1.00', "eval 'sub version {...} in version string";
158    is parse_version_string(q[ use version; $VERSION = version->new("1.2.3") ]),
159       qv("1.2.3"), "version.pm not confused by version sub";
160}
161