1#!perl
2
3use strict;
4use warnings;
5
6use File::Basename;
7use Test::More 0.88;
8use lib 't';
9use Util qw[tmpfile rewind slurp monkey_patch dir_list parse_case
10  hashify connect_args clear_socket_source set_socket_source sort_headers
11  $CRLF $LF];
12
13use HTTP::Tiny;
14BEGIN { monkey_patch() }
15
16for my $file ( dir_list("corpus", qr/^proxy-auth/ ) ) {
17  my $label = basename($file);
18  my $data = do { local (@ARGV,$/) = $file; <> };
19  my ($params, @case_pairs) = split /--+\n/, $data;
20  my $case = parse_case($params);
21
22  my $url = $case->{url}[0];
23  my $method = $case->{method}[0] || 'GET';
24  my %headers = hashify( $case->{headers} );
25  my %new_args = hashify( $case->{new_args} );
26
27  my %options;
28  $options{headers} = \%headers if %headers;
29  my $call_args = %options ? [$method, $url, \%options] : [$method, $url];
30
31  my $version = HTTP::Tiny->VERSION || 0;
32  my $agent = $new_args{agent} || "HTTP-Tiny/$version";
33
34  my (@socket_pairs);
35  while ( @case_pairs ) {
36    my ($expect_req, $give_res) = splice( @case_pairs, 0, 2 );
37    # cleanup source data
38    $expect_req =~ s{HTTP-Tiny/VERSION}{$agent};
39    s{\n}{$CRLF}g for ($expect_req, $give_res);
40
41    # setup mocking and test
42    my $req_fh = tmpfile();
43    my $res_fh = tmpfile($give_res);
44
45    push @socket_pairs, [$req_fh, $res_fh, $expect_req];
46  }
47
48  clear_socket_source();
49  set_socket_source(@$_) for @socket_pairs;
50
51  my $http = HTTP::Tiny->new(keep_alive => 0, %new_args);
52  my $response  = $http->request(@$call_args);
53
54  my $calls = 0
55    + (defined($new_args{max_redirect}) ? $new_args{max_redirect} : 5);
56
57  for my $i ( 0 .. $calls ) {
58    last unless @socket_pairs;
59    my ($req_fh, $res_fh, $expect_req) = @{ shift @socket_pairs };
60    my $got_req = slurp($req_fh);
61    is( sort_headers($got_req), sort_headers($expect_req), "$label request ($i)");
62    $i++;
63  }
64
65  my $exp_content = $case->{expected}
66                  ? join("$CRLF", @{$case->{expected}}) : '';
67
68  is ( $response->{content}, $exp_content, "$label content" );
69
70  if ( $case->{expected_url} ) {
71    is ( $response->{url}, $case->{expected_url}[0], "$label response URL" );
72  }
73
74}
75
76done_testing;
77