1# ex:ts=8 sw=4:
2# $OpenBSD: PackageRepositoryList.pm,v 1.32 2020/02/19 14:22:29 espie Exp $
3#
4# Copyright (c) 2003-2006 Marc Espie <espie@openbsd.org>
5#
6# Permission to use, copy, modify, and distribute this software for any
7# purpose with or without fee is hereby granted, provided that the above
8# copyright notice and this permission notice appear in all copies.
9#
10# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
11# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
12# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
13# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
14# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
15# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
16# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
17
18use strict;
19use warnings;
20
21package OpenBSD::PackageRepositoryList;
22
23sub new
24{
25	my ($class, $state) = @_;
26	return bless {l => [], k => {}, state => $state}, $class;
27}
28
29sub filter_new
30{
31	my $self = shift;
32	my @l = ();
33	for my $r (@_) {
34		next if !defined $r;
35		next if $self->{k}{$r};
36		$self->{k}{$r} = 1;
37		push @l, $r;
38	}
39	return @l;
40}
41
42sub add
43{
44	my $self = shift;
45	push @{$self->{l}}, $self->filter_new(@_);
46}
47
48sub prepend
49{
50	my $self = shift;
51	unshift @{$self->{l}}, $self->filter_new(@_);
52}
53
54sub do_something
55{
56	my ($self, $do, $pkgname, @args) = @_;
57	if (defined $pkgname && $pkgname eq '-') {
58		return OpenBSD::PackageRepository->pipe->new($self->{state})->$do($pkgname, @args);
59	}
60	for my $repo (@{$self->{l}}) {
61		my $r = $repo->$do($pkgname, @args);
62		return $r if defined $r;
63	}
64	return undef;
65}
66
67sub find
68{
69	my ($self, @args) = @_;
70
71	return $self->do_something('find', @args);
72}
73
74sub grabPlist
75{
76	my ($self, @args) = @_;
77	return $self->do_something('grabPlist', @args);
78}
79
80sub match_locations
81{
82	my ($self, @search) = @_;
83	my $result = [];
84	for my $repo (@{$self->{l}}) {
85		my $l = $repo->match_locations(@search);
86		if ($search[0]->{keep_all}) {
87			push(@$result, @$l);
88		} elsif (@$l > 0) {
89			return $l;
90		}
91	}
92	return $result;
93}
94
951;
96