xref: /openbsd/gnu/usr.bin/perl/cpan/HTTP-Tiny/t/100_get.t (revision 4cfece93) 
1#!perl
2
3use strict;
4use warnings;
5
6use File::Basename;
7use Test::More 0.88;
8use lib 't';
9use Util qw[tmpfile rewind slurp monkey_patch dir_list parse_case
10  hashify connect_args set_socket_source sort_headers $CRLF $LF];
11
12use HTTP::Tiny;
13BEGIN { monkey_patch() }
14
15for my $file ( dir_list("corpus", qr/^get/ ) ) {
16  my $label = basename($file);
17  my $data = do { local (@ARGV,$/) = $file; <> };
18  my ($params, $expect_req, $give_res) = split /--+\n/, $data;
19  my $case = parse_case($params);
20
21  my $url = $case->{url}[0];
22  my %headers = hashify( $case->{headers} );
23  my %new_args = hashify( $case->{new_args} );
24
25  my %options;
26  $options{headers} = \%headers if %headers;
27  if ( $case->{data_cb} ) {
28    $main::data = '';
29    $options{data_callback} = eval join "\n", @{$case->{data_cb}};
30    die unless ref( $options{data_callback} ) eq 'CODE';
31  }
32
33  my $version = HTTP::Tiny->VERSION || 0;
34  my $agent = $new_args{agent} || "HTTP-Tiny/$version";
35
36  # cleanup source data
37  $expect_req =~ s{HTTP-Tiny/VERSION}{$agent};
38  s{\n}{$CRLF}g for ($expect_req, $give_res);
39
40  # setup mocking and test
41  my $res_fh = tmpfile($give_res);
42  my $req_fh = tmpfile();
43
44  my $http = HTTP::Tiny->new(keep_alive => 0, %new_args);
45  set_socket_source($req_fh, $res_fh);
46
47  (my $url_basename = $url) =~ s{.*/}{};
48
49  my @call_args = %options ? ($url, \%options) : ($url);
50  my $response  = $http->get(@call_args);
51
52  my ($got_host, $got_port) = connect_args();
53  my ($exp_host, $exp_port) = (
54    ($new_args{proxy} || $url ) =~ m{^http://([^:/]+?):?(\d*)/}g
55  );
56  $exp_host ||= 'localhost';
57  $exp_port ||= 80;
58
59  my $got_req = slurp($req_fh);
60
61  is ($got_host, $exp_host, "$label host $exp_host");
62  is ($got_port, $exp_port, "$label port $exp_port");
63  is( sort_headers($got_req), sort_headers($expect_req), "$label request data");
64
65  my ($rc) = $give_res =~ m{\S+\s+(\d+)}g;
66  # maybe override
67  $rc = $case->{expected_rc}[0] if defined $case->{expected_rc};
68
69  is( $response->{status}, $rc, "$label response code $rc" )
70    or diag $response->{content};
71
72  if ( substr($rc,0,1) eq '2' ) {
73    ok( $response->{success}, "$label success flag true" );
74  }
75  else {
76    ok( ! $response->{success}, "$label success flag false" );
77  }
78
79  is ( $response->{url}, $url, "$label response URL" );
80
81  if (defined $case->{expected_headers}) {
82    my %expected = hashify( $case->{expected_headers} );
83    is_deeply($response->{headers}, \%expected, "$label expected headers");
84  }
85
86  my $check_expected = $case->{expected_like}
87    ?  sub {
88        my ($text, $msg) = @_;
89        like( $text, "/".$case->{expected_like}[0]."/", $msg );
90      }
91    : sub {
92        my ($text, $msg) = @_;
93        my $exp_content =
94          $case->{expected} ? join("$CRLF", @{$case->{expected}}, '') : '';
95        is ( $text, $exp_content, $msg );
96      }
97    ;
98
99
100
101  if ( $options{data_callback} ) {
102    $check_expected->( $main::data, "$label cb got content" );
103    is ( $response->{content}, '', "$label resp content empty" );
104  }
105  else {
106    $check_expected->( $response->{content}, "$label content" );
107  }
108
109  ok ( ! exists $response->{redirects}, "$label redirects array doesn't exist")
110    or diag explain $response->{redirects};
111}
112
113done_testing;
114