1# Bayou by coolio.
2#
3# Bayou is a new serial vault that can appear in Dungeon, Snake Pits and Lair.
4# There are no monster spawns so it can appear on any depth level.
5#
6# A Bayou level has a 'swampy' atmosphere (because everybody loves Swamp) by
7# placing a large number of ponds and lakes with thick vegetation.
8
9NAME:   serial_bayou
10TAGS:   allow_dup extra luniq_serial decor nolayout_encompass
11DEPTH:  D, Depths, Snake, Lair
12CHANCE: 1%
13{{
14  local c = 4 + crawl.random2(3)*crawl.random2(2)
15  hook("post_place", function()
16    dgn.place_maps{tag="coolio_serial_bayou", count=c}
17  end)
18}}
19
20NAME:   serial_bayou_pond_a
21TAGS:   coolio_serial_bayou allow_dup extra decor
22DEPTH:  D, Depths, Snake, Lair
23MONS:   plant
24SUBST:  ? = .WW2
25SUBST:  1 = 11.t
26SUBST:  2 = t
27MAP
28    1..1..1
29   1..1??....1
30 .1..??2W?...1
311..1?2WWWW1.1
32...??WWWW?..1
33.1.?WW2W?.11
34 ..1??W?..1
35   ..11..1
36ENDMAP
37
38NAME:   serial_bayou_pond_b
39TAGS:   coolio_serial_bayou allow_dup extra decor
40DEPTH:  D, Depths, Snake, Lair
41MONS:   plant
42SUBST:  ? = .WW21
43SUBST:  1 = 11.t
44MAP
45  ..1..11..
46..1?W?W?WW1
47.1WW?W?W??..
481W?WWwwwW?W1
49.WW?wwww?W?1
501WW?WW?WW?1.
51.1WW?WW?WW..
52. 1 .1..1 .
53ENDMAP
54
55NAME:   serial_bayou_pond_c
56TAGS:   coolio_serial_bayou allow_dup extra decor
57DEPTH:  D, Depths, Snake, Lair
58MONS:   plant
59SUBST:  ? = WWtt2
60SUBST:  . = ..W12
61KMONS:  2 = plant
62KFEAT:  2 = W
63MAP
64       1
65    ..1W
66 .11WWWW.
67.WW????WW
68.1?tttt?W.
691W?tttt?W1
70.W?tttt?W1
71.WW????W1.
72 .1W1W1W.
73  .....
74   .1.
75ENDMAP
76
77NAME:   serial_bayou_pond_d
78#small pond
79TAGS:  coolio_serial_bayou allow_dup extra decor
80DEPTH:  D, Depths, Snake, Lair
81SUBST:  1 = 1W.
82SUBST:  W = WWWt
83KMONS:  1 = plant
84KFEAT:  1 = W
85MAP
86 11
87 WWW1
881WWW1
89 W11
90ENDMAP
91
92NAME:serial_bayou_pond_e
93#small pond
94TAGS:  coolio_serial_bayou allow_dup extra decor
95DEPTH: D, Depths, Snake, Lair
96SUBST: W = WWW1.
97SUBST: . = ..t
98KMONS: 1 = plant
99KFEAT: 1 = W
100MAP
101.WWW.
102WWWWW
103.WWW.
104ENDMAP
105
106NAME: serial_bayou_ford_a
107#a small pond that can be forded
108TAGS:  coolio_serial_bayou transparent extra decor
109DEPTH: D, Depths, Snake, Lair
110SUBST: ? = Wt
111SUBST: V = Www
112SUBST: W = WWWW1
113SUBST: ! = W..
114KMONS: 1 = plant
115KFEAT: 1 = W
116MAP
117       ttttt
118      tttttttt
119     ??WW??WW??
120    ?tWWWWWWWWW?
121  ??tWWWWWW!!W!.@
122  ?WWW!!.!......@
123 @...............@
124  @..!!.!.!!!!!WW???
125   @?!W!!W?WWWWWWWWW?
126    ?WWWWWWWWWVWWWWWW?
127     ?WWWWWVwwwVWWWW?
128      ?WWWVVwVWWW???
129      ?WWWWWVWW?tt
130      ?WWW?WW?
131       t?ttt?
132ENDMAP
133
134NAME:   serial_bayou_shore_a
135#a shore of a small lake
136TAGS:   coolio_serial_bayou extra decor transparent
137ORIENT: east
138DEPTH:  D, Depths, Snake, Lair
139SUBST:  ? = Wt
140SUBST:  V = Www
141SUBST:  W = WWW1
142SUBST:  ! = W1..
143KMONS:  1 = plant
144KFEAT:  1 = W
145MAP
146 @@      ttttxxxxxx
147@..WWWWWWWWttttxxxx
148 ..!WWWWWWWWWttttxx
149 ..!WWWWWVVVVWWtttx
150 ..!WWWWWVwwwVWWttx
151 ...!WWWVwwwwwVWttx
152 ...!WWWVwwwwwVWttx
153 ..!WWWWVwwwwwVWttx
154 ..!WWWWWVwwwVWtttx
155 ..!WWWWWVwwwVttttx
156@..WWWWWWWVVVWtttxx
157@..WWWWWWWWWWttttxx
158 @@      tttttttxxx
159ENDMAP
160
161NAME:   serial_bayou_shore_b
162#a shore of a small pond, duplicable
163TAGS:   coolio_serial_bayou allow_dup extra decor transparent
164ORIENT: east
165DEPTH:  D, Depths, Snake, Lair
166SUBST:  ? = Wt
167SUBST:  V = Www
168SUBST:  W = WWW1
169SUBST:  ! = W1..
170KMONS:  1 = plant
171KFEAT:  1 = W
172MAP
173  ???xxx
174@.!W??xx
175@.!WWW?x
176@.!WVV?x
177@.!WWW?x
178@.!W??xx
179  ???xxx
180ENDMAP
181
182NAME:   serial_bayou_lagoon_a
183TAGS:   coolio_serial_bayou transparent extra decor
184DEPTH:  D, Depths, Snake, Lair
185SUBST:  ? = W11.
186SUBST:  w = wwt
187KMONS:  1 = plant
188KFEAT:  1 = W
189MAP
190?????????
191?WWt1W11???
192??WWWwwwwW????
193 ?????WtwwW11??
194     ??1WwwtW1??
195      ?11twwWW1?
196      ??11ttwWW?
197       ?1tWwwW1?
198     ??11tWWW1??
199  ????WWtWW????
200 ??1WWWt1???
201??WWtW1???
202?W111???
203?W1???
204????
205ENDMAP
206
207NAME:  serial_bayou_lagoon_b
208#a big lagoon with a bridge thingy going through it
209TAGS:  coolio_serial_bayou
210DEPTH: D, Depths, Snake, Lair
211SUBST: ? = Wt
212SUBST: V = Www
213SUBST: W = WWWW1
214KMONS: 1 = plant
215KFEAT: 1 = W
216FTILE: . = floor_dirt
217MAP
218    ?????     ???
219   ?WWWWW?????ttt?
220  WWWWWWWttttWVWWt?
221 @WWWWWWWWWWWVwVWWW?@@??
222 @....................WW?
223 @?WWWWWWWWWVwwVWWWw.wWWW?
224   ?WWWWWWWWWVVWWWWw.wWWWW?
225    ?WWWWW???WWWWWWw.VVWWWW?
226     ?????   ?tttWWV.wVVVWWW?
227              ?tttWw.wwVVVWWW?
228               ?ttVw.wwwVVWWtt
229               ?ttWw.wwVVVVWtt
230              ?ttWWV.wVVVWttt
231             ?tttVww.WWWWWtt
232             ?WWVVww.WWWWttt
233             ?WVwwww.WWWWtt
234            ??WWWVww.WWWt?
235           ?WWWWWWVw.WWW?
236            ?WWWWWWV.WW?
237             ?WWWWW?.??
238              ?????@@@
239ENDMAP
240
241NAME:  serial_bayou_lake_a
242#a big lake
243TAGS:  coolio_serial_bayou transparent
244DEPTH: D, Depths, Snake, Lair
245SUBST: ? = Wt
246SUBST: V = Www
247SUBST: W = WWWW1
248KMONS: 1 = plant
249KFEAT: 1 = W
250MAP
251          ?????????
252      ?????????????????
253     ??????WWW?WWWWW??????
254   ???WWWWWWVVVVV?WW?WW???
255  ??WWW?WWVVwwwwwVVWW?WWW??
256 ??WW?WWWVwwwwwwwwwVWWWWW???
257??WWWWWWVwwwwwwwwwwwVW?WWWW??
258??W?WWWWVwwwwwwwwwwwVWWWWWW??
259??WWW?WWVwwwwwwwwwwwVWWW?WW??
260 ??WW?WW?VwwwwwwwwwVW?WWWW??
261  ??WWWWWWVVwwwwwVV?WW?WW??
262    ???W?WWWWVVVVVWWWWWW???
263     ??????W?WWWWWWW??????
264       ?????????????????
265           ?????????
266ENDMAP
267
268NAME:  serial_bayou_crossing
269TAGS:  coolio_serial_bayou transparent
270DEPTH: D, Depths, Snake, Lair
271SUBST: ? = W1tt
272SUBST: W = WWW.
273KMONS: 1 = plant
274KFEAT: 1 = W
275MAP
276    t?@?t
277    t?W?tt
278    t?W?tt
279  ttt?W?t
280ttttt?W?ttttt
281?????WWW?????
282@WWWWWWWWWWW@
283?????WWW?????
284ttttt?W?ttttt
285  ttt?W?t t
286   tt?W?t
287    t?W?tt
288    t?@?t
289ENDMAP
290