1#
2# $Id: timedat.dem,v 1.13.2.1 2017/09/03 23:32:22 sfeam Exp $
3#
4
5set title "Fsteps plot\nwith date and time as x-values"
6set style data fsteps
7set xlabel "Date\nTime"
8set timefmt "%d/%m/%y\t%H%M"
9set yrange [ 0 : ]
10set xdata time
11set xrange [ "1/6/93":"1/11/93" ]
12set ylabel "Concentration\nmg/l"
13set format x "%d/%m\n%H:%M"
14set grid
15set key left
16plot 'timedat.dat' using 1:3 t '', \
17     'timedat.dat' using 1:3 t 'Total P' with points, \
18     'timedat.dat' using 1:4 t '', \
19     'timedat.dat' using 1:4 t 'PO4' with points
20pause -1 "Hit return to continue"
21
22reset
23
24set title "Time data on Y, millisecond precision" font ",14"
25set ydata time
26set timefmt "%s"
27set offset 0.5,1.5,.2,.2
28unset key
29
30fulltime(col) = strftime("%d %b %Y\n%H:%M:%.3S",column(col))
31parttime(col) = strftime("%H:%M:%.3S",column(col))
32
33plot '-' using 0:1:(fulltime(1)):xticlabels(2):yticlabels(parttime(1)) \
34         with labels point pt 7 left offset 1,1 font ",7"
351390852607.1	A
361390852607.2	B
371390852607.4	C
381390852607.8	D
391390852608.4	E
401390852610.001	F
41e
42
43pause -1 "Hit return to continue"
44
45reset
46set title "Date format (top) vs Time format (bottom)" font ":Bold,14"
47set xrange [-7000:3000]
48set link x2
49set tics font ",8"
50set x2tics format "%D\n%R" time
51set xtics format "%tH:%tM:%tS" time
52
53set yzeroaxis
54unset ytics
55set bmargin at screen .3
56set tmargin at screen .6
57
58plot x notitle
59
60pause -1 "Hit return to continue"
61
62print "\nRelative time output (strftime(), axis labels)"
63
64t = -3672.5
65print 't = ',t
66print 'print strftime("%.2tM == %.2tS", t)' , "	", strftime("%.2tM min == %.2tS sec", t)
67print 'print strftime("%tM:%.2tS", t)  ' , "	", strftime("%tM:%.2tS", t)
68print 'print strftime("%tH:%tM:%.2tS", t)' , "	", strftime("%tH:%tM:%.2tS", t)
69
70t = 3672.5
71print 't = ',t
72print 'print strftime("%.2tM == %.2tS", t)' , "	", strftime("%.2tM min == %.2tS sec", t)
73print 'print strftime("%tM:%.2tS", t)  ' , "	", strftime("%tM:%.2tS", t)
74print 'print strftime("%tH:%tM:%.2tS", t)' , "	", strftime("%tH:%tM:%.2tS", t)
75
76print "\nRelative time input (strptime(), data files)"
77
78print 'print strptime("%tH:%tM:%tS", "-1:01:12.50")', "\t", strptime("%tH:%tM:%tS", "-1:01:12.50")
79print 'print strptime("    %tM:%tS", "-61:12.50")', "\t", strptime("    %tM:%tS", "-61:12.50")
80print 'print strptime("        %tS", "-3672.50")', "\t", strptime("        %tS", "-3672.50")
81
82reset
83