1# Qt core library codecs module
2
3HEADERS += \
4    codecs/qtextcodec_p.h \
5    codecs/qutfcodec_p.h
6
7SOURCES += \
8    codecs/qutfcodec.cpp
9
10qtConfig(textcodec) {
11    HEADERS += \
12        codecs/qlatincodec_p.h \
13        codecs/qsimplecodec_p.h \
14        codecs/qtextcodec.h
15
16    SOURCES += \
17        codecs/qlatincodec.cpp \
18        codecs/qsimplecodec.cpp \
19        codecs/qtextcodec.cpp
20
21    qtConfig(codecs) {
22        HEADERS += \
23            codecs/qisciicodec_p.h \
24            codecs/qtsciicodec_p.h
25
26        SOURCES += \
27            codecs/qisciicodec.cpp \
28            codecs/qtsciicodec.cpp
29    }
30
31    qtConfig(icu) {
32        HEADERS += \
33            codecs/qicucodec_p.h
34        SOURCES += \
35            codecs/qicucodec.cpp
36    } else {
37        qtConfig(big_codecs) {
38            HEADERS += \
39                codecs/qgb18030codec_p.h \
40                codecs/qeucjpcodec_p.h \
41                codecs/qjiscodec_p.h \
42                codecs/qsjiscodec_p.h \
43                codecs/qeuckrcodec_p.h \
44                codecs/qbig5codec_p.h
45
46            SOURCES += \
47                codecs/qgb18030codec.cpp \
48                codecs/qjpunicode.cpp \
49                codecs/qeucjpcodec.cpp \
50                codecs/qjiscodec.cpp \
51                codecs/qsjiscodec.cpp \
52                codecs/qeuckrcodec.cpp \
53                codecs/qbig5codec.cpp
54        }
55
56        qtConfig(iconv) {
57            HEADERS += codecs/qiconvcodec_p.h
58            SOURCES += codecs/qiconvcodec.cpp
59            QMAKE_USE_PRIVATE += iconv
60        }
61
62        win32 {
63            SOURCES += codecs/qwindowscodec.cpp
64            HEADERS += codecs/qwindowscodec_p.h
65        }
66    }
67}
68