1/* $OpenBSD: ldscript.arm64,v 1.3 2021/05/15 14:20:11 kettenis Exp $ */
2
3ENTRY(_start)
4SECTIONS
5{
6  /* Read-only sections, merged into text segment: */
7  . = 0;
8  ImageBase = .;
9  .text		: {
10    *(.peheader)
11    *(.text .stub .text.* .gnu.linkonce.t.*)
12    /* .gnu.warning sections are handled specially by elf32.em. */
13    *(.gnu.warning)
14    *(.plt)
15  } =0xD4200000
16  . = ALIGN(16);
17  .data		: {
18    *(.rodata .rodata.* .gnu.linkonce.r.*)
19    *(.rodata1)
20    *(.sdata2 .sdata2.* .gnu.linkonce.s2.*)
21    *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*)
22    *(.opd)
23    *(.data .data.* .gnu.linkonce.d.*)
24    *(.data1)
25    *(.plabel)
26
27    . = ALIGN(16);
28    __bss_start = .;
29    *(.sbss .sbss.* .gnu.linkonce.sb.*)
30    *(.scommon)
31    *(.dynbss)
32    *(.bss *.bss.*)
33    *(COMMON)
34    . = ALIGN(16);
35    __bss_end = .;
36  }
37  . = ALIGN(16);
38  set_Xcommand_set	: {
39    __start_set_Xcommand_set = .;
40    *(set_Xcommand_set)
41    __stop_set_Xcommand_set = .;
42  }
43  set_Xficl_compile_set	: {
44    __start_set_Xficl_compile_set = .;
45    *(set_Xficl_compile_set)
46    __stop_set_Xficl_compile_set = .;
47  }
48  . = ALIGN(16);
49  __gp = .;
50  .sdata	: {
51    *(.got.plt .got)
52    *(.sdata .sdata.* .gnu.linkonce.s.*)
53    *(dynsbss)
54    *(.scommon)
55  }
56  . = ALIGN(16);
57  .dynamic	: { *(.dynamic) }
58  . = ALIGN(16);
59  .rela.dyn	: {
60    *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*)
61    *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*)
62    *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*)
63    *(.rela.got)
64    *(.rela.sdata .rela.sdata.* .rela.gnu.linkonce.s.*)
65    *(.rela.sbss .rela.sbss.* .rela.gnu.linkonce.sb.*)
66    *(.rela.sdata2 .rela.sdata2.* .rela.gnu.linkonce.s2.*)
67    *(.rela.sbss2 .rela.sbss2.* .rela.gnu.linkonce.sb2.*)
68    *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*)
69    *(.rela.plt)
70    *(.relset_*)
71    *(.rela.dyn .rela.dyn.*)
72  }
73  . = ALIGN(16);
74  .reloc	: { *(.reloc) }
75  . = ALIGN(16);
76  .dynsym	: { *(.dynsym) }
77  .dynstr	: { *(.dynstr) }
78  _edata = .;
79
80  /* Unused sections */
81  .hash		: { *(.hash) }
82}
83