xref: /qemu/qga/meson.build (revision 4ac2ee19) 
1qga_qapi_outputs = [
2  'qga-qapi-commands.c',
3  'qga-qapi-commands.h',
4  'qga-qapi-emit-events.c',
5  'qga-qapi-emit-events.h',
6  'qga-qapi-events.c',
7  'qga-qapi-events.h',
8  'qga-qapi-init-commands.c',
9  'qga-qapi-init-commands.h',
10  'qga-qapi-introspect.c',
11  'qga-qapi-introspect.h',
12  'qga-qapi-types.c',
13  'qga-qapi-types.h',
14  'qga-qapi-visit.c',
15  'qga-qapi-visit.h',
16]
17
18qga_qapi_files = custom_target('QGA QAPI files',
19                               output: qga_qapi_outputs,
20                               input: 'qapi-schema.json',
21                               command: [ qapi_gen, '-o', 'qga', '-p', 'qga-', '@INPUT0@' ],
22                               depend_files: qapi_gen_depends)
23
24qga_ss = ss.source_set()
25i = 0
26foreach output: qga_qapi_outputs
27  qga_ss.add(qga_qapi_files[i])
28  i = i + 1
29endforeach
30
31qga_ss.add(files(
32  'commands.c',
33  'guest-agent-command-state.c',
34  'main.c',
35))
36qga_ss.add(when: 'CONFIG_POSIX', if_true: files(
37  'channel-posix.c',
38  'commands-posix.c'))
39qga_ss.add(when: 'CONFIG_WIN32', if_true: files(
40  'channel-win32.c',
41  'commands-win32.c',
42  'service-win32.c',
43  'vss-win32.c'
44))
45
46qga_ss = qga_ss.apply(config_host, strict: false)
47
48qga = executable('qemu-ga', qga_ss.sources(),
49                 link_args: config_host['LIBS_QGA'].split(),
50                 dependencies: [qemuutil, libudev],
51                 install: true)
52all_qga = [qga]
53
54if targetos == 'windows'
55  if 'CONFIG_QGA_VSS' in config_host
56    subdir('vss-win32')
57  else
58    gen_tlb = []
59  endif
60
61  wixl = find_program('wixl', required: false)
62  if wixl.found()
63    deps = [gen_tlb, qga]
64    if 'CONFIG_QGA_VSS' in config_host and 'QEMU_GA_MSI_WITH_VSS' in config_host
65      deps += qga_vss
66    endif
67    qga_msi = custom_target('QGA MSI',
68                            input: files('installer/qemu-ga.wxs'),
69                            output: 'qemu-ga-@0@.msi'.format(config_host['ARCH']),
70                            depends: deps,
71                            command: [
72                              'QEMU_GA_VERSION=' + config_host['QEMU_GA_VERSION'],
73                              'QEMU_GA_MANUFACTURER=' + config_host['QEMU_GA_MANUFACTURER'],
74                              'QEMU_GA_DISTRO=' + config_host['QEMU_GA_DISTRO'],
75                              'BUILD_DIR=' + meson.build_root(),
76                              wixl, '-o', '@OUTPUT0@', '@INPUT0@',
77                              config_host['QEMU_GA_MSI_ARCH'].split(),
78                              config_host['QEMU_GA_MSI_WITH_VSS'].split(),
79                              config_host['QEMU_GA_MSI_MINGW_DLL_PATH'].split(),
80                            ])
81    all_qga += [qga_msi]
82    alias_target('msi', qga_msi)
83  endif
84else
85  install_subdir('run', install_dir: get_option('localstatedir'))
86endif
87
88alias_target('qemu-ga', all_qga)
89