1 /*	e.y	(CWI)	1.2	85/03/22	*/
2 %{#
3 #include "e.h"
4 #
5 int	fromflg;
6 %}
7 %term	CONTIG QTEXT SPACE THIN TAB
8 %term	MATRIX LCOL CCOL RCOL COL
9 %term	MARK LINEUP
10 %term	SUM INT PROD UNION INTER
11 %term	LPILE PILE CPILE RPILE ABOVE
12 %term	DEFINE TDEFINE NDEFINE DELIM GSIZE GFONT INCLUDE SPACE
13 %right	FROM TO
14 %left	OVER SQRT
15 %right	SUP SUB
16 %right	SIZE FONT ROMAN ITALIC BOLD FAT
17 %right	UP DOWN BACK FWD
18 %left	LEFT RIGHT
19 %right	DOT DOTDOT HAT TILDE BAR UNDER VEC DYAD UTILDE
20 
21 %%
22 
23 stuff	: eqn 	{ putout($1); }
24 	| error	{ error(FATAL, "syntax error"); }
25 	|	{ eqnreg = 0; }
26 	;
27 
28 eqn	: box
29 	| eqn box	{ eqnbox($1, $2, 0); }
30 	| eqn lineupbox	{ eqnbox($1, $2, 1); }
31 	| LINEUP	{ lineup(0); }
32 	;
33 
34 lineupbox: LINEUP box	{ $$ = $2; lineup(1); }
35 	;
36 
37 matrix	: MATRIX	{ $$ = ct; } ;
38 
39 collist	: column
40 	| collist column
41 	;
42 
43 column	: lcol '{' list '}'	{ column('L', $1); }
44 	| ccol '{' list '}'	{ column('C', $1); }
45 	| rcol '{' list '}'	{ column('R', $1); }
46 	| col '{' list '}'	{ column('-', $1); }
47 	;
48 
49 lcol	: LCOL		{ $$ = ct++; } ;
50 ccol	: CCOL		{ $$ = ct++; } ;
51 rcol	: RCOL		{ $$ = ct++; } ;
52 col	: COL		{ $$ = ct++; } ;
53 
54 sbox	: sup box	%prec SUP	{ $$ = $2; }
55 	;
56 
57 tbox	: to box	%prec TO	{ $$ = $2; }
58 	|		%prec FROM	{ $$ = 0; }
59 	;
60 
61 box	: box OVER box	{ boverb($1, $3); }
62 	| MARK box	{ mark($2); }
63 	| size box	%prec SIZE	{ size($1, $2); }
64 	| font box	%prec FONT	{ font($1, $2); }
65 	| FAT box	{ fatbox($2); }
66 	| SQRT box	{ sqrt($2); }
67 	| lpile '{' list '}'	{ lpile('L', $1, ct); ct = $1; }
68 	| cpile '{' list '}'	{ lpile('C', $1, ct); ct = $1; }
69 	| rpile '{' list '}'	{ lpile('R', $1, ct); ct = $1; }
70 	| pile '{' list '}'	{ lpile('-', $1, ct); ct = $1; }
71 	| box sub box sbox	%prec SUB	{ shift2($1, $3, $4); }
72 	| box sub box		%prec SUB	{ bshiftb($1, $2, $3); }
73 	| box sup box		%prec SUP	{ bshiftb($1, $2, $3); }
74 	| int sub box sbox	%prec SUB	{ integral($1, $3, $4); }
75 	| int sub box		%prec SUB	{ integral($1, $3, 0); }
76 	| int sup box		%prec SUP	{ integral($1, 0, $3); }
77 	| int					{ integral($1, 0, 0); }
78 	| left eqn right	{ paren($1, $2, $3); }
79 	| pbox
80 	| box from box tbox	%prec FROM	{ fromto($1, $3, $4); fromflg=0; }
81 	| box to box	%prec TO	{ fromto($1, 0, $3); }
82 	| box diacrit	{ diacrit($1, $2); }
83 	| fwd box	%prec UP	{ move(FWD, $1, $2); }
84 	| up box	%prec UP	{ move(UP, $1, $2); }
85 	| back box	%prec UP	{ move(BACK, $1, $2); }
86 	| down box	%prec UP	{ move(DOWN, $1, $2); }
87 	| matrix '{' collist '}'	{ matrix($1); }
88 	;
89 
90 int	: INT	{ setintegral(); }
91 	;
92 
93 fwd	: FWD text	{ $$ = atoi((char *) $1); } ;
94 up	: UP text	{ $$ = atoi((char *) $1); } ;
95 back	: BACK text	{ $$ = atoi((char *) $1); } ;
96 down	: DOWN text	{ $$ = atoi((char *) $1); } ;
97 
98 diacrit	: HAT	{ $$ = HAT; }
99 	| VEC	{ $$ = VEC; }
100 	| DYAD	{ $$ = DYAD; }
101 	| BAR	{ $$ = BAR; }
102 	| UNDER	{ $$ = UNDER; }	/* under bar */
103 	| DOT	{ $$ = DOT; }
104 	| TILDE	{ $$ = TILDE; }
105 	| UTILDE	{ $$ = UTILDE; }
106 	| DOTDOT	{ $$ = DOTDOT; } /* umlaut = double dot */
107 	;
108 
109 from	: FROM	{ $$=ps; ps -= 3; fromflg = 1;
110 		if(dbg)printf(".\tfrom: old ps %d, new ps %d, fflg %d\n", $$, ps, fromflg);
111 		}
112 	;
113 
114 to	: TO	{ $$=ps; if(fromflg==0)ps -= 3;
115 			if(dbg)printf(".\tto: old ps %d, new ps %d\n", $$, ps);
116 		}
117 	;
118 
119 left	: LEFT text	{ $$ = ((char *)$2)[0]; }
120 	| LEFT '{'	{ $$ = '{'; }
121 	;
122 
123 right	: RIGHT text	{ $$ = ((char *)$2)[0]; }
124 	| RIGHT '}'	{ $$ = '}'; }
125 	|		{ $$ = 0; }
126 	;
127 
128 list	: eqn	{ lp[ct++] = $1; }
129 	| list ABOVE eqn	{ lp[ct++] = $3; }
130 	;
131 
132 lpile	: LPILE	{ $$ = ct; } ;
133 cpile	: CPILE	{ $$ = ct; } ;
134 pile	: PILE	{ $$ = ct; } ;
135 rpile	: RPILE	{ $$ = ct; } ;
136 
137 size	: SIZE text	{ $$ = ps; setsize((char *) $2); }
138 	;
139 
140 font	: ROMAN		{ setfont(ROM); }
141 	| ITALIC	{ setfont(ITAL); }
142 	| BOLD		{ setfont(BLD); }
143 	| FONT text	{ setfont(((char *)$2)[0]); }
144 	;
145 
146 sub	: SUB	{ shift(SUB); }
147 	;
148 
149 sup	: SUP	{ shift(SUP); }
150 	;
151 
152 pbox	: '{' eqn '}'	{ $$ = $2; }
153 	| QTEXT		{ text(QTEXT, (char *) $1); }
154 	| CONTIG	{ text(CONTIG, (char *) $1); }
155 	| SPACE		{ text(SPACE, 0); }
156 	| THIN		{ text(THIN, 0); }
157 	| TAB		{ text(TAB, 0); }
158 	| SUM		{ funny(SUM); }
159 	| PROD		{ funny(PROD); }
160 	| UNION		{ funny(UNION); }
161 	| INTER		{ funny(INTER); }	/* intersection */
162 	;
163 
164 text	: CONTIG
165 	| QTEXT
166 	;
167 
168 %%
169