1# ex:ts=8 sw=4:
2# $OpenBSD: SharedLibs.pm,v 1.59 2017/09/16 12:04:13 espie Exp $
3#
4# Copyright (c) 2003-2010 Marc Espie <espie@openbsd.org>
5#
6# Permission to use, copy, modify, and distribute this software for any
7# purpose with or without fee is hereby granted, provided that the above
8# copyright notice and this permission notice appear in all copies.
9#
10# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
11# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
12# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
13# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
14# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
15# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
16# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
17
18use strict;
19use warnings;
20
21use OpenBSD::Paths;
22use OpenBSD::LibSpec;
23
24package OpenBSD::PackingElement;
25
26sub mark_available_lib
27{
28}
29
30package OpenBSD::PackingElement::Lib;
31
32sub mark_available_lib
33{
34	my ($self, $pkgname, $state) = @_;
35	OpenBSD::SharedLibs::register_libname($self->fullname,
36	    $pkgname, $state);
37}
38
39package OpenBSD::SharedLibs;
40use File::Basename;
41use OpenBSD::Error;
42
43our $repo = OpenBSD::LibRepo->new;
44
45sub register_library
46{
47	my ($lib, $pkgname) = @_;
48	$repo->register($lib, $pkgname);
49}
50
51sub register_libname
52{
53	my ($name, $pkgname, $state) = @_;
54	my $lib = OpenBSD::Library->from_string($name);
55	if ($lib->is_valid) {
56		register_library($lib, $pkgname);
57	} else {
58		$state->errsay("Bogus library in #1: #2", $pkgname, $name)
59		    unless $pkgname eq 'system';
60	}
61
62}
63
64sub find_best
65{
66	my ($class, $stem) = @_;
67	return $repo->find_best($stem);
68}
69
70my $done_plist = {};
71
72sub system_dirs
73{
74	return OpenBSD::Paths->library_dirs;
75}
76
77sub add_libs_from_system
78{
79	my ($destdir, $state) = @_;
80	return if $done_plist->{'system'};
81	$done_plist->{'system'} = 1;
82	for my $dirname (system_dirs()) {
83		opendir(my $dir, $destdir.$dirname."/lib") or next;
84		while (my $d = readdir($dir)) {
85			next unless $d =~ m/\.so/;
86			register_libname("$dirname/lib/$d", 'system', $state);
87		}
88		closedir($dir);
89	}
90}
91
92sub add_libs_from_installed_package
93{
94	my ($pkgname, $state) = @_;
95	return if $done_plist->{$pkgname};
96	$done_plist->{$pkgname} = 1;
97	my $plist = OpenBSD::PackingList->from_installation($pkgname,
98	    \&OpenBSD::PackingList::LibraryOnly);
99	return if !defined $plist;
100
101	$plist->mark_available_lib($pkgname, $state);
102}
103
104sub add_libs_from_plist
105{
106	my ($plist, $state) = @_;
107	my $pkgname = $plist->pkgname;
108	return if $done_plist->{$pkgname};
109	$done_plist->{$pkgname} = 1;
110	$plist->mark_available_lib($pkgname, $state);
111}
112
113sub lookup_libspec
114{
115	my ($base, $spec) = @_;
116	return $spec->lookup($repo, $base);
117}
118
119my $printed = {};
120
121sub report_problem
122{
123	my ($state, $spec) = @_;
124	my $name = $spec->to_string;
125	my $base = $state->{localbase};
126	my $approx = $spec->lookup_stem($repo);
127
128	my $r = "";
129	if (!$spec->is_valid) {
130		$r = "| bad library specification\n";
131	} elsif (!defined $approx) {
132 		$r = "| not found anywhere\n";
133	} else {
134		for my $bad (sort {$a->compare($b)} @$approx) {
135			my $ouch = $spec->no_match($bad, $base);
136			$ouch //= "not reachable";
137			$r .= "| ".$bad->to_string." (".$bad->origin."): ".
138			    $ouch."\n";
139		}
140	}
141	if (!defined $printed->{$name} || $printed->{$name} ne $r) {
142		$printed->{$name} = $r;
143		$state->errsay("|library #1 not found", $name);
144		$state->print("#1", $r);
145	}
146}
147
1481;
149