xref: /qemu/docs/meson.build (revision b83a80e8) 
1if get_option('sphinx_build') == ''
2  sphinx_build = find_program(['sphinx-build-3', 'sphinx-build'],
3                              required: get_option('docs'))
4else
5  sphinx_build = find_program(get_option('sphinx_build'),
6                              required: get_option('docs'))
7endif
8
9# Check if tools are available to build documentation.
10build_docs = false
11if sphinx_build.found()
12  SPHINX_ARGS = ['env', 'CONFDIR=' + qemu_confdir, sphinx_build, '-q']
13  # If we're making warnings fatal, apply this to Sphinx runs as well
14  if get_option('werror')
15    SPHINX_ARGS += [ '-W' ]
16  endif
17
18  # This is a bit awkward but works: create a trivial document and
19  # try to run it with our configuration file (which enforces a
20  # version requirement). This will fail if sphinx-build is too old.
21  run_command('mkdir', ['-p', tmpdir / 'sphinx'], check: true)
22  run_command('touch', [tmpdir / 'sphinx/index.rst'], check: true)
23  sphinx_build_test_out = run_command(SPHINX_ARGS + [
24    '-c', meson.current_source_dir(),
25    '-b', 'html', tmpdir / 'sphinx',
26    tmpdir / 'sphinx/out'], check: false)
27  build_docs = (sphinx_build_test_out.returncode() == 0)
28
29  if not build_docs
30    warning('@0@: @1@'.format(sphinx_build.full_path(), sphinx_build_test_out.stderr()))
31    if get_option('docs').enabled()
32      error('Install a Python 3 version of python-sphinx and the readthedoc theme')
33    endif
34  endif
35endif
36
37if build_docs
38  SPHINX_ARGS += ['-Dversion=' + meson.project_version(), '-Drelease=' + config_host['PKGVERSION']]
39
40  have_ga = have_tools and config_host.has_key('CONFIG_GUEST_AGENT')
41
42  man_pages = {
43        'qemu-ga.8': (have_ga ? 'man8' : ''),
44        'qemu-ga-ref.7': (have_ga ? 'man7' : ''),
45        'qemu-qmp-ref.7': 'man7',
46        'qemu-storage-daemon-qmp-ref.7': (have_tools ? 'man7' : ''),
47        'qemu-img.1': (have_tools ? 'man1' : ''),
48        'qemu-nbd.8': (have_tools ? 'man8' : ''),
49        'qemu-pr-helper.8': (have_tools ? 'man8' : ''),
50        'qemu-storage-daemon.1': (have_tools ? 'man1' : ''),
51        'qemu-trace-stap.1': (stap.found() ? 'man1' : ''),
52        'virtfs-proxy-helper.1': (have_virtfs_proxy_helper ? 'man1' : ''),
53        'virtiofsd.1': (have_virtiofsd ? 'man1' : ''),
54        'qemu.1': 'man1',
55        'qemu-block-drivers.7': 'man7',
56        'qemu-cpu-models.7': 'man7'
57  }
58
59  sphinxdocs = []
60  sphinxmans = []
61
62  private_dir = meson.current_build_dir() / 'manual.p'
63  output_dir = meson.current_build_dir() / 'manual'
64  input_dir = meson.current_source_dir()
65
66  this_manual = custom_target('QEMU manual',
67                build_by_default: build_docs,
68                output: 'docs.stamp',
69                input: files('conf.py'),
70                depfile: 'docs.d',
71                command: [SPHINX_ARGS, '-Ddepfile=@DEPFILE@',
72                          '-Ddepfile_stamp=@OUTPUT0@',
73                          '-b', 'html', '-d', private_dir,
74                          input_dir, output_dir])
75  sphinxdocs += this_manual
76  install_subdir(output_dir, install_dir: qemu_docdir, strip_directory: true)
77
78  these_man_pages = []
79  install_dirs = []
80  foreach page, section : man_pages
81    these_man_pages += page
82    install_dirs += section == '' ? false : get_option('mandir') / section
83  endforeach
84
85  sphinxmans += custom_target('QEMU man pages',
86                              build_by_default: build_docs,
87                              output: these_man_pages,
88                              input: this_manual,
89                              install: build_docs,
90                              install_dir: install_dirs,
91                              command: [SPHINX_ARGS, '-b', 'man', '-d', private_dir,
92                                        input_dir, meson.current_build_dir()])
93
94  alias_target('sphinxdocs', sphinxdocs)
95  alias_target('html', sphinxdocs)
96  alias_target('man', sphinxmans)
97endif
98