1// Copyright 2009 The Go Authors. All rights reserved.
2// Use of this source code is governed by a BSD-style
3// license that can be found in the LICENSE file.
4//
5// System calls and other sys.stuff for 386, NetBSD
6// /usr/src/sys/kern/syscalls.master for syscall numbers.
7//
8
9#include "go_asm.h"
10#include "go_tls.h"
11#include "textflag.h"
12
13#define CLOCK_REALTIME		0
14#define CLOCK_MONOTONIC		3
15#define FD_CLOEXEC		1
16#define F_SETFD			2
17
18#define SYS_exit			1
19#define SYS_read			3
20#define SYS_write			4
21#define SYS_open			5
22#define SYS_close			6
23#define SYS_getpid			20
24#define SYS_kill			37
25#define SYS_munmap			73
26#define SYS_madvise			75
27#define SYS_fcntl			92
28#define SYS_mmap			197
29#define SYS___sysctl			202
30#define SYS___sigaltstack14		281
31#define SYS___sigprocmask14		293
32#define SYS_getcontext			307
33#define SYS_setcontext			308
34#define SYS__lwp_create			309
35#define SYS__lwp_exit			310
36#define SYS__lwp_self			311
37#define SYS__lwp_setprivate		317
38#define SYS__lwp_kill			318
39#define SYS__lwp_unpark			321
40#define SYS___sigaction_sigtramp	340
41#define SYS_kqueue			344
42#define SYS_sched_yield			350
43#define SYS___setitimer50		425
44#define SYS___clock_gettime50		427
45#define SYS___nanosleep50		430
46#define SYS___kevent50			435
47#define SYS____lwp_park60		478
48
49// Exit the entire program (like C exit)
50TEXT runtime·exit(SB),NOSPLIT,$-4
51	MOVL	$SYS_exit, AX
52	INT	$0x80
53	MOVL	$0xf1, 0xf1		// crash
54	RET
55
56// func exitThread(wait *uint32)
57TEXT runtime·exitThread(SB),NOSPLIT,$0-4
58	MOVL	wait+0(FP), AX
59	// We're done using the stack.
60	MOVL	$0, (AX)
61	MOVL	$SYS__lwp_exit, AX
62	INT	$0x80
63	MOVL	$0xf1, 0xf1		// crash
64	JMP	0(PC)
65
66TEXT runtime·open(SB),NOSPLIT,$-4
67	MOVL	$SYS_open, AX
68	INT	$0x80
69	JAE	2(PC)
70	MOVL	$-1, AX
71	MOVL	AX, ret+12(FP)
72	RET
73
74TEXT runtime·closefd(SB),NOSPLIT,$-4
75	MOVL	$SYS_close, AX
76	INT	$0x80
77	JAE	2(PC)
78	MOVL	$-1, AX
79	MOVL	AX, ret+4(FP)
80	RET
81
82TEXT runtime·read(SB),NOSPLIT,$-4
83	MOVL	$SYS_read, AX
84	INT	$0x80
85	JAE	2(PC)
86	NEGL	AX			// caller expects negative errno
87	MOVL	AX, ret+12(FP)
88	RET
89
90// func pipe() (r, w int32, errno int32)
91TEXT runtime·pipe(SB),NOSPLIT,$0-12
92	MOVL	$42, AX
93	INT	$0x80
94	JCC	pipeok
95	MOVL	$-1, r+0(FP)
96	MOVL	$-1, w+4(FP)
97	MOVL	AX, errno+8(FP)
98	RET
99pipeok:
100	MOVL	AX, r+0(FP)
101	MOVL	DX, w+4(FP)
102	MOVL	$0, errno+8(FP)
103	RET
104
105// func pipe2(flags int32) (r, w int32, errno int32)
106TEXT runtime·pipe2(SB),NOSPLIT,$12-16
107	MOVL	$453, AX
108	LEAL	r+4(FP), BX
109	MOVL	BX, 4(SP)
110	MOVL	flags+0(FP), BX
111	MOVL	BX, 8(SP)
112	INT	$0x80
113	MOVL	AX, errno+12(FP)
114	RET
115
116TEXT runtime·write1(SB),NOSPLIT,$-4
117	MOVL	$SYS_write, AX
118	INT	$0x80
119	JAE	2(PC)
120	NEGL	AX			// caller expects negative errno
121	MOVL	AX, ret+12(FP)
122	RET
123
124TEXT runtime·usleep(SB),NOSPLIT,$24
125	MOVL	$0, DX
126	MOVL	usec+0(FP), AX
127	MOVL	$1000000, CX
128	DIVL	CX
129	MOVL	AX, 12(SP)		// tv_sec - l32
130	MOVL	$0, 16(SP)		// tv_sec - h32
131	MOVL	$1000, AX
132	MULL	DX
133	MOVL	AX, 20(SP)		// tv_nsec
134
135	MOVL	$0, 0(SP)
136	LEAL	12(SP), AX
137	MOVL	AX, 4(SP)		// arg 1 - rqtp
138	MOVL	$0, 8(SP)		// arg 2 - rmtp
139	MOVL	$SYS___nanosleep50, AX
140	INT	$0x80
141	RET
142
143TEXT runtime·lwp_kill(SB),NOSPLIT,$12-8
144	MOVL	$0, 0(SP)
145	MOVL	tid+0(FP), AX
146	MOVL	AX, 4(SP)		// arg 1 - target
147	MOVL	sig+4(FP), AX
148	MOVL	AX, 8(SP)		// arg 2 - signo
149	MOVL	$SYS__lwp_kill, AX
150	INT	$0x80
151	RET
152
153TEXT runtime·raiseproc(SB),NOSPLIT,$12
154	MOVL	$SYS_getpid, AX
155	INT	$0x80
156	MOVL	$0, 0(SP)
157	MOVL	AX, 4(SP)		// arg 1 - pid
158	MOVL	sig+0(FP), AX
159	MOVL	AX, 8(SP)		// arg 2 - signo
160	MOVL	$SYS_kill, AX
161	INT	$0x80
162	RET
163
164TEXT runtime·mmap(SB),NOSPLIT,$36
165	LEAL	addr+0(FP), SI
166	LEAL	4(SP), DI
167	CLD
168	MOVSL				// arg 1 - addr
169	MOVSL				// arg 2 - len
170	MOVSL				// arg 3 - prot
171	MOVSL				// arg 4 - flags
172	MOVSL				// arg 5 - fd
173	MOVL	$0, AX
174	STOSL				// arg 6 - pad
175	MOVSL				// arg 7 - offset
176	MOVL	$0, AX			// top 32 bits of file offset
177	STOSL
178	MOVL	$SYS_mmap, AX
179	INT	$0x80
180	JAE	ok
181	MOVL	$0, p+24(FP)
182	MOVL	AX, err+28(FP)
183	RET
184ok:
185	MOVL	AX, p+24(FP)
186	MOVL	$0, err+28(FP)
187	RET
188
189TEXT runtime·munmap(SB),NOSPLIT,$-4
190	MOVL	$SYS_munmap, AX
191	INT	$0x80
192	JAE	2(PC)
193	MOVL	$0xf1, 0xf1		// crash
194	RET
195
196TEXT runtime·madvise(SB),NOSPLIT,$-4
197	MOVL	$SYS_madvise, AX
198	INT	$0x80
199	JAE	2(PC)
200	MOVL	$-1, AX
201	MOVL	AX, ret+12(FP)
202	RET
203
204TEXT runtime·setitimer(SB),NOSPLIT,$-4
205	MOVL	$SYS___setitimer50, AX
206	INT	$0x80
207	RET
208
209// func walltime1() (sec int64, nsec int32)
210TEXT runtime·walltime1(SB), NOSPLIT, $32
211	LEAL	12(SP), BX
212	MOVL	$CLOCK_REALTIME, 4(SP)	// arg 1 - clock_id
213	MOVL	BX, 8(SP)		// arg 2 - tp
214	MOVL	$SYS___clock_gettime50, AX
215	INT	$0x80
216
217	MOVL	12(SP), AX		// sec - l32
218	MOVL	AX, sec_lo+0(FP)
219	MOVL	16(SP), AX		// sec - h32
220	MOVL	AX, sec_hi+4(FP)
221
222	MOVL	20(SP), BX		// nsec
223	MOVL	BX, nsec+8(FP)
224	RET
225
226// int64 nanotime1(void) so really
227// void nanotime1(int64 *nsec)
228TEXT runtime·nanotime1(SB),NOSPLIT,$32
229	LEAL	12(SP), BX
230	MOVL	$CLOCK_MONOTONIC, 4(SP)	// arg 1 - clock_id
231	MOVL	BX, 8(SP)		// arg 2 - tp
232	MOVL	$SYS___clock_gettime50, AX
233	INT	$0x80
234
235	MOVL	16(SP), CX		// sec - h32
236	IMULL	$1000000000, CX
237
238	MOVL	12(SP), AX		// sec - l32
239	MOVL	$1000000000, BX
240	MULL	BX			// result in dx:ax
241
242	MOVL	20(SP), BX		// nsec
243	ADDL	BX, AX
244	ADCL	CX, DX			// add high bits with carry
245
246	MOVL	AX, ret_lo+0(FP)
247	MOVL	DX, ret_hi+4(FP)
248	RET
249
250TEXT runtime·getcontext(SB),NOSPLIT,$-4
251	MOVL	$SYS_getcontext, AX
252	INT	$0x80
253	JAE	2(PC)
254	MOVL	$0xf1, 0xf1		// crash
255	RET
256
257TEXT runtime·sigprocmask(SB),NOSPLIT,$-4
258	MOVL	$SYS___sigprocmask14, AX
259	INT	$0x80
260	JAE	2(PC)
261	MOVL	$0xf1, 0xf1		// crash
262	RET
263
264TEXT sigreturn_tramp<>(SB),NOSPLIT,$0
265	LEAL	140(SP), AX		// Load address of ucontext
266	MOVL	AX, 4(SP)
267	MOVL	$SYS_setcontext, AX
268	INT	$0x80
269	MOVL	$-1, 4(SP)		// Something failed...
270	MOVL	$SYS_exit, AX
271	INT	$0x80
272
273TEXT runtime·sigaction(SB),NOSPLIT,$24
274	LEAL	sig+0(FP), SI
275	LEAL	4(SP), DI
276	CLD
277	MOVSL				// arg 1 - sig
278	MOVSL				// arg 2 - act
279	MOVSL				// arg 3 - oact
280	LEAL	sigreturn_tramp<>(SB), AX
281	STOSL				// arg 4 - tramp
282	MOVL	$2, AX
283	STOSL				// arg 5 - vers
284	MOVL	$SYS___sigaction_sigtramp, AX
285	INT	$0x80
286	JAE	2(PC)
287	MOVL	$0xf1, 0xf1		// crash
288	RET
289
290TEXT runtime·sigfwd(SB),NOSPLIT,$12-16
291	MOVL	fn+0(FP), AX
292	MOVL	sig+4(FP), BX
293	MOVL	info+8(FP), CX
294	MOVL	ctx+12(FP), DX
295	MOVL	SP, SI
296	SUBL	$32, SP
297	ANDL	$-15, SP	// align stack: handler might be a C function
298	MOVL	BX, 0(SP)
299	MOVL	CX, 4(SP)
300	MOVL	DX, 8(SP)
301	MOVL	SI, 12(SP)	// save SI: handler might be a Go function
302	CALL	AX
303	MOVL	12(SP), AX
304	MOVL	AX, SP
305	RET
306
307// Called by OS using C ABI.
308TEXT runtime·sigtramp(SB),NOSPLIT,$28
309	NOP	SP	// tell vet SP changed - stop checking offsets
310	// Save callee-saved C registers, since the caller may be a C signal handler.
311	MOVL	BX, bx-4(SP)
312	MOVL	BP, bp-8(SP)
313	MOVL	SI, si-12(SP)
314	MOVL	DI, di-16(SP)
315	// We don't save mxcsr or the x87 control word because sigtrampgo doesn't
316	// modify them.
317
318	MOVL	32(SP), BX // signo
319	MOVL	BX, 0(SP)
320	MOVL	36(SP), BX // info
321	MOVL	BX, 4(SP)
322	MOVL	40(SP), BX // context
323	MOVL	BX, 8(SP)
324	CALL	runtime·sigtrampgo(SB)
325
326	MOVL	di-16(SP), DI
327	MOVL	si-12(SP), SI
328	MOVL	bp-8(SP),  BP
329	MOVL	bx-4(SP),  BX
330	RET
331
332// int32 lwp_create(void *context, uintptr flags, void *lwpid);
333TEXT runtime·lwp_create(SB),NOSPLIT,$16
334	MOVL	$0, 0(SP)
335	MOVL	ctxt+0(FP), AX
336	MOVL	AX, 4(SP)		// arg 1 - context
337	MOVL	flags+4(FP), AX
338	MOVL	AX, 8(SP)		// arg 2 - flags
339	MOVL	lwpid+8(FP), AX
340	MOVL	AX, 12(SP)		// arg 3 - lwpid
341	MOVL	$SYS__lwp_create, AX
342	INT	$0x80
343	JCC	2(PC)
344	NEGL	AX
345	MOVL	AX, ret+12(FP)
346	RET
347
348TEXT runtime·lwp_tramp(SB),NOSPLIT,$0
349
350	// Set FS to point at m->tls
351	LEAL	m_tls(BX), BP
352	PUSHAL				// save registers
353	PUSHL	BP
354	CALL	lwp_setprivate<>(SB)
355	POPL	AX
356	POPAL
357
358	// Now segment is established. Initialize m, g.
359	get_tls(AX)
360	MOVL	DX, g(AX)
361	MOVL	BX, g_m(DX)
362
363	CALL	runtime·stackcheck(SB)	// smashes AX, CX
364	MOVL	0(DX), DX		// paranoia; check they are not nil
365	MOVL	0(BX), BX
366
367	// more paranoia; check that stack splitting code works
368	PUSHAL
369	CALL	runtime·emptyfunc(SB)
370	POPAL
371
372	// Call fn
373	CALL	SI
374
375	// fn should never return
376	MOVL	$0x1234, 0x1005
377	RET
378
379TEXT runtime·sigaltstack(SB),NOSPLIT,$-8
380	MOVL	$SYS___sigaltstack14, AX
381	MOVL	new+0(FP), BX
382	MOVL	old+4(FP), CX
383	INT	$0x80
384	CMPL	AX, $0xfffff001
385	JLS	2(PC)
386	INT	$3
387	RET
388
389TEXT runtime·setldt(SB),NOSPLIT,$8
390	// Under NetBSD we set the GS base instead of messing with the LDT.
391	MOVL	base+4(FP), AX
392	MOVL	AX, 0(SP)
393	CALL	lwp_setprivate<>(SB)
394	RET
395
396TEXT lwp_setprivate<>(SB),NOSPLIT,$16
397	// adjust for ELF: wants to use -4(GS) for g
398	MOVL	base+0(FP), CX
399	ADDL	$4, CX
400	MOVL	$0, 0(SP)		// syscall gap
401	MOVL	CX, 4(SP)		// arg 1 - ptr
402	MOVL	$SYS__lwp_setprivate, AX
403	INT	$0x80
404	JCC	2(PC)
405	MOVL	$0xf1, 0xf1		// crash
406	RET
407
408TEXT runtime·osyield(SB),NOSPLIT,$-4
409	MOVL	$SYS_sched_yield, AX
410	INT	$0x80
411	RET
412
413TEXT runtime·lwp_park(SB),NOSPLIT,$-4
414	MOVL	$SYS____lwp_park60, AX
415	INT	$0x80
416	MOVL	AX, ret+24(FP)
417	RET
418
419TEXT runtime·lwp_unpark(SB),NOSPLIT,$-4
420	MOVL	$SYS__lwp_unpark, AX
421	INT	$0x80
422	MOVL	AX, ret+8(FP)
423	RET
424
425TEXT runtime·lwp_self(SB),NOSPLIT,$-4
426	MOVL	$SYS__lwp_self, AX
427	INT	$0x80
428	MOVL	AX, ret+0(FP)
429	RET
430
431TEXT runtime·sysctl(SB),NOSPLIT,$28
432	LEAL	mib+0(FP), SI
433	LEAL	4(SP), DI
434	CLD
435	MOVSL				// arg 1 - name
436	MOVSL				// arg 2 - namelen
437	MOVSL				// arg 3 - oldp
438	MOVSL				// arg 4 - oldlenp
439	MOVSL				// arg 5 - newp
440	MOVSL				// arg 6 - newlen
441	MOVL	$SYS___sysctl, AX
442	INT	$0x80
443	JAE	4(PC)
444	NEGL	AX
445	MOVL	AX, ret+24(FP)
446	RET
447	MOVL	$0, AX
448	MOVL	AX, ret+24(FP)
449	RET
450
451GLOBL runtime·tlsoffset(SB),NOPTR,$4
452
453// int32 runtime·kqueue(void)
454TEXT runtime·kqueue(SB),NOSPLIT,$0
455	MOVL	$SYS_kqueue, AX
456	INT	$0x80
457	JAE	2(PC)
458	NEGL	AX
459	MOVL	AX, ret+0(FP)
460	RET
461
462// int32 runtime·kevent(int kq, Kevent *changelist, int nchanges, Kevent *eventlist, int nevents, Timespec *timeout)
463TEXT runtime·kevent(SB),NOSPLIT,$0
464	MOVL	$SYS___kevent50, AX
465	INT	$0x80
466	JAE	2(PC)
467	NEGL	AX
468	MOVL	AX, ret+24(FP)
469	RET
470
471// int32 runtime·closeonexec(int32 fd)
472TEXT runtime·closeonexec(SB),NOSPLIT,$32
473	MOVL	$SYS_fcntl, AX
474	// 0(SP) is where the caller PC would be; kernel skips it
475	MOVL	fd+0(FP), BX
476	MOVL	BX, 4(SP)	// fd
477	MOVL	$F_SETFD, 8(SP)
478	MOVL	$FD_CLOEXEC, 12(SP)
479	INT	$0x80
480	JAE	2(PC)
481	NEGL	AX
482	RET
483
484// func runtime·setNonblock(fd int32)
485TEXT runtime·setNonblock(SB),NOSPLIT,$16-4
486	MOVL	$92, AX // fcntl
487	MOVL	fd+0(FP), BX // fd
488	MOVL	BX, 4(SP)
489	MOVL	$3, 8(SP) // F_GETFL
490	MOVL	$0, 12(SP)
491	INT	$0x80
492	MOVL	fd+0(FP), BX // fd
493	MOVL	BX, 4(SP)
494	MOVL	$4, 8(SP) // F_SETFL
495	ORL	$4, AX // O_NONBLOCK
496	MOVL	AX, 12(SP)
497	MOVL	$92, AX // fcntl
498	INT	$0x80
499	RET
500