xref: /original-bsd/usr.sbin/sendmail/cf/m4/cf.m4 (revision 29e78bed) 
1divert(0)dnl
2#
3# Copyright (c) 1983 Eric P. Allman
4# Copyright (c) 1988 The Regents of the University of California.
5# All rights reserved.
6#
7# %sccs.include.redist.sh%
8#
9
10
11######################################################################
12######################################################################
13#####
14#####		SENDMAIL CONFIGURATION FILE
15#####
16define(`TEMPFILE', maketemp(/tmp/cfXXXXXX))dnl
17syscmd(sh ../sh/makeinfo.sh > TEMPFILE)dnl
18include(TEMPFILE)dnl
19syscmd(rm -f TEMPFILE)dnl
20#####
21######################################################################
22######################################################################
23
24divert(-1)
25
26changecom()
27ifdef(`pushdef', `',
28	`errprint(`You need a newer version of M4, at least as new as
29System V or GNU')
30	include(NoSuchFile)')
31define(`PUSHDIVERT', `pushdef(`__D__', divnum)divert($1)')
32define(`POPDIVERT', `divert(__D__)popdef(`__D__')')
33define(`OSTYPE', `include(../ostype/$1.m4)')
34define(`MAILER',
35`ifdef(`_MAILER_$1_', `dnl`'',
36`define(`_MAILER_$1_', `')PUSHDIVERT(7)include(../mailer/$1.m4)POPDIVERT`'')')
37define(`DOMAIN', `include(../domain/$1.m4)')
38define(`FEATURE', `include(../feature/$1.m4)')
39define(`HACK', `include(../hack/$1.m4)')
40define(`OLDSENDMAIL', `define(`_OLD_SENDMAIL_', `')')
41define(`VERSIONID', ``#####  $1  #####'')
42define(`LOCAL_RULE_3', `divert(2)')
43define(`LOCAL_RULE_0', `divert(3)')
44define(`LOCAL_CONFIG', `divert(6)')
45define(`LOCAL_NET_CONFIG', `define(`_LOCAL_RULES_', 1)divert(1)')
46define(`UUCPSMTP', `R DOL(*) < @ $1 .UUCP > DOL(*)	DOL(1) < @ $2 > DOL(2)')
47define(`CONCAT', `$1$2$3$4$5$6$7')
48define(`DOL', ``$'$1')
49define(`SITECONFIG',
50`CONCAT(D, $3, $2)
51define(`_CLASS_$3_', `')dnl
52ifelse($3, U, Cw$2, `dnl')
53define(`SITE', `ifelse(CONCAT($'2`, $3), SU,
54		CONCAT(CY, $'1`),
55		CONCAT(C, $3, $'1`))')
56sinclude(../siteconfig/$1.m4)')
57define(`EXPOSED_USER', `PUSHDIVERT(5)CE$1
58POPDIVERT`'dnl')
59define(`LOCAL_USER', `PUSHDIVERT(5)CL$1
60POPDIVERT`'dnl')
61define(`MASQUERADE_AS', `define(`MASQUERADE_NAME', $1)')
62
63m4wrap(`include(`../m4/proto.m4')')
64
65# set up default values for options
66define(`confMAILER_NAME', ``MAILER-DAEMON'')
67define(`confFROM_LINE', `From $?<$<$|$g$.  $d')
68define(`confOPERATORS', `.:%@!^/[]')
69define(`confSMTP_LOGIN_MSG', `$j Sendmail $v/$Z ready at $b')
70define(`confEIGHT_BIT_INPUT', `False')
71define(`confALIAS_WAIT', `10')
72define(`confMIN_FREE_BLOCKS', `4')
73define(`confBLANK_SUB', `.')
74define(`confCON_EXPENSIVE', `False')
75define(`confCHECKPOINT_INTERVAL', `10')
76define(`confDELIVERY_MODE', `background')
77define(`confAUTO_REBUILD', `False')
78define(`confSAVE_FROM_LINES', `False')
79define(`confTEMP_FILE_MODE', `0600')
80define(`confMATCH_GECOS', `False')
81define(`confDEF_GROUP_ID', `1')
82define(`confMAX_HOP', `17')
83define(`confIGNORE_DOTS', `False')
84define(`confBIND_OPTS', `')
85define(`confMCI_CACHE_SIZE', `2')
86define(`confMCI_CACHE_TIMEOUT', `5m')
87define(`confLOG_LEVEL', `9')
88define(`confME_TOO', `False')
89define(`confCHECK_ALIASES', `True')
90define(`confOLD_STYLE_HEADERS', `True')
91define(`confPRIVACY_FLAGS', `public')
92define(`confSAFE_QUEUE', `True')
93define(`confMESSAGE_TIMEOUT', `5d')
94define(`confTIME_ZONE', `USE_SYSTEM')
95define(`confDEF_USER_ID', `1')
96define(`confQUEUE_LA', `8')
97define(`confREFUSE_LA', `12')
98define(`confSEPARATE_PROC', `False')
99
100divert(0)dnl
101VERSIONID(`@(#)cf.m4	6.7 (Berkeley) 02/24/93')
102