1SOURCES += \
2    $$PWD/RtMidi.cpp
3
4HEADERS += \
5    $$PWD/RtMidi.hpp
6
7win32 {
8    DEFINES += __WINDOWS_MM__
9    LIBS += -lwinmm
10}
11else:macx {
12    DEFINES += __MACOSX_CORE__
13    LIBS += -framework CoreMIDI -framework CoreAudio -framework CoreFoundation
14
15    use_jack {
16        DEFINES += __UNIX_JACK__
17        LIBS += -ljack
18        jack_has_rename {
19            DEFINES += JACK_HAS_PORT_RENAME
20        }
21    }
22}
23else:linux {
24    DEFINES += __LINUX_ALSA__
25    LIBS += -lasound
26
27    use_jack {
28        DEFINES += __UNIX_JACK__
29        LIBS += -ljack
30        jack_has_rename {
31            DEFINES += JACK_HAS_PORT_RENAME
32        }
33    }
34}
35else:bsd {
36    # OSS does not offer MIDI functionalities, only fallback to dummy interface
37    use_alsa {
38        DEFINES += __LINUX_ALSA__
39        LIBS += -lasound
40    }
41    use_jack {
42        DEFINES += __UNIX_JACK__
43        LIBS += -ljack
44        jack_has_rename {
45            DEFINES += JACK_HAS_PORT_RENAME
46        }
47    }
48}
49