xref: /original-bsd/usr.sbin/sendmail/cf/m4/cf.m4 (revision 948d00a2) 
1divert(0)dnl
2#
3# Copyright (c) 1983 Eric P. Allman
4# Copyright (c) 1988, 1993
5#	The Regents of the University of California.  All rights reserved.
6#
7# %sccs.include.redist.sh%
8#
9
10
11######################################################################
12######################################################################
13#####
14#####		SENDMAIL CONFIGURATION FILE
15#####
16define(`TEMPFILE', maketemp(/tmp/cfXXXXXX))dnl
17syscmd(sh ../sh/makeinfo.sh > TEMPFILE)dnl
18include(TEMPFILE)dnl
19syscmd(rm -f TEMPFILE)dnl
20#####
21######################################################################
22######################################################################
23
24divert(-1)
25
26changecom()
27undefine(`format')
28undefine(`hpux')
29ifdef(`pushdef', `',
30	`errprint(`You need a newer version of M4, at least as new as
31System V or GNU')
32	include(NoSuchFile)')
33define(`PUSHDIVERT', `pushdef(`__D__', divnum)divert($1)')
34define(`POPDIVERT', `divert(__D__)popdef(`__D__')')
35define(`OSTYPE', `PUSHDIVERT(-1)define(`_ARG_', $2)include(../ostype/$1.m4)POPDIVERT`'')
36define(`MAILER',
37`ifdef(`_MAILER_$1_', `dnl`'',
38`define(`_MAILER_$1_', `')PUSHDIVERT(7)include(../mailer/$1.m4)POPDIVERT`'')')
39define(`DOMAIN', `PUSHDIVERT(-1)define(`_ARG_', $2)include(../domain/$1.m4)POPDIVERT`'')
40define(`FEATURE', `PUSHDIVERT(-1)define(`_ARG_', $2)include(../feature/$1.m4)POPDIVERT`'')
41define(`HACK', `PUSHDIVERT(-1)define(`_ARG_', $2)include(../hack/$1.m4)POPDIVERT`'')
42define(`VERSIONID', ``#####  $1  #####'')
43define(`LOCAL_RULE_0', `divert(3)')
44define(`LOCAL_RULE_1',
45`divert(9)dnl
46#######################################
47###  Ruleset 1 -- Sender Rewriting  ###
48#######################################
49
50S1
51')
52define(`LOCAL_RULE_2',
53`divert(9)dnl
54##########################################
55###  Ruleset 2 -- Recipient Rewriting  ###
56##########################################
57
58S2
59')
60define(`LOCAL_RULE_3', `divert(2)')
61define(`LOCAL_CONFIG', `divert(6)')
62define(`LOCAL_NET_CONFIG', `define(`_LOCAL_RULES_', 1)divert(1)')
63define(`DOTTED_USER',
64	`ifdef(`__DOTTED_USER_LIST__',
65		`define(`__DOTTED_USER_LIST__', __DOTTED_USER_LIST__
66CD $1)',
67		`define(`__DOTTED_USER_LIST__', CD $1)')')
68define(`UUCPSMTP', `R DOL(*) < @ $1 .UUCP > DOL(*)	DOL(1) < @ $2 > DOL(2)')
69define(`CONCAT', `$1$2$3$4$5$6$7')
70define(`DOL', ``$'$1')
71define(`SITECONFIG',
72`CONCAT(D, $3, $2)
73define(`_CLASS_$3_', `')dnl
74ifelse($3, U, Cw$2 $2.UUCP, `dnl')
75define(`SITE', `ifelse(CONCAT($'2`, $3), SU,
76		CONCAT(CY, $'1`),
77		CONCAT(C, $3, $'1`))')
78sinclude(../siteconfig/$1.m4)')
79define(`EXPOSED_USER', `PUSHDIVERT(5)CE$1
80POPDIVERT`'dnl')
81define(`LOCAL_USER', `PUSHDIVERT(5)CL$1
82POPDIVERT`'dnl')
83define(`MASQUERADE_AS', `define(`MASQUERADE_NAME', $1)')
84
85m4wrap(`include(`../m4/proto.m4')')
86
87# set up default values for options
88define(`confMAILER_NAME', ``MAILER-DAEMON'')
89define(`confFROM_LINE', `From $g  $d')
90define(`confOPERATORS', `.:%@!^/[]+')
91define(`confSMTP_LOGIN_MSG', `$j Sendmail $v/$Z ready at $b')
92define(`confRECEIVED_HEADER', `$?sfrom $s $.$?_($?s$|from $.$_) $.by $j ($v/$Z)$?r with $r$. id $i$?u for $u$.; $b')
93define(`confSEVEN_BIT_INPUT', `False')
94define(`confEIGHT_BIT_HANDLING', `pass8')
95define(`confALIAS_WAIT', `10')
96define(`confMIN_FREE_BLOCKS', `4')
97define(`confBLANK_SUB', `.')
98define(`confCON_EXPENSIVE', `False')
99define(`confCHECKPOINT_INTERVAL', `10')
100define(`confDELIVERY_MODE', `background')
101define(`confAUTO_REBUILD', `False')
102define(`confSAVE_FROM_LINES', `False')
103define(`confTEMP_FILE_MODE', `0600')
104define(`confMATCH_GECOS', `False')
105define(`confDEF_GROUP_ID', `1')
106define(`confMAX_HOP', `17')
107define(`confIGNORE_DOTS', `False')
108define(`confBIND_OPTS', `')
109define(`confMCI_CACHE_SIZE', `2')
110define(`confMCI_CACHE_TIMEOUT', `5m')
111define(`confUSE_ERRORS_TO', `False')
112define(`confLOG_LEVEL', `9')
113define(`confME_TOO', `False')
114define(`confCHECK_ALIASES', `True')
115define(`confOLD_STYLE_HEADERS', `True')
116define(`confPRIVACY_FLAGS', `authwarnings')
117define(`confDONT_PRUNE_ROUTES', `False')
118define(`confSAFE_QUEUE', `True')
119define(`confMESSAGE_TIMEOUT', `5d/4h')
120define(`confTIME_ZONE', `USE_SYSTEM')
121define(`confDEF_USER_ID', `1')
122define(`confQUEUE_LA', `8')
123define(`confREFUSE_LA', `12')
124define(`confSEPARATE_PROC', `False')
125define(`confCW_FILE', `/etc/sendmail.cw')
126define(`confMIME_FORMAT_ERRORS', `True')
127define(`confTRY_NULL_MX_LIST', `False')
128define(`confSORT_QUEUE_BY_HOST', `False')
129define(`confBROKEN_SMTP_PEERS', `False')
130
131divert(0)dnl
132VERSIONID(`@(#)cf.m4	8.11 (Berkeley) 11/13/94')
133