1# Copyright 2015 The Kyua Authors.
2# All rights reserved.
3#
4# Redistribution and use in source and binary forms, with or without
5# modification, are permitted provided that the following conditions are
6# met:
7#
8# * Redistributions of source code must retain the above copyright
9#   notice, this list of conditions and the following disclaimer.
10# * Redistributions in binary form must reproduce the above copyright
11#   notice, this list of conditions and the following disclaimer in the
12#   documentation and/or other materials provided with the distribution.
13# * Neither the name of Google Inc. nor the names of its contributors
14#   may be used to endorse or promote products derived from this software
15#   without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29function warn(msg) {
30    print FILENAME "[" FNR "]: " msg > "/dev/stderr"
31    error = 1
32}
33
34BEGIN {
35    skip = 0
36    error = 0
37}
38
39/CHECK_STYLE_DISABLE/ {
40    skip = 1
41    next
42}
43
44/CHECK_STYLE_ENABLE/ {
45    skip = 0
46    next
47}
48
49/CHECK_STYLE_(ENABLE|DISABLE)/ {
50    next
51}
52
53{
54    if (skip)
55        next
56}
57
58/#ifdef/ {
59    warn("Undesired usage of #ifdef; use #if defined()")
60}
61
62/#ifndef/ {
63    warn("Undesired usage of #ifndef; use #if !defined()")
64}
65
66/assert[ \t]*\(/ {
67    warn("Use the macros in sanity.hpp instead of assert");
68}
69
70/#.*include.*assert/ {
71    warn("Do not include assert.h nor cassert");
72}
73
74/std::endl/ {
75    warn("Use \\n instead of std::endl");
76}
77
78/\/\*/ {
79    warn("Do not use C-style comments");
80}
81
82END {
83    if (skip)
84        warn("Missing CHECK_STYLE_ENABLE");
85    if (error)
86        exit 1
87}
88