xref: /qemu/util/meson.build (revision a0e93dd8) 
1util_ss.add(files('osdep.c', 'cutils.c', 'unicode.c', 'qemu-timer-common.c'))
2util_ss.add(files('thread-context.c'), numa)
3if not config_host_data.get('CONFIG_ATOMIC64')
4  util_ss.add(files('atomic64.c'))
5endif
6if host_os != 'windows'
7  util_ss.add(files('aio-posix.c'))
8  util_ss.add(files('fdmon-poll.c'))
9  if config_host_data.get('CONFIG_EPOLL_CREATE1')
10    util_ss.add(files('fdmon-epoll.c'))
11  endif
12  util_ss.add(files('compatfd.c'))
13  util_ss.add(files('event_notifier-posix.c'))
14  util_ss.add(files('mmap-alloc.c'))
15  freebsd_dep = []
16  if host_os == 'freebsd'
17    freebsd_dep = util
18  endif
19  util_ss.add(files('oslib-posix.c'), freebsd_dep)
20  util_ss.add(files('qemu-thread-posix.c'))
21  util_ss.add(files('memfd.c'))
22  util_ss.add(files('drm.c'))
23else
24  util_ss.add(files('aio-win32.c'))
25  util_ss.add(files('event_notifier-win32.c'))
26  util_ss.add(files('oslib-win32.c'))
27  util_ss.add(files('qemu-thread-win32.c'))
28  util_ss.add(winmm, pathcch)
29endif
30util_ss.add(when: linux_io_uring, if_true: files('fdmon-io_uring.c'))
31if glib_has_gslice
32  util_ss.add(files('qtree.c'))
33endif
34util_ss.add(files('defer-call.c'))
35util_ss.add(files('envlist.c', 'path.c', 'module.c'))
36util_ss.add(files('host-utils.c'))
37util_ss.add(files('bitmap.c', 'bitops.c'))
38util_ss.add(files('fifo8.c'))
39util_ss.add(files('cacheflush.c'))
40util_ss.add(files('error.c', 'error-report.c'))
41util_ss.add(files('qemu-print.c'))
42util_ss.add(files('id.c'))
43util_ss.add(files('qemu-config.c', 'notify.c'))
44util_ss.add(files('qemu-option.c', 'qemu-progress.c'))
45util_ss.add(files('keyval.c'))
46util_ss.add(files('crc32c.c'))
47util_ss.add(files('uuid.c'))
48util_ss.add(files('getauxval.c'))
49util_ss.add(files('rcu.c'))
50if have_membarrier
51  util_ss.add(files('sys_membarrier.c'))
52endif
53util_ss.add(files('log.c'))
54util_ss.add(files('qdist.c'))
55util_ss.add(files('qht.c'))
56util_ss.add(files('qsp.c'))
57util_ss.add(files('range.c'))
58util_ss.add(files('reserved-region.c'))
59util_ss.add(files('stats64.c'))
60util_ss.add(files('systemd.c'))
61util_ss.add(files('transactions.c'))
62util_ss.add(files('guest-random.c'))
63util_ss.add(files('yank.c'))
64util_ss.add(files('int128.c'))
65util_ss.add(files('memalign.c'))
66util_ss.add(files('interval-tree.c'))
67util_ss.add(files('lockcnt.c'))
68
69if have_user
70  util_ss.add(files('selfmap.c'))
71endif
72
73if have_system
74  util_ss.add(files('crc-ccitt.c'))
75  util_ss.add(when: gio, if_true: files('dbus.c'))
76  if host_os == 'linux'
77    util_ss.add(files('userfaultfd.c'))
78  endif
79endif
80
81if have_block or have_ga
82  util_ss.add(files('aiocb.c', 'async.c'))
83  util_ss.add(files('base64.c'))
84  util_ss.add(files('main-loop.c'))
85  util_ss.add(files('qemu-coroutine.c', 'qemu-coroutine-lock.c', 'qemu-coroutine-io.c'))
86  util_ss.add(files(f'coroutine-@coroutine_backend@.c'))
87  util_ss.add(files('thread-pool.c', 'qemu-timer.c'))
88  util_ss.add(files('qemu-sockets.c'))
89endif
90if have_block
91  util_ss.add(files('aio-wait.c'))
92  util_ss.add(files('buffer.c'))
93  util_ss.add(files('bufferiszero.c'))
94  util_ss.add(files('hbitmap.c'))
95  util_ss.add(files('hexdump.c'))
96  util_ss.add(files('iova-tree.c'))
97  util_ss.add(files('iov.c', 'uri.c'))
98  util_ss.add(files('nvdimm-utils.c'))
99  util_ss.add(files('block-helpers.c'))
100  util_ss.add(files('qemu-coroutine-sleep.c'))
101  util_ss.add(files('qemu-co-shared-resource.c'))
102  util_ss.add(files('qemu-co-timeout.c'))
103  util_ss.add(files('readline.c'))
104  util_ss.add(files('throttle.c'))
105  util_ss.add(files('timed-average.c'))
106  if config_host_data.get('CONFIG_INOTIFY1')
107    freebsd_dep = []
108    if host_os == 'freebsd'
109      freebsd_dep = inotify
110    endif
111    util_ss.add(files('filemonitor-inotify.c'), freebsd_dep)
112  else
113    util_ss.add(files('filemonitor-stub.c'))
114  endif
115  if host_os == 'linux'
116    util_ss.add(files('vhost-user-server.c'), vhost_user)
117    util_ss.add(files('vfio-helpers.c'))
118    util_ss.add(files('chardev_open.c'))
119  endif
120endif
121
122if cpu == 'aarch64'
123  util_ss.add(files('cpuinfo-aarch64.c'))
124elif cpu in ['x86', 'x86_64']
125  util_ss.add(files('cpuinfo-i386.c'))
126elif cpu == 'loongarch64'
127  util_ss.add(files('cpuinfo-loongarch.c'))
128elif cpu in ['ppc', 'ppc64']
129  util_ss.add(files('cpuinfo-ppc.c'))
130endif
131