1(* ::Package:: *)
2
3(* ::Title::Bold::Closed:: *)
4(*\[Integral]Sqrt[a Cos[c+d x]+b Sin[c+d x]]\[DifferentialD]x*)
5
6
7(* ::Subsubsection:: *)
8(*Derivation: Algebraic simplification*)
9
10
11(* ::Subsubsection:: *)
12(*Basis: a Cos[z]+b Sin[z]=Sqrt[a^2+b^2] Cos[z-ArcTan[a,b]]*)
13
14
15(* ::Subsubsection:: *)
16(*Rule: If  a^2+b^2!=0 \[And] Sqrt[a^2+b^2]>0, then*)
17
18
19(* ::Subsubtitle::Bold:: *)
20(*\[Integral]Sqrt[a Cos[c+d x]+b Sin[c+d x]]\[DifferentialD]x  \[LongRightArrow]  (a^2+b^2)^(1/4)\[Integral]Sqrt[Cos[c+d x-ArcTan[a,b]]]\[DifferentialD]x*)
21
22
23(* ::Subsubsection:: *)
24(*Program code:*)
25
26
27(* ::Code:: *)
28Int[Sqrt[a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_]],x_Symbol] :=
29  Dist[(a^2+b^2)^(1/4),Int[Sqrt[Cos[c+d*x-ArcTan[a,b]]],x]] /;
30FreeQ[{a,b,c,d},x] && NonzeroQ[a^2+b^2] && PositiveQ[Sqrt[a^2+b^2]]
31
32
33(* ::Subsubsection:: *)
34(**)
35
36
37(* ::Subsubsection:: *)
38(*Derivation: Piecewise constant extraction and algebraic simplification*)
39
40
41(* ::Subsubsection:: *)
42(*Basis: \!\( *)
43(*\*SubscriptBox[\(\[PartialD]\), \(x\)]*)
44(*\*FractionBox[*)
45(*SqrtBox[\(a\ Cos[c + d\ x] + b\ Sin[c + d\ x]\)], *)
46(*SqrtBox[*)
47(*FractionBox[\(a\ Cos[c + d\ x] + b\ Sin[c + d\ x]\), *)
48(*SqrtBox[\( *)
49(*\*SuperscriptBox[\(a\), \(2\)] + *)
50(*\*SuperscriptBox[\(b\), \(2\)]\)]]]]\)=0*)
51
52
53(* ::Subsubsection:: *)
54(*Basis: (a Cos[z]+b Sin[z])/Sqrt[a^2+b^2]=Cos[z-ArcTan[a,b]]*)
55
56
57(* ::Subsubsection:: *)
58(*Rule: If  a^2+b^2!=0 \[And] \[Not](Sqrt[a^2+b^2]>0), then*)
59
60
61(* ::Subsubtitle::Bold:: *)
62(*\[Integral]Sqrt[a Cos[c+d x]+b Sin[c+d x]]\[DifferentialD]x  \[LongRightArrow]  (Sqrt[a Cos[c+d x]+b Sin[c+d x]]/Sqrt[((a Cos[c+d x]+b Sin[c+d x])/Sqrt[a^2+b^2])])\[Integral]Sqrt[Cos[c+d x-ArcTan[a,b]]]\[DifferentialD]x*)
63
64
65(* ::Subsubsection:: *)
66(*Program code:*)
67
68
69(* ::Code:: *)
70(* Int[Sqrt[a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_]],x_Symbol] :=
71  Sqrt[a*Cos[c+d*x]+b*Sin[c+d*x]]/Sqrt[(a*Cos[c+d*x]+b*Sin[c+d*x])/Sqrt[a^2+b^2]]*
72    Int[Sqrt[Cos[c+d*x-ArcTan[a,b]]],x] /;
73FreeQ[{a,b,c,d},x] && NonzeroQ[a^2+b^2] && Not[PositiveQ[Sqrt[a^2+b^2]]] *)
74
75
76(* ::PageBreak:: *)
77(**)
78
79
80(* ::Title::Bold::Closed:: *)
81(*\[Integral]1/Sqrt[a Cos[c+d x]+b Sin[c+d x]] \[DifferentialD]x*)
82
83
84(* ::Subsubsection:: *)
85(*Derivation: Algebraic simplification*)
86
87
88(* ::Subsubsection:: *)
89(*Basis: a Cos[z]+b Sin[z]=Sqrt[a^2+b^2] Cos[z-ArcTan[a,b]]*)
90
91
92(* ::Subsubsection:: *)
93(*Rule: If  a^2+b^2!=0 \[And] Sqrt[a^2+b^2]>0, then*)
94
95
96(* ::Subsubtitle::Bold:: *)
97(*\[Integral]1/Sqrt[a Cos[c+d x]+b Sin[c+d x]] \[DifferentialD]x  \[LongRightArrow]  (1/(a^2+b^2)^(1/4))\[Integral]1/Sqrt[Cos[c+d x-ArcTan[a,b]]] \[DifferentialD]x*)
98
99
100(* ::Subsubsection:: *)
101(*Program code:*)
102
103
104(* ::Code:: *)
105Int[1/Sqrt[a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_]],x_Symbol] :=
106  Dist[1/(a^2+b^2)^(1/4),Int[1/Sqrt[Cos[c+d*x-ArcTan[a,b]]],x]] /;
107FreeQ[{a,b,c,d},x] && NonzeroQ[a^2+b^2] && PositiveQ[Sqrt[a^2+b^2]]
108
109
110(* ::Subsubsection:: *)
111(**)
112
113
114(* ::Subsubsection:: *)
115(*Derivation: Piecewise constant extraction and algebraic simplification*)
116
117
118(* ::Subsubsection:: *)
119(*Basis: \!\( *)
120(*\*SubscriptBox[\(\[PartialD]\), \(x\)]*)
121(*\*FractionBox[*)
122(*SqrtBox[*)
123(*FractionBox[\(a\ Cos[c + d\ x] + b\ Sin[c + d\ x]\), *)
124(*SqrtBox[\( *)
125(*\*SuperscriptBox[\(a\), \(2\)] + *)
126(*\*SuperscriptBox[\(b\), \(2\)]\)]]], *)
127(*SqrtBox[\(a\ Cos[c + d\ x] + b\ Sin[c + d\ x]\)]]\)=0*)
128
129
130(* ::Subsubsection:: *)
131(*Basis: (a Cos[z]+b Sin[z])/Sqrt[a^2+b^2]=Cos[z-ArcTan[a,b]]*)
132
133
134(* ::Subsubsection:: *)
135(*Rule: If  a^2+b^2!=0 \[And] \[Not](Sqrt[a^2+b^2]>0), then*)
136
137
138(* ::Subsubtitle::Bold:: *)
139(*\[Integral]1/Sqrt[a Cos[c+d x]+b Sin[c+d x]] \[DifferentialD]x  \[LongRightArrow]  (Sqrt[((a Cos[c+d x]+b Sin[c+d x])/Sqrt[a^2+b^2])]/Sqrt[a Cos[c+d x]+b Sin[c+d x]])\[Integral]1/Sqrt[Cos[c+d x-ArcTan[a,b]]] \[DifferentialD]x*)
140
141
142(* ::Subsubsection:: *)
143(*Program code:*)
144
145
146(* ::Code:: *)
147(* Int[1/Sqrt[a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_]],x_Symbol] :=
148  Sqrt[(a*Cos[c+d*x]+b*Sin[c+d*x])/Sqrt[a^2+b^2]]/Sqrt[a*Cos[c+d*x]+b*Sin[c+d*x]]*
149    Int[1/Sqrt[Cos[c+d*x-ArcTan[a,b]]],x] /;
150FreeQ[{a,b,c,d},x] && NonzeroQ[a^2+b^2] && Not[PositiveQ[Sqrt[a^2+b^2]]] *)
151
152
153(* ::PageBreak:: *)
154(**)
155
156
157(* ::Title::Bold::Closed:: *)
158(*\[Integral](a Cos[c+d x]+b Sin[c+d x])^n \[DifferentialD]x*)
159
160
161(* ::Subsubsection:: *)
162(*Rule: If  a^2+b^2=0, then*)
163
164
165(* ::Subsubtitle::Bold:: *)
166(*\[Integral](a Cos[c+d x]+b Sin[c+d x])^n \[DifferentialD]x  \[LongRightArrow]  ((a (a Cos[c+d x]+b Sin[c+d x])^n)/(b d n))*)
167
168
169(* ::Subsubsection:: *)
170(*Program code:*)
171
172
173(* ::Code:: *)
174Int[(a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_])^n_,x_Symbol] :=
175  a*(a*Cos[c+d*x]+b*Sin[c+d*x])^n/(b*d*n) /;
176FreeQ[{a,b,c,d,n},x] && ZeroQ[a^2+b^2]
177
178
179(* ::Subsubsection:: *)
180(**)
181
182
183(* ::Subsubsection:: *)
184(*Reference: G&R 2.557.5b'*)
185
186
187(* ::Subsubsection:: *)
188(*Rule: If  a^2+b^2!=0, then*)
189
190
191(* ::Subsubtitle::Bold:: *)
192(*\[Integral]1/(a Cos[c+d x]+b Sin[c+d x])^2 \[DifferentialD]x  \[LongRightArrow]  (Sin[c+d x]/(a d (a Cos[c+d x]+b Sin[c+d x])))*)
193
194
195(* ::Subsubsection:: *)
196(*Program code:*)
197
198
199(* ::Code:: *)
200Int[1/(a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_])^2,x_Symbol] :=
201  Sin[c+d*x]/(a*d*(a*Cos[c+d*x]+b*Sin[c+d*x])) /;
202FreeQ[{a,b,c,d},x] && NonzeroQ[a^2+b^2]
203
204
205(* ::Subsubsection:: *)
206(**)
207
208
209(* ::Subsubsection:: *)
210(*Reference: G&R 2.557'*)
211
212
213(* ::Subsubsection:: *)
214(*Derivation: Integration by substitution*)
215
216
217(* ::Subsubsection:: *)
218(*Basis: If  (n-1)/2\[Element]\[DoubleStruckCapitalZ], then (a Cos[z]+b Sin[z])^n=(a^2+b^2-(-b Cos[z]+a Sin[z])^2)^((n-1)/2) \!\( *)
219(*\*SubscriptBox[\(\[PartialD]\), \(z\)]\((\(-b\)\ Cos[z] + a\ Sin[z])\)\)*)
220
221
222(* ::Subsubsection:: *)
223(*Note: Should this rule also be used for odd n<0?*)
224
225
226(* ::Subsubsection:: *)
227(*Rule: If  a^2+b^2!=0 \[And] (n-1)/2\[Element]\[DoubleStruckCapitalZ] \[And] n>0, then*)
228
229
230(* ::Subsubtitle::Bold:: *)
231(*\[Integral](a Cos[c+d x]+b Sin[c+d x])^n \[DifferentialD]x  \[LongRightArrow]  (1/d)Subst[Int[(a^2+b^2-x^2)^((n-1)/2),x],x,-b Cos[c+d x]+a Sin[c+d x]]*)
232
233
234(* ::Subsubsection:: *)
235(*Program code:*)
236
237
238(* ::Code:: *)
239Int[(a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_])^n_,x_Symbol] :=
240  Dist[1/d,Subst[Int[Regularize[(a^2+b^2-x^2)^((n-1)/2),x],x],x,-b*Cos[c+d*x]+a*Sin[c+d*x]]] /;
241FreeQ[{a,b},x] && NonzeroQ[a^2+b^2] && OddQ[n] && n>0
242
243
244(* ::Subsubsection:: *)
245(**)
246
247
248(* ::Subsubsection:: *)
249(*Derivation: Integration by parts with a double-back flip*)
250
251
252(* ::Subsubsection:: *)
253(*Rule: If  a^2+b^2!=0 \[And] n>1 \[And] (n-1)/2\[NotElement]\[DoubleStruckCapitalZ], then*)
254
255
256(* ::Subsubtitle::Bold:: *)
257(*\[Integral](a Cos[c+d x]+b Sin[c+d x])^n \[DifferentialD]x  \[LongRightArrow]  *)
258(*-(((b Cos[c+d x]-a Sin[c+d x]) (a Cos[c+d x]+b Sin[c+d x])^(n-1))/(d n))+((n-1) (a^2+b^2))/n \[Integral](a Cos[c+d x]+b Sin[c+d x])^(n-2) \[DifferentialD]x*)
259
260
261(* ::Subsubsection:: *)
262(*Program code:*)
263
264
265(* ::Code:: *)
266Int[(a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_])^n_,x_Symbol] :=
267  -(b*Cos[c+d*x]-a*Sin[c+d*x])*(a*Cos[c+d*x]+b*Sin[c+d*x])^(n-1)/(d*n) +
268  Dist[(n-1)*(a^2+b^2)/n,Int[(a*Cos[c+d*x]+b*Sin[c+d*x])^(n-2),x]] /;
269FreeQ[{a,b,c,d},x] && NonzeroQ[a^2+b^2] && RationalQ[n] && n>1 && Not[OddQ[n]]
270
271
272(* ::Subsubsection:: *)
273(**)
274
275
276(* ::Subsubsection:: *)
277(*Derivation: Integration by parts with a double-back flip*)
278
279
280(* ::Subsubsection:: *)
281(*Rule: If  a^2+b^2!=0 \[And] n<-1 \[And] n!=-2, then*)
282
283
284(* ::Subsubtitle::Bold:: *)
285(*\[Integral](a Cos[c+d x]+b Sin[c+d x])^n \[DifferentialD]x  \[LongRightArrow]  *)
286(*(((b Cos[c+d x]-a Sin[c+d x]) (a Cos[c+d x]+b Sin[c+d x])^(n+1))/(d (n+1) (a^2+b^2)))+(n+2)/((n+1) (a^2+b^2)) \[Integral](a Cos[c+d x]+b Sin[c+d x])^(n+2) \[DifferentialD]x*)
287
288
289(* ::Subsubsection:: *)
290(*Program code:*)
291
292
293(* ::Code:: *)
294Int[(a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_])^n_,x_Symbol] :=
295  (b*Cos[c+d*x]-a*Sin[c+d*x])*(a*Cos[c+d*x]+b*Sin[c+d*x])^(n+1)/(d*(n+1)*(a^2+b^2)) +
296  Dist[(n+2)/((n+1)*(a^2+b^2)),Int[(a*Cos[c+d*x]+b*Sin[c+d*x])^(n+2),x]] /;
297FreeQ[{a,b,c,d},x] && NonzeroQ[a^2+b^2] && RationalQ[n] && n<-1 && n!=-2
298
299
300(* ::PageBreak:: *)
301(**)
302
303
304(* ::Title::Bold::Closed:: *)
305(*\[Integral](Cos[c+d x]^m Sin[c+d x]^n)/(a Cos[c+d x]+b Sin[c+d x])^p \[DifferentialD]x*)
306
307
308(* ::Subsubsection:: *)
309(*Derivation: Algebraic expansion*)
310
311
312(* ::Subsubsection:: *)
313(*Basis: (Cos[z] Sin[z])/(a Cos[z]+b Sin[z])=(b Cos[z])/(a^2+b^2)+(a Sin[z])/(a^2+b^2)-(a b)/((a^2+b^2) (a Cos[z]+b Sin[z]))*)
314
315
316(* ::Subsubsection:: *)
317(*Rule: If  a^2+b^2!=0 \[And] m,n\[Element]\[DoubleStruckCapitalZ] \[And] m>0 \[And] n>0, then*)
318
319
320(* ::Subsubtitle::Bold:: *)
321(*\[Integral](Cos[c+d x]^m Sin[c+d x]^n)/(a Cos[c+d x]+b Sin[c+d x]) \[DifferentialD]x  \[LongRightArrow]  (b/(a^2+b^2))\[Integral]Cos[c+d x]^m Sin[c+d x]^(n-1) \[DifferentialD]x+                   *)
322(*                       a/(a^2+b^2) \[Integral]Cos[c+d x]^(m-1) Sin[c+d x]^n \[DifferentialD]x-(a b)/(a^2+b^2) \[Integral](Cos[c+d x]^(m-1) Sin[c+d x]^(n-1))/(a Cos[c+d x]+b Sin[c+d x]) \[DifferentialD]x*)
323
324
325(* ::Subsubsection:: *)
326(*Program code:*)
327
328
329(* ::Code:: *)
330(* Int[Cos[c_.+d_.*x_]^m_.*Sin[c_.+d_.*x_]^n_./(a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_]),x_Symbol] :=
331  Dist[b/(a^2+b^2),Int[Cos[c+d*x]^m*Sin[c+d*x]^(n-1),x]] +
332  Dist[a/(a^2+b^2),Int[Cos[c+d*x]^(m-1)*Sin[c+d*x]^n,x]] -
333  Dist[a*b/(a^2+b^2),Int[Cos[c+d*x]^(m-1)*Sin[c+d*x]^(n-1)/(a*Cos[c+d*x]+b*Sin[c+d*x]),x]] /;
334FreeQ[{a,b,c,d},x] && NonzeroQ[a^2+b^2] && IntegersQ[m,n] && m>0 && n>0 *)
335
336
337(* ::Subsubsection:: *)
338(**)
339
340
341(* ::Subsubsection:: *)
342(*Derivation: Algebraic expansion*)
343
344
345(* ::Subsubsection:: *)
346(*Basis: (Cos[z] Sin[z])/(a Cos[z]+b Sin[z])=(b Cos[z])/(a^2+b^2)+(a Sin[z])/(a^2+b^2)-(a b)/((a^2+b^2) (a Cos[z]+b Sin[z]))*)
347
348
349(* ::Subsubsection:: *)
350(*Rule: If  a^2+b^2!=0 \[And] m,n,p\[Element]\[DoubleStruckCapitalZ] \[And] m>0 \[And] n>0 \[And] p<0, then*)
351
352
353(* ::Subsubtitle::Bold:: *)
354(*\[Integral]Cos[c+d x]^m Sin[c+d x]^n (a Cos[c+d x]+b Sin[c+d x])^p \[DifferentialD]x  \[LongRightArrow]                                        *)
355(*(b/(a^2+b^2))\[Integral]Cos[c+d x]^m Sin[c+d x]^(n-1) (a Cos[c+d x]+b Sin[c+d x])^(p+1) \[DifferentialD]x+*)
356(*a/(a^2+b^2) \[Integral]Cos[c+d x]^(m-1) Sin[c+d x]^n (a Cos[c+d x]+b Sin[c+d x])^(p+1) \[DifferentialD]x-*)
357(*(a b)/(a^2+b^2) \[Integral]Cos[c+d x]^(m-1) Sin[c+d x]^(n-1) (a Cos[c+d x]+b Sin[c+d x])^p \[DifferentialD]x    *)
358
359
360(* ::Subsubsection:: *)
361(*Program code:*)
362
363
364(* ::Code:: *)
365Int[Cos[c_.+d_.*x_]^m_.*Sin[c_.+d_.*x_]^n_.*(a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_])^p_,x_Symbol] :=
366  Dist[b/(a^2+b^2),Int[Cos[c+d*x]^m*Sin[c+d*x]^(n-1)*(a*Cos[c+d*x]+b*Sin[c+d*x])^(p+1),x]] +
367  Dist[a/(a^2+b^2),Int[Cos[c+d*x]^(m-1)*Sin[c+d*x]^n*(a*Cos[c+d*x]+b*Sin[c+d*x])^(p+1),x]] -
368  Dist[a*b/(a^2+b^2),Int[Cos[c+d*x]^(m-1)*Sin[c+d*x]^(n-1)*(a*Cos[c+d*x]+b*Sin[c+d*x])^p,x]] /;
369FreeQ[{a,b,c,d},x] && NonzeroQ[a^2+b^2] && IntegersQ[m,n,p] && m>0 && n>0 && p<0
370
371
372(* ::Subsubsection:: *)
373(**)
374
375
376(* ::Subsubsection:: *)
377(*Derivation: Algebraic expansion*)
378
379
380(* ::Subsubsection:: *)
381(*Basis: Sin[z]^2/(a Cos[z]+b Sin[z])=(b Sin[z])/(a^2+b^2)-(a Cos[z])/(a^2+b^2)+a^2/((a^2+b^2) (a Cos[z]+b Sin[z]))*)
382
383
384(* ::Subsubsection:: *)
385(*Rule: If  a^2+b^2!=0 \[And] n\[Element]\[DoubleStruckCapitalZ] \[And] n>1, then*)
386
387
388(* ::Subsubtitle::Bold:: *)
389(*\[Integral](u Sin[c+d x]^n)/(a Cos[c+d x]+b Sin[c+d x]) \[DifferentialD]x  \[LongRightArrow]  (b/(a^2+b^2))\[Integral]u Sin[c+d x]^(n-1) \[DifferentialD]x-*)
390(*a/(a^2+b^2) \[Integral]u Sin[c+d x]^(n-2) Cos[c+d x]\[DifferentialD]x+a^2/(a^2+b^2) \[Integral](u Sin[c+d x]^(n-2))/(a Cos[c+d x]+b Sin[c+d x]) \[DifferentialD]x*)
391
392
393(* ::Subsubsection:: *)
394(*Program code:*)
395
396
397(* ::Code:: *)
398Int[u_.*Sin[c_.+d_.*x_]^n_./(a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_]),x_Symbol] :=
399  Dist[b/(a^2+b^2),Int[u*Sin[c+d*x]^(n-1),x]] -
400  Dist[a/(a^2+b^2),Int[u*Sin[c+d*x]^(n-2)*Cos[c+d*x],x]] +
401  Dist[a^2/(a^2+b^2),Int[u*Sin[c+d*x]^(n-2)/(a*Cos[c+d*x]+b*Sin[c+d*x]),x]] /;
402FreeQ[{a,b,c,d},x] && NonzeroQ[a^2+b^2] && IntegerQ[n] && n>0 &&
403(n>1 || MatchQ[u,v_.*Tan[c+d*x]^m_. /; IntegerQ[m] && m>0])
404
405
406(* ::Subsubsection:: *)
407(**)
408
409
410(* ::Subsubsection:: *)
411(*Derivation: Algebraic expansion*)
412
413
414(* ::Subsubsection:: *)
415(*Basis: Cos[z]^2/(a Cos[z]+b Sin[z])=(a Cos[z])/(a^2+b^2)-(b Sin[z])/(a^2+b^2)+b^2/((a^2+b^2) (a Cos[z]+b Sin[z]))*)
416
417
418(* ::Subsubsection:: *)
419(*Rule: If  a^2+b^2!=0 \[And] n\[Element]\[DoubleStruckCapitalZ] \[And] n>1, then*)
420
421
422(* ::Subsubtitle::Bold:: *)
423(*\[Integral](u Cos[c+d x]^n)/(a Cos[c+d x]+b Sin[c+d x]) \[DifferentialD]x  \[LongRightArrow]  (a/(a^2+b^2))\[Integral]u Cos[c+d x]^(n-1) \[DifferentialD]x-*)
424(*b/(a^2+b^2) \[Integral]u Cos[c+d x]^(n-2) Sin[c+d x]\[DifferentialD]x+b^2/(a^2+b^2) \[Integral](u Cos[c+d x]^(n-2))/(a Cos[c+d x]+b Sin[c+d x]) \[DifferentialD]x*)
425
426
427(* ::Subsubsection:: *)
428(*Program code:*)
429
430
431(* ::Code:: *)
432Int[u_.*Cos[c_.+d_.*x_]^n_./(a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_]),x_Symbol] :=
433  Dist[a/(a^2+b^2),Int[u*Cos[c+d*x]^(n-1),x]] -
434  Dist[b/(a^2+b^2),Int[u*Cos[c+d*x]^(n-2)*Sin[c+d*x],x]] +
435  Dist[b^2/(a^2+b^2),Int[u*Cos[c+d*x]^(n-2)/(a*Cos[c+d*x]+b*Sin[c+d*x]),x]] /;
436FreeQ[{a,b,c,d},x] && NonzeroQ[a^2+b^2] && IntegerQ[n] && n>0 &&
437(n>1 || MatchQ[u,v_.*Cot[c+d*x]^m_. /; IntegerQ[m] && m>0])
438
439
440(* ::Subsubsection:: *)
441(**)
442
443
444(* ::Subsubsection:: *)
445(*Derivation: Algebraic expansion*)
446
447
448(* ::Subsubsection:: *)
449(*Basis: Sec[z]/(a Cos[z]+b Sin[z])=Tan[z]/b+(b Cos[z]-a Sin[z])/(b (a Cos[z]+b Sin[z]))*)
450
451
452(* ::Subsubsection:: *)
453(*Rule:*)
454
455
456(* ::Subsubtitle::Bold:: *)
457(*\[Integral](u Sec[c+d x])/(a Cos[c+d x]+b Sin[c+d x]) \[DifferentialD]x  \[LongRightArrow]  (1/b)\[Integral]u Tan[c+d x]\[DifferentialD]x+1/b \[Integral](u (b Cos[c+d x]-a Sin[c+d x]))/(a Cos[c+d x]+b Sin[c+d x]) \[DifferentialD]x*)
458
459
460(* ::Subsubsection:: *)
461(*Program code:*)
462
463
464(* ::Code:: *)
465(* Int[u_.*Sec[c_.+d_.*x_]/(a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_]),x_Symbol] :=
466  Dist[1/b,Int[u*Tan[c+d*x],x]] +
467  Dist[1/b,Int[u*(b*Cos[c+d*x]-a*Sin[c+d*x])/(a*Cos[c+d*x]+b*Sin[c+d*x]),x]] /;
468FreeQ[{a,b,c,d},x] *)
469
470
471(* ::Subsubsection:: *)
472(**)
473
474
475(* ::Subsubsection:: *)
476(*Derivation: Algebraic expansion*)
477
478
479(* ::Subsubsection:: *)
480(*Basis: Csc[z]/(a Cos[z]+b Sin[z])=Cot[z]/a-(b Cos[z]-a Sin[z])/(a (a Cos[z]+b Sin[z]))*)
481
482
483(* ::Subsubsection:: *)
484(*Rule:*)
485
486
487(* ::Subsubtitle::Bold:: *)
488(*\[Integral](u Csc[c+d x])/(a Cos[c+d x]+b Sin[c+d x]) \[DifferentialD]x  \[LongRightArrow]  (1/a)\[Integral]u Cot[c+d x]\[DifferentialD]x-1/a \[Integral](u (b Cos[c+d x]-a Sin[c+d x]))/(a Cos[c+d x]+b Sin[c+d x]) \[DifferentialD]x*)
489
490
491(* ::Subsubsection:: *)
492(*Program code:*)
493
494
495(* ::Code:: *)
496(* Int[u_.*Csc[c_.+d_.*x_]/(a_.*Cos[c_.+d_.*x_]+b_.*Sin[c_.+d_.*x_]),x_Symbol] :=
497  Dist[1/a,Int[u*Cot[c+d*x],x]] -
498  Dist[1/a,Int[u*(b*Cos[c+d*x]-a*Sin[c+d*x])/(a*Cos[c+d*x]+b*Sin[c+d*x]),x]] /;
499FreeQ[{a,b,c,d},x] *)
500
501
502(* ::PageBreak:: *)
503(**)
504
505
506(* ::Title::Bold::Closed:: *)
507(*\[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x*)
508
509
510(* ::Subsubsection:: *)
511(*Reference: G&R 2.558.4c*)
512
513
514(* ::Subsubsection:: *)
515(*Rule: If  a-b=0, then*)
516
517
518(* ::Subsubtitle::Bold:: *)
519(*\[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x  \[LongRightArrow]  (1/(c e))Log[a+c Tan[1/2 (d+e x)]]*)
520
521
522(* ::Subsubsection:: *)
523(*Program code:*)
524
525
526(* ::Code:: *)
527Int[1/(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
528  Log[a+c*Tan[(d+e*x)/2]]/(c*e) /;
529FreeQ[{a,b,c,d,e},x] && ZeroQ[a-b]
530
531
532(* ::Subsubsection:: *)
533(**)
534
535
536(* ::Subsubsection:: *)
537(*Reference: G&R 2.558.4c*)
538
539
540(* ::Subsubsection:: *)
541(*Rule: If  a+b=0, then*)
542
543
544(* ::Subsubtitle::Bold:: *)
545(*\[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x  \[LongRightArrow]  -(1/(c e))Log[a+c Cot[1/2 (d+e x)]]*)
546
547
548(* ::Subsubsection:: *)
549(*Program code:*)
550
551
552(* ::Code:: *)
553Int[1/(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
554  -Log[a+c*Cot[(d+e*x)/2]]/(c*e) /;
555FreeQ[{a,b,c,d,e},x] && ZeroQ[a+b]
556
557
558(* ::Subsubsection:: *)
559(**)
560
561
562(* ::Subsubsection:: *)
563(*Reference: G&R 2.558.4d*)
564
565
566(* ::Subsubsection:: *)
567(*Rule: If  a^2-b^2-c^2=0, then*)
568
569
570(* ::Subsubtitle::Bold:: *)
571(*\[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x  \[LongRightArrow]  ((-c+a Sin[d+e x])/(c e (c Cos[d+e x]-b Sin[d+e x])))*)
572
573
574(* ::Subsubsection:: *)
575(*Program code:*)
576
577
578(* ::Code:: *)
579Int[1/(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
580  (-c+a*Sin[d+e*x])/(c*e*(c*Cos[d+e*x]-b*Sin[d+e*x])) /;
581FreeQ[{a,b,c,d,e},x] && ZeroQ[a^2-b^2-c^2]
582
583
584(* ::Subsubsection:: *)
585(**)
586
587
588(* ::Subsubsection:: *)
589(*Reference: G&R 2.558.4a, CRC 342b*)
590
591
592(* ::Subsubsection:: *)
593(*Rule: If  a^2-b^2!=0 \[And] a^2-b^2-c^2>0, then*)
594
595
596(* ::Subsubtitle::Bold:: *)
597(*\[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x  \[LongRightArrow]  (2/(e Sqrt[a^2-b^2-c^2]))ArcTan[(c+(a-b) Tan[1/2 (d+e x)])/Sqrt[a^2-b^2-c^2]]*)
598
599
600(* ::Subsubsection:: *)
601(*Program code:*)
602
603
604(* ::Code:: *)
605Int[1/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
606  2*ArcTan[(c+(a-b)*Tan[(d+e*x)/2])/Rt[a^2-b^2-c^2,2]]/(e*Rt[a^2-b^2-c^2,2]) /;
607FreeQ[{a,b,c,d,e},x] && NonzeroQ[a^2-b^2] && PosQ[a^2-b^2-c^2]
608
609
610(* ::Subsubsection:: *)
611(**)
612
613
614(* ::Subsubsection:: *)
615(*Reference: G&R 2.558.4b', CRC 342b'*)
616
617
618(* ::Subsubsection:: *)
619(*Rule: If  a^2-b^2!=0 \[And] \[Not](a^2-b^2-c^2>0), then*)
620
621
622(* ::Subsubtitle::Bold:: *)
623(*\[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x  \[LongRightArrow]  -(2/(e Sqrt[-a^2+b^2+c^2]))ArcTanh[(c+(a-b) Tan[1/2 (d+e x)])/Sqrt[-a^2+b^2+c^2]]*)
624
625
626(* ::Subsubsection:: *)
627(*Program code:*)
628
629
630(* ::Code:: *)
631Int[1/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
632  -2*ArcTanh[(c+(a-b)*Tan[(d+e*x)/2])/Rt[-a^2+b^2+c^2,2]]/(e*Rt[-a^2+b^2+c^2,2]) /;
633FreeQ[{a,b,c,d,e},x] && NonzeroQ[a^2-b^2] && NegQ[a^2-b^2-c^2]
634
635
636(* ::PageBreak:: *)
637(**)
638
639
640(* ::Title::Bold::Closed:: *)
641(*\[Integral]Sqrt[a+b Cos[d+e x]+c Sin[d+e x]]\[DifferentialD]x*)
642
643
644(* ::Subsubsection:: *)
645(*Reference: G&R 2.558.1 inverted with  n=1/2 and  a^2-b^2-c^2=0*)
646
647
648(* ::Subsubsection:: *)
649(*Rule: If  a^2-b^2-c^2=0, then*)
650
651
652(* ::Subsubtitle::Bold:: *)
653(*\[Integral]Sqrt[a+b Cos[d+e x]+c Sin[d+e x]]\[DifferentialD]x  \[LongRightArrow]  ((2 (-c Cos[d+e x]+b Sin[d+e x]))/(e Sqrt[a+b Cos[d+e x]+c Sin[d+e x]]))*)
654
655
656(* ::Subsubsection:: *)
657(*Program code:*)
658
659
660(* ::Code:: *)
661Int[Sqrt[a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]],x_Symbol] :=
662  2*(-c*Cos[d+e*x]+b*Sin[d+e*x])/(e*Sqrt[a+b*Cos[d+e*x]+c*Sin[d+e*x]]) /;
663FreeQ[{a,b,c,d,e},x] && ZeroQ[a^2-b^2-c^2]
664
665
666(* ::Subsubsection:: *)
667(**)
668
669
670(* ::Subsubsection:: *)
671(*Derivation: Algebraic simplification*)
672
673
674(* ::Subsubsection:: *)
675(*Basis: a+b Cos[z]+c Sin[z]=a+Sqrt[b^2+c^2] Cos[z-ArcTan[b,c]]*)
676
677
678(* ::Subsubsection:: *)
679(*Rule: If  a^2-b^2-c^2!=0 \[And] a+Sqrt[b^2+c^2]>0, then*)
680
681
682(* ::Subsubtitle::Bold:: *)
683(*\[Integral]Sqrt[a+b Cos[d+e x]+c Sin[d+e x]]\[DifferentialD]x  \[LongRightArrow]  \[Integral]Sqrt[a+Sqrt[b^2+c^2] Cos[d+e x-ArcTan[b,c]]]\[DifferentialD]x*)
684
685
686(* ::Subsubsection:: *)
687(*Program code:*)
688
689
690(* ::Code:: *)
691Int[Sqrt[a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]],x_Symbol] :=
692  Int[Sqrt[a+Sqrt[b^2+c^2]*Cos[d+e*x-ArcTan[b,c]]],x] /;
693FreeQ[{a,b,c,d,e},x] && NonzeroQ[a^2-b^2-c^2] && PositiveQ[a+Sqrt[b^2+c^2]]
694
695
696(* ::Subsubsection:: *)
697(**)
698
699
700(* ::Subsubsection:: *)
701(*Derivation: Piecewise constant extraction and algebraic simplification*)
702
703
704(* ::Subsubsection:: *)
705(*Basis: \!\( *)
706(*\*SubscriptBox[\(\[PartialD]\), \(x\)]*)
707(*\*FractionBox[*)
708(*SqrtBox[\(a + b\ Cos[d + e\ x] + c\ Sin[d + e\ x]\)], *)
709(*SqrtBox[*)
710(*FractionBox[\(a + b\ Cos[d + e\ x] + c\ Sin[d + e\ x]\), \(a + *)
711(*\*SqrtBox[\( *)
712(*\*SuperscriptBox[\(b\), \(2\)] + *)
713(*\*SuperscriptBox[\(c\), \(2\)]\)]\)]]]\)=0*)
714
715
716(* ::Subsubsection:: *)
717(*Basis: a+b Cos[z]+c Sin[z]=a+Sqrt[b^2+c^2] Cos[z-ArcTan[b,c]]*)
718
719
720(* ::Subsubsection:: *)
721(*Rule: If  a^2-b^2-c^2!=0 \[And] \[Not](a+Sqrt[b^2+c^2]>0), then*)
722
723
724(* ::Subsubtitle::Bold:: *)
725(*\[Integral]Sqrt[a+b Cos[d+e x]+c Sin[d+e x]]\[DifferentialD]x  \[LongRightArrow]  (Sqrt[a+b Cos[d+e x]+c Sin[d+e x]]/Sqrt[((a+b Cos[d+e x]+c Sin[d+e x])/(a+Sqrt[b^2+c^2]))])\[Integral]Sqrt[a/(a+Sqrt[b^2+c^2])+Sqrt[b^2+c^2]/(a+Sqrt[b^2+c^2]) Cos[d+e x-ArcTan[b,c]]]\[DifferentialD]x*)
726
727
728(* ::Subsubsection:: *)
729(*Program code:*)
730
731
732(* ::Code:: *)
733Int[Sqrt[a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]],x_Symbol] :=
734  Sqrt[a+b*Cos[d+e*x]+c*Sin[d+e*x]]/Sqrt[(a+b*Cos[d+e*x]+c*Sin[d+e*x])/(a+Sqrt[b^2+c^2])]*
735    Int[Sqrt[a/(a+Sqrt[b^2+c^2])+Sqrt[b^2+c^2]/(a+Sqrt[b^2+c^2])*Cos[d+e*x-ArcTan[b,c]]],x] /;
736FreeQ[{a,b,c,d,e},x] && NonzeroQ[a^2-b^2-c^2] && Not[PositiveQ[a+Sqrt[b^2+c^2]]]
737
738
739(* ::PageBreak:: *)
740(**)
741
742
743(* ::Title::Bold::Closed:: *)
744(*\[Integral]1/Sqrt[a+b Cos[d+e x]+c Sin[d+e x]] \[DifferentialD]x*)
745
746
747(* ::Subsubsection:: *)
748(*Derivation: Algebraic simplification    NonzeroQ[a^2 - b^2 - c^2] ???? *)
749
750
751(* ::Subsubsection:: *)
752(*Basis: a+b Cos[z]+c Sin[z]=a+Sqrt[b^2+c^2] Cos[z-ArcTan[b,c]]*)
753
754
755(* ::Subsubsection:: *)
756(*Rule: If  a+Sqrt[b^2+c^2]>0, then*)
757
758
759(* ::Subsubtitle::Bold:: *)
760(*\[Integral]1/Sqrt[a+b Cos[d+e x]+c Sin[d+e x]] \[DifferentialD]x  \[LongRightArrow]  \[Integral]1/Sqrt[a+Sqrt[b^2+c^2] Cos[d+e x-ArcTan[b,c]]] \[DifferentialD]x*)
761
762
763(* ::Subsubsection:: *)
764(*Program code:*)
765
766
767(* ::Code:: *)
768Int[1/Sqrt[a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]],x_Symbol] :=
769  Int[1/Sqrt[a+Sqrt[b^2+c^2]*Cos[d+e*x-ArcTan[b,c]]],x] /;
770FreeQ[{a,b,c,d,e},x] && PositiveQ[a+Sqrt[b^2+c^2]]
771
772
773(* ::Subsubsection:: *)
774(**)
775
776
777(* ::Subsubsection:: *)
778(*Derivation: Piecewise constant extraction and algebraic simplification*)
779
780
781(* ::Subsubsection:: *)
782(*Basis: \!\( *)
783(*\*SubscriptBox[\(\[PartialD]\), \(x\)]*)
784(*\*FractionBox[*)
785(*SqrtBox[*)
786(*FractionBox[\(a + b\ Cos[d + e\ x] + c\ Sin[d + e\ x]\), \(a + *)
787(*\*SqrtBox[\( *)
788(*\*SuperscriptBox[\(b\), \(2\)] + *)
789(*\*SuperscriptBox[\(c\), \(2\)]\)]\)]], *)
790(*SqrtBox[\(a + b\ Cos[d + e\ x] + c\ Sin[d + e\ x]\)]]\)=0*)
791
792
793(* ::Subsubsection:: *)
794(*Basis: a+b Cos[z]+c Sin[z]=a+Sqrt[b^2+c^2] Cos[z-ArcTan[b,c]]*)
795
796
797(* ::Subsubsection:: *)
798(*Rule: If  a+Sqrt[b^2+c^2]!=0 \[And] \[Not](a+Sqrt[b^2+c^2]>0), then*)
799
800
801(* ::Subsubtitle::Bold:: *)
802(*\[Integral]1/Sqrt[a+b Cos[d+e x]+c Sin[d+e x]] \[DifferentialD]x  \[LongRightArrow]  (Sqrt[((a+b Cos[d+e x]+c Sin[d+e x])/(a+Sqrt[b^2+c^2]))]/Sqrt[a+b Cos[d+e x]+c Sin[d+e x]])\[Integral]1/Sqrt[a/(a+Sqrt[b^2+c^2])+Sqrt[b^2+c^2]/(a+Sqrt[b^2+c^2]) Cos[d+e x-ArcTan[b,c]]] \[DifferentialD]x*)
803
804
805(* ::Subsubsection:: *)
806(*Program code:*)
807
808
809(* ::Code:: *)
810Int[1/Sqrt[a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]],x_Symbol] :=
811  Sqrt[(a+b*Cos[d+e*x]+c*Sin[d+e*x])/(a+Sqrt[b^2+c^2])]/Sqrt[a+b*Cos[d+e*x]+c*Sin[d+e*x]]*
812    Int[1/Sqrt[a/(a+Sqrt[b^2+c^2])+Sqrt[b^2+c^2]/(a+Sqrt[b^2+c^2])*Cos[d+e*x-ArcTan[b,c]]],x] /;
813FreeQ[{a,b,c,d,e},x] && NonzeroQ[a+Sqrt[b^2+c^2]] && Not[PositiveQ[a+Sqrt[b^2+c^2]]]
814
815
816(* ::PageBreak:: *)
817(**)
818
819
820(* ::Title::Bold::Closed:: *)
821(*\[Integral](a+b Cos[d+e x]+c Sin[d+e x])^n \[DifferentialD]x*)
822
823
824(* ::Subsubsection:: *)
825(*Reference: G&R 2.558.1 inverted with a^2-b^2-c^2=0*)
826
827
828(* ::Subsubsection:: *)
829(*Rule: If  a^2-b^2-c^2=0 \[And] n\[Element]\[DoubleStruckCapitalF] \[And] n>1, then*)
830
831
832(* ::Subsubtitle::Bold:: *)
833(*\[Integral](a+b Cos[d+e x]+c Sin[d+e x])^n \[DifferentialD]x  \[LongRightArrow]                                                                                *)
834(*                 (((-c Cos[d+e x]+b Sin[d+e x]) (a+b Cos[d+e x]+c Sin[d+e x])^(n-1))/(e n))+*)
835(*(a (2 n-1))/n \[Integral](a+b Cos[d+e x]+c Sin[d+e x])^(n-1) \[DifferentialD]x                         *)
836
837
838(* ::Subsubsection:: *)
839(*Program code:*)
840
841
842(* ::Code:: *)
843Int[(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^n_,x_Symbol] :=
844  (-c*Cos[d+e*x]+b*Sin[d+e*x])*(a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n-1)/(e*n) +
845  Dist[a*(2*n-1)/n,Int[(a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n-1),x]] /;
846FreeQ[{a,b,c,d,e},x] && ZeroQ[a^2-b^2-c^2] && RationalQ[n] && n>1
847
848
849(* ::Subsubsection:: *)
850(**)
851
852
853(* ::Subsubsection:: *)
854(*Reference: G&R 2.558.1 inverted*)
855
856
857(* ::Subsubsection:: *)
858(*Rule: If  a^2-b^2-c^2!=0 \[And] n\[Element]\[DoubleStruckCapitalF] \[And] n>1, then*)
859
860
861(* ::Subsubtitle::Bold:: *)
862(*\[Integral](a+b Cos[d+e x]+c Sin[d+e x])^n \[DifferentialD]x  \[LongRightArrow]                                                                                  *)
863(*                   (((-c Cos[d+e x]+b Sin[d+e x]) (a+b Cos[d+e x]+c Sin[d+e x])^(n-1))/(e n))+*)
864(*1/n \[Integral](n a^2+(n-1)(b^2+c^2)+a b (2 n-1) Cos[d+e x]+a c (2 n-1)Sin[d+e x])(a+b Cos[d+e x]+c Sin[d+e x])^(n-2) \[DifferentialD]x*)
865
866
867(* ::Subsubsection:: *)
868(*Program code:*)
869
870
871(* ::Code:: *)
872Int[(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^n_,x_Symbol] :=
873  (-c*Cos[d+e*x]+b*Sin[d+e*x])*(a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n-1)/(e*n) +
874  Dist[1/n,Int[(n*a^2+(n-1)*(b^2+c^2)+a*b*(2*n-1)*Cos[d+e*x]+a*c*(2*n-1)*Sin[d+e*x])*
875    (a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n-2),x]] /;
876FreeQ[{a,b,c,d,e},x] && NonzeroQ[a^2-b^2-c^2] && FractionQ[n] && n>1
877
878
879(* ::PageBreak:: *)
880(**)
881
882
883(* ::Title::Bold::Closed:: *)
884(*\[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x])^n \[DifferentialD]x*)
885
886
887(* ::Subsubsection:: *)
888(*Reference: G&R 2.558.1 inverted with a^2-b^2-c^2=0 inverted*)
889
890
891(* ::Subsubsection:: *)
892(*Rule: If  a^2-b^2-c^2=0 \[And] n<-1, then*)
893
894
895(* ::Subsubtitle::Bold:: *)
896(*\[Integral](a+b Cos[d+e x]+c Sin[d+e x])^n \[DifferentialD]x  \[LongRightArrow]                                                                                          *)
897(*                                   (((c Cos[d+e x]-b Sin[d+e x]) (a+b Cos[d+e x]+c Sin[d+e x])^n)/(a e (2 n+1)))+*)
898(*(n+1)/(a (2 n+1)) \[Integral](a+b Cos[d+e x]+c Sin[d+e x])^(n+1) \[DifferentialD]x*)
899
900
901(* ::Subsubsection:: *)
902(*Program code:*)
903
904
905(* ::Code:: *)
906Int[(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^n_,x_Symbol] :=
907  (c*Cos[d+e*x]-b*Sin[d+e*x])*(a+b*Cos[d+e*x]+c*Sin[d+e*x])^n/(a*e*(2*n+1)) +
908  Dist[(n+1)/(a*(2*n+1)),Int[(a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n+1),x]] /;
909FreeQ[{a,b,c,d,e},x] && ZeroQ[a^2-b^2-c^2] && RationalQ[n] && n<-1
910
911
912(* ::Subsubsection:: *)
913(**)
914
915
916(* ::Subsubsection:: *)
917(*Reference: G&R 2.558.1 with  n=-2*)
918
919
920(* ::Subsubsection:: *)
921(*Rule: If  a^2-b^2-c^2!=0, then*)
922
923
924(* ::Subsubtitle::Bold:: *)
925(*\[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x])^2 \[DifferentialD]x  \[LongRightArrow]                                                                                                                                   *)
926(*                        ((c Cos[d+e x]-b Sin[d+e x])/(e (a^2-b^2-c^2) (a+b Cos[d+e x]+c Sin[d+e x])))+a/(a^2-b^2-c^2) \[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x*)
927
928
929(* ::Subsubsection:: *)
930(*Program code:*)
931
932
933(* ::Code:: *)
934Int[1/(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^2,x_Symbol] :=
935  (c*Cos[d+e*x]-b*Sin[d+e*x])/(e*(a^2-b^2-c^2)*(a+b*Cos[d+e*x]+c*Sin[d+e*x])) +
936  Dist[a/(a^2-b^2-c^2),Int[1/(a+b*Cos[d+e*x]+c*Sin[d+e*x]),x]] /;
937FreeQ[{a,b,c,d,e},x] && NonzeroQ[a^2-b^2-c^2]
938
939
940(* ::Subsubsection:: *)
941(**)
942
943
944(* ::Subsubsection:: *)
945(*Reference: G&R 2.558.1 with n=-(3/2)*)
946
947
948(* ::Subsubsection:: *)
949(*Rule: If  a^2-b^2-c^2!=0, then*)
950
951
952(* ::Subsubtitle::Bold:: *)
953(*\[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x])^(3/2) \[DifferentialD]x  \[LongRightArrow]                                                                                                                                      *)
954(*            ((2 (c Cos[d+e x]-b Sin[d+e x]))/(e (a^2-b^2-c^2) Sqrt[a+b Cos[d+e x]+c Sin[d+e x]]))+1/(a^2-b^2-c^2) \[Integral]Sqrt[a+b Cos[d+e x]+c Sin[d+e x]]\[DifferentialD]x*)
955
956
957(* ::Subsubsection:: *)
958(*Program code:*)
959
960
961(* ::Code:: *)
962Int[1/(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^(3/2),x_Symbol] :=
963  2*(c*Cos[d+e*x]-b*Sin[d+e*x])/(e*(a^2-b^2-c^2)*Sqrt[a+b*Cos[d+e*x]+c*Sin[d+e*x]]) +
964  Dist[1/(a^2-b^2-c^2),Int[Sqrt[a+b*Cos[d+e*x]+c*Sin[d+e*x]],x]] /;
965FreeQ[{a,b,c,d,e},x] && NonzeroQ[a^2-b^2-c^2]
966
967
968(* ::Subsubsection:: *)
969(**)
970
971
972(* ::Subsubsection:: *)
973(*Reference: G&R 2.558.1*)
974
975
976(* ::Subsubsection:: *)
977(*Rule: If  a^2-b^2-c^2!=0 \[And] n<-1 \[And] n!=-2 \[And] n!=-(3/2), then*)
978
979
980(* ::Subsubtitle::Bold:: *)
981(*\[Integral](a+b Cos[d+e x]+c Sin[d+e x])^n \[DifferentialD]x  \[LongRightArrow]  (((-c Cos[d+e x]+b Sin[d+e x]) (a+b Cos[d+e x]+c Sin[d+e x])^(n+1))/(e (n+1) (a^2-b^2-c^2)))+*)
982(*1/((n+1) (a^2-b^2-c^2)) \[Integral]((n+1) a-(n+2) b Cos[d+e x]-(n+2) c Sin[d+e x]) (a+b Cos[d+e x]+c Sin[d+e x])^(n+1) \[DifferentialD]x*)
983
984
985(* ::Subsubsection:: *)
986(*Program code:*)
987
988
989(* ::Code:: *)
990Int[(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^n_,x_Symbol] :=
991  (-c*Cos[d+e*x]+b*Sin[d+e*x])*(a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n+1)/(e*(n+1)*(a^2-b^2-c^2)) +
992  Dist[1/((n+1)*(a^2-b^2-c^2)),
993    Int[((n+1)*a-(n+2)*b*Cos[d+e*x]-(n+2)*c*Sin[d+e*x])*(a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n+1),x]] /;
994FreeQ[{a,b,c,d,e},x] && NonzeroQ[a^2-b^2-c^2] && RationalQ[n] && n<-1 && n!=-2 && n!=-3/2
995
996
997(* ::PageBreak:: *)
998(**)
999
1000
1001(* ::Title::Bold::Closed:: *)
1002(*\[Integral](A+B Cos[d+e x]+C Sin[d+e x])(a+b Cos[d+e x]+c Sin[d+e x])^n \[DifferentialD]x*)
1003
1004
1005(* ::Subsubsection:: *)
1006(*Note: Although exactly analogous to G&R 2.451.3 for hyperbolic functions, there is no corresponding G&R 2.558.n formula for trig functions.  Apparently the authors did not anticipate  b^2+c^2 could be 0 in the complex plane.*)
1007
1008
1009(* ::Subsubsection:: *)
1010(*Rule: If  b^2+c^2=0, then*)
1011
1012
1013(* ::Subsubtitle::Bold:: *)
1014(*\[Integral](A+B Cos[d+e x]+C Sin[d+e x])/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x  \[LongRightArrow]  (((2 a A-b B-c C) x)/(2 a^2))-((b B+c C) (b Cos[d+e x]-c Sin[d+e x]))/(2 a b c e)+*)
1015(*((a^2 (b B-c C)-2 a A b^2+b^2 (b B+c C)) Log[a+b Cos[d+e x]+c Sin[d+e x]])/(2 a^2 b c e)*)
1016
1017
1018(* ::Subsubsection:: *)
1019(*Program code:*)
1020
1021
1022(* ::Code:: *)
1023Int[(A_.+B_.*Cos[d_.+e_.*x_]+C_.*Sin[d_.+e_.*x_])/(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
1024  (2*a*A-b*B-c*C)*x/(2*a^2) - (b*B+c*C)*(b*Cos[d+e*x]-c*Sin[d+e*x])/(2*a*b*c*e) +
1025  (a^2*(b*B-c*C)-2*a*A*b^2+b^2*(b*B+c*C))*Log[a+b*Cos[d+e*x]+c*Sin[d+e*x]]/(2*a^2*b*c*e) /;
1026FreeQ[{a,b,c,d,e,A,B,C},x] && ZeroQ[b^2+c^2]
1027
1028
1029(* ::Code:: *)
1030Int[(A_.+C_.*Sin[d_.+e_.*x_])/(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
1031  (2*a*A-c*C)*x/(2*a^2) - C*Cos[d+e*x]/(2*a*e) + c*C*Sin[d+e*x]/(2*a*b*e) +
1032  (-a^2*C+2*a*c*A+b^2*C)*Log[a+b*Cos[d+e*x]+c*Sin[d+e*x]]/(2*a^2*b*e) /;
1033FreeQ[{a,b,c,d,e,A,C},x] && ZeroQ[b^2+c^2]
1034
1035
1036(* ::Code:: *)
1037Int[(A_.+B_.*Cos[d_.+e_.*x_])/(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
1038  (2*a*A-b*B)*x/(2*a^2) - b*B*Cos[d+e*x]/(2*a*c*e) + B*Sin[d+e*x]/(2*a*e) +
1039  (a^2*B-2*a*b*A+b^2*B)*Log[a+b*Cos[d+e*x]+c*Sin[d+e*x]]/(2*a^2*c*e) /;
1040FreeQ[{a,b,c,d,e,A,B},x] && ZeroQ[b^2+c^2]
1041
1042
1043(* ::Subsubsection:: *)
1044(**)
1045
1046
1047(* ::Subsubsection:: *)
1048(*Reference: G&R 2.558.2 with  A(b^2+c^2)-a(b B+c C)=0*)
1049
1050
1051(* ::Subsubsection:: *)
1052(*Rule: If  b^2+c^2!=0 \[And] A(b^2+c^2)-a(b B+c C)=0, then*)
1053
1054
1055(* ::Subsubtitle::Bold:: *)
1056(*\[Integral](A+B Cos[d+e x]+C Sin[d+e x])/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x  \[LongRightArrow]  (((b B+c C) x)/(b^2+c^2))+((c B-b C) Log[a+b Cos[d+e x]+c Sin[d+e x]])/(e (b^2+c^2))*)
1057
1058
1059(* ::Subsubsection:: *)
1060(*Program code:*)
1061
1062
1063(* ::Code:: *)
1064Int[(A_.+B_.*Cos[d_.+e_.*x_]+C_.*Sin[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
1065  (b*B+c*C)*x/(b^2+c^2) + (c*B-b*C)*Log[a+b*Cos[d+e*x]+c*Sin[d+e*x]]/(e*(b^2+c^2)) /;
1066FreeQ[{a,b,c,d,e,A,B,C},x] && NonzeroQ[b^2+c^2] && ZeroQ[A*(b^2+c^2)-a*(b*B+c*C)]
1067
1068
1069(* ::Subsubsection:: *)
1070(*Reference: G&R 2.558.2 with  B=0  and  A (b^2+c^2)-a c C=0*)
1071
1072
1073(* ::Code:: *)
1074Int[(A_.+C_.*Sin[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
1075  c*C*x/(b^2+c^2) - b*C*Log[a+b*Cos[d+e*x]+c*Sin[d+e*x]]/(e*(b^2+c^2)) /;
1076FreeQ[{a,b,c,d,e,A,C},x] && NonzeroQ[b^2+c^2] && ZeroQ[A*(b^2+c^2)-a*c*C]
1077
1078
1079(* ::Subsubsection:: *)
1080(*Reference: G&R 2.558.2 with  C=0  and  A (b^2+c^2)-a b B=0*)
1081
1082
1083(* ::Code:: *)
1084Int[(A_.+B_.*Cos[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
1085  b*B*x/(b^2+c^2) + c*B*Log[a+b*Cos[d+e*x]+c*Sin[d+e*x]]/(e*(b^2+c^2)) /;
1086FreeQ[{a,b,c,d,e,A,B},x] && NonzeroQ[b^2+c^2] && ZeroQ[A*(b^2+c^2)-a*b*B]
1087
1088
1089(* ::Subsubsection:: *)
1090(**)
1091
1092
1093(* ::Subsubsection:: *)
1094(*Reference: G&R 2.558.2*)
1095
1096
1097(* ::Subsubsection:: *)
1098(*Rule: If  b^2+c^2!=0 \[And] A (b^2+c^2)-a (b B+c C)!=0, then*)
1099
1100
1101(* ::Subsubtitle::Bold:: *)
1102(*\[Integral](A+B Cos[d+e x]+C Sin[d+e x])/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x  \[LongRightArrow]  (((b B+c C) x)/(b^2+c^2))+*)
1103(*((c B-b C) Log[a+b Cos[d+e x]+c Sin[d+e x]])/(e (b^2+c^2))+(A (b^2+c^2)-a (b B+c C))/(b^2+c^2) \[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x*)
1104
1105
1106(* ::Subsubsection:: *)
1107(*Program code:*)
1108
1109
1110(* ::Code:: *)
1111Int[(A_.+B_.*Cos[d_.+e_.*x_]+C_.*Sin[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
1112  (b*B+c*C)*x/(b^2+c^2) + (c*B-b*C)*Log[a+b*Cos[d+e*x]+c*Sin[d+e*x]]/(e*(b^2+c^2)) +
1113  Dist[(A*(b^2+c^2)-a*(b*B+c*C))/(b^2+c^2),Int[1/(a+b*Cos[d+e*x]+c*Sin[d+e*x]),x]] /;
1114FreeQ[{a,b,c,d,e,A,B,C},x] && NonzeroQ[b^2+c^2] && NonzeroQ[A*(b^2+c^2)-a*(b*B+c*C)]
1115
1116
1117(* ::Subsubsection:: *)
1118(*Reference: G&R 2.558.2 with  B=0*)
1119
1120
1121(* ::Code:: *)
1122Int[(A_.+C_.*Sin[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
1123  c*C*(d+e*x)/(e*(b^2+c^2)) - b*C*Log[a+b*Cos[d+e*x]+c*Sin[d+e*x]]/(e*(b^2+c^2)) +
1124  Dist[(A*(b^2+c^2)-a*c*C)/(b^2+c^2),Int[1/(a+b*Cos[d+e*x]+c*Sin[d+e*x]),x]] /;
1125FreeQ[{a,b,c,d,e,A,C},x] && NonzeroQ[b^2+c^2] && NonzeroQ[A*(b^2+c^2)-a*c*C]
1126
1127
1128(* ::Subsubsection:: *)
1129(*Reference: G&R 2.558.2 with  C=0*)
1130
1131
1132(* ::Code:: *)
1133Int[(A_.+B_.*Cos[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_]),x_Symbol] :=
1134  b*B*(d+e*x)/(e*(b^2+c^2)) +
1135  c*B*Log[a+b*Cos[d+e*x]+c*Sin[d+e*x]]/(e*(b^2+c^2)) +
1136  Dist[(A*(b^2+c^2)-a*b*B)/(b^2+c^2),Int[1/(a+b*Cos[d+e*x]+c*Sin[d+e*x]),x]] /;
1137FreeQ[{a,b,c,d,e,A,B},x] && NonzeroQ[b^2+c^2] && NonzeroQ[A*(b^2+c^2)-a*b*B]
1138
1139
1140(* ::Subsubsection:: *)
1141(**)
1142
1143
1144(* ::Subsubsection:: *)
1145(*Reference: G&R 2.558.1 with  n=-2  and  a A-b B-c C=0*)
1146
1147
1148(* ::Subsubsection:: *)
1149(*Rule: If  a^2-b^2-c^2!=0 \[And] a A-b B-c C=0, then*)
1150
1151
1152(* ::Subsubtitle::Bold:: *)
1153(*\[Integral](A+B Cos[d+e x]+C Sin[d+e x])/(a+b Cos[d+e x]+c Sin[d+e x])^2 \[DifferentialD]x  \[LongRightArrow]  ((c B-b C-(a C-c A) Cos[d+e x]+(a B-b A) Sin[d+e x])/(e (a^2-b^2-c^2) (a+b Cos[d+e x]+c Sin[d+e x])))*)
1154
1155
1156(* ::Subsubsection:: *)
1157(*Program code:*)
1158
1159
1160(* ::Code:: *)
1161Int[(A_.+B_.*Cos[d_.+e_.*x_]+C_.*Sin[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^2,x_Symbol] :=
1162  (c*B-b*C-(a*C-c*A)*Cos[d+e*x]+(a*B-b*A)*Sin[d+e*x])/
1163    (e*(a^2-b^2-c^2)*(a+b*Cos[d+e*x]+c*Sin[d+e*x])) /;
1164FreeQ[{a,b,c,d,e,A,B,C},x] && NonzeroQ[a^2-b^2-c^2] && ZeroQ[a*A-b*B-c*C]
1165
1166
1167(* ::Subsubsection:: *)
1168(*Reference: G&R 2.558.1 with  B=0,  n=-2  and  a A-c C=0*)
1169
1170
1171(* ::Code:: *)
1172Int[(A_.+C_.*Sin[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^2,x_Symbol] :=
1173  -(b*C+(a*C-c*A)*Cos[d+e*x]+b*A*Sin[d+e*x])/(e*(a^2-b^2-c^2)*(a+b*Cos[d+e*x]+c*Sin[d+e*x])) /;
1174FreeQ[{a,b,c,d,e,A,C},x] && NonzeroQ[a^2-b^2-c^2] && ZeroQ[a*A-c*C]
1175
1176
1177(* ::Subsubsection:: *)
1178(*Reference: G&R 2.558.1 with  C=0,  n=-2  and  a A-b B=0*)
1179
1180
1181(* ::Code:: *)
1182Int[(A_.+B_.*Cos[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^2,x_Symbol] :=
1183  (c*B+c*A*Cos[d+e*x]+(a*B-b*A)*Sin[d+e*x])/(e*(a^2-b^2-c^2)*(a+b*Cos[d+e*x]+c*Sin[d+e*x])) /;
1184FreeQ[{a,b,c,d,e,A,B},x] && NonzeroQ[a^2-b^2-c^2] && ZeroQ[a*A-b*B]
1185
1186
1187(* ::Subsubsection:: *)
1188(**)
1189
1190
1191(* ::Subsubsection:: *)
1192(*Reference: G&R 2.558.1 with  n=-2*)
1193
1194
1195(* ::Subsubsection:: *)
1196(*Rule: If  a^2-b^2-c^2!=0 \[And] a A-b B-c C!=0, then*)
1197
1198
1199(* ::Subsubtitle::Bold:: *)
1200(*\[Integral](A+B Cos[d+e x]+C Sin[d+e x])/(a+b Cos[d+e x]+c Sin[d+e x])^2 \[DifferentialD]x  \[LongRightArrow]                                                                                                                 *)
1201(*((c B-b C-(a C-c A) Cos[d+e x]+(a B-b A) Sin[d+e x])/(e (a^2-b^2-c^2) (a+b Cos[d+e x]+c Sin[d+e x])))+(a A-b B-c C)/(a^2-b^2-c^2) \[Integral]1/(a+b Cos[d+e x]+c Sin[d+e x]) \[DifferentialD]x*)
1202
1203
1204(* ::Subsubsection:: *)
1205(*Program code:*)
1206
1207
1208(* ::Code:: *)
1209Int[(A_.+B_.*Cos[d_.+e_.*x_]+C_.*Sin[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^2,x_Symbol] :=
1210  (c*B-b*C-(a*C-c*A)*Cos[d+e*x]+(a*B-b*A)*Sin[d+e*x])/
1211    (e*(a^2-b^2-c^2)*(a+b*Cos[d+e*x]+c*Sin[d+e*x])) +
1212  Dist[(a*A-b*B-c*C)/(a^2-b^2-c^2),Int[1/(a+b*Cos[d+e*x]+c*Sin[d+e*x]),x]] /;
1213FreeQ[{a,b,c,d,e,A,B,C},x] && NonzeroQ[a^2-b^2-c^2] && NonzeroQ[a*A-b*B-c*C]
1214
1215
1216(* ::Subsubsection:: *)
1217(*Reference: G&R 2.558.1 with  B=0  and  n=-2*)
1218
1219
1220(* ::Code:: *)
1221Int[(A_.+C_.*Sin[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^2,x_Symbol] :=
1222  -(b*C+(a*C-c*A)*Cos[d+e*x]+b*A*Sin[d+e*x])/(e*(a^2-b^2-c^2)*(a+b*Cos[d+e*x]+c*Sin[d+e*x])) +
1223  Dist[(a*A-c*C)/(a^2-b^2-c^2),Int[1/(a+b*Cos[d+e*x]+c*Sin[d+e*x]),x]] /;
1224FreeQ[{a,b,c,d,e,A,C},x] && NonzeroQ[a^2-b^2-c^2] && NonzeroQ[a*A-c*C]
1225
1226
1227(* ::Subsubsection:: *)
1228(*Reference: G&R 2.558.1 with  C=0  and  n=-2*)
1229
1230
1231(* ::Code:: *)
1232Int[(A_.+B_.*Cos[d_.+e_.*x_])/(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^2,x_Symbol] :=
1233  (c*B+c*A*Cos[d+e*x]+(a*B-b*A)*Sin[d+e*x])/(e*(a^2-b^2-c^2)*(a+b*Cos[d+e*x]+c*Sin[d+e*x])) +
1234  Dist[(a*A-b*B)/(a^2-b^2-c^2),Int[1/(a+b*Cos[d+e*x]+c*Sin[d+e*x]),x]] /;
1235FreeQ[{a,b,c,d,e,A,B},x] && NonzeroQ[a^2-b^2-c^2] && NonzeroQ[a*A-b*B]
1236
1237
1238(* ::Subsubsection:: *)
1239(**)
1240
1241
1242(* ::Subsubsection:: *)
1243(*Reference: G&R 2.558.1*)
1244
1245
1246(* ::Subsubsection:: *)
1247(*Rule: If  a^2-b^2-c^2!=0 \[And] n<-1 \[And] n!=-2, then*)
1248
1249
1250(* ::Subsubtitle::Bold:: *)
1251(*\[Integral](A+B Cos[d+e x]+C Sin[d+e x])(a+b Cos[d+e x]+c Sin[d+e x])^n \[DifferentialD]x  \[LongRightArrow]  *)
1252(*-(((c B-b C-(a C-c A) Cos[d+e x]+(a B-b A) Sin[d+e x]) (a+b Cos[d+e x]+c Sin[d+e x])^(n+1))/(e (n+1) (a^2-b^2-c^2)))+*)
1253(*1/((n+1) (a^2-b^2-c^2)) \[Integral]((n+1) (a A-b B-c C)+(n+2) (a B-b A) Cos[d+e x]+(n+2) (a C-c A) Sin[d+e x]) (a+b Cos[d+e x]+c Sin[d+e x])^(n+1) \[DifferentialD]x*)
1254
1255
1256(* ::Subsubsection:: *)
1257(*Program code:*)
1258
1259
1260(* ::Code:: *)
1261Int[(A_.+B_.*Cos[d_.+e_.*x_]+C_.*Sin[d_.+e_.*x_])*(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^n_,x_Symbol] :=
1262  -(c*B-b*C-(a*C-c*A)*Cos[d+e*x]+(a*B-b*A)*Sin[d+e*x])*(a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n+1)/
1263    (e*(n+1)*(a^2-b^2-c^2)) +
1264  Dist[1/((n+1)*(a^2-b^2-c^2)),
1265    Int[((n+1)*(a*A-b*B-c*C)+(n+2)*(a*B-b*A)*Cos[d+e*x]+(n+2)*(a*C-c*A)*Sin[d+e*x])*
1266      (a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n+1),x]] /;
1267FreeQ[{a,b,c,d,e,A,B,C},x] && NonzeroQ[a^2-b^2-c^2] && RationalQ[n] && n<-1 && n!=-2
1268
1269
1270(* ::Subsubsection:: *)
1271(*Reference: G&R 2.558.1 with  B=0*)
1272
1273
1274(* ::Code:: *)
1275Int[(A_.+C_.*Sin[d_.+e_.*x_])*(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^n_,x_Symbol] :=
1276  (b*C+(a*C-c*A)*Cos[d+e*x]+b*A*Sin[d+e*x])*(a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n+1)/
1277    (e*(n+1)*(a^2-b^2-c^2)) +
1278  Dist[1/((n+1)*(a^2-b^2-c^2)),
1279    Int[((n+1)*(a*A-c*C)-(n+2)*b*A*Cos[d+e*x]+(n+2)*(a*C-c*A)*Sin[d+e*x])*
1280      (a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n+1),x]] /;
1281FreeQ[{a,b,c,d,e,A,C},x] && NonzeroQ[a^2-b^2-c^2] && RationalQ[n] && n<-1 && n!=-2
1282
1283
1284(* ::Subsubsection:: *)
1285(*Reference: G&R 2.558.1 with  C=0*)
1286
1287
1288(* ::Code:: *)
1289Int[(A_.+B_.*Cos[d_.+e_.*x_])*(a_.+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^n_,x_Symbol] :=
1290  -(c*B+c*A*Cos[d+e*x]+(a*B-b*A)*Sin[d+e*x])*(a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n+1)/
1291    (e*(n+1)*(a^2-b^2-c^2)) +
1292  Dist[1/((n+1)*(a^2-b^2-c^2)),
1293    Int[((n+1)*(a*A-b*B)+(n+2)*(a*B-b*A)*Cos[d+e*x]-(n+2)*c*A*Sin[d+e*x])*
1294      (a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n+1),x]] /;
1295FreeQ[{a,b,c,d,e,A,B},x] && NonzeroQ[a^2-b^2-c^2] && RationalQ[n] && n<-1 && n!=-2
1296
1297
1298(* ::Subsubsection:: *)
1299(**)
1300
1301
1302(* ::Subsubsection:: *)
1303(*Derivation: Algebraic simplification*)
1304
1305
1306(* ::Subsubsection:: *)
1307(*Basis: (A+B z) (a+b z)^n=B/b (a+b z)^(n+1)+(A b-a B)/b (a+b z)^n*)
1308
1309
1310(* ::Subsubsection:: *)
1311(*Rule: If  b C-c B=0 \[And] b A-a B!=0 \[And] (n=-(1/2) \[Or] a^2-b^2-c^2=0), then*)
1312
1313
1314(* ::Subsubtitle::Bold:: *)
1315(*\[Integral](A+B Cos[d+e x]+C Sin[d+e x])(a+b Cos[d+e x]+c Sin[d+e x])^n \[DifferentialD]x  \[LongRightArrow]                                                 *)
1316(*              (B/b)\[Integral](a+b Cos[d+e x]+c Sin[d+e x])^(n+1) \[DifferentialD]x+(b A-a B)/b \[Integral](a+b Cos[d+e x]+c Sin[d+e x])^n \[DifferentialD]x*)
1317
1318
1319(* ::Subsubsection:: *)
1320(*Program code:*)
1321
1322
1323(* ::Code:: *)
1324Int[(A_.+B_.*Cos[d_.+e_.*x_]+C_.*Sin[d_.+e_.*x_])*(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^n_,x_Symbol] :=
1325  Dist[B/b,Int[(a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n+1),x]] +
1326  Dist[(b*A-a*B)/b,Int[(a+b*Cos[d+e*x]+c*Sin[d+e*x])^n,x]] /;
1327FreeQ[{a,b,c,d,e,A,B,C},x] && ZeroQ[b*C-c*B] && NonzeroQ[b*A-a*B] && RationalQ[n] && (n==-1/2 || ZeroQ[a^2-b^2-c^2])
1328
1329
1330(* ::Subsubsection:: *)
1331(**)
1332
1333
1334(* ::Subsubsection:: *)
1335(*Reference: G&R 2.558.1 inverted*)
1336
1337
1338(* ::Subsubsection:: *)
1339(*Rule: If  a^2-b^2-c^2!=0 \[And] n\[Element]\[DoubleStruckCapitalF] \[And] n>0, then*)
1340
1341
1342(* ::Subsubtitle::Bold:: *)
1343(*\[Integral](A+B Cos[d+e x]+C Sin[d+e x])(a+b Cos[d+e x]+c Sin[d+e x])^n \[DifferentialD]x  \[LongRightArrow]  *)
1344(*(((B c-b C-a C Cos[d+e x]+a B Sin[d+e x]) (a+b Cos[d+e x]+c Sin[d+e x])^n)/(a e (n+1)))+*)
1345(*1/(a (n+1)) \[Integral](a (b B+c C) n+a^2 A (n+1)+(a^2 B n+c (b C-c B) n+a b A (n+1)) Cos[d+e x]+(a^2 C n-b (b C-c B) n+a c A (n+1)) Sin[d+e x]) (a+b Cos[d+e x]+c Sin[d+e x])^(n-1) \[DifferentialD]x*)
1346
1347
1348(* ::Subsubsection:: *)
1349(*Program code:*)
1350
1351
1352(* ::Code:: *)
1353Int[(A_.+B_.*Cos[d_.+e_.*x_]+C_.*Sin[d_.+e_.*x_])*(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^n_,x_Symbol] :=
1354  (B*c-b*C-a*C*Cos[d+e*x]+a*B*Sin[d+e*x])*(a+b*Cos[d+e*x]+c*Sin[d+e*x])^n/(a*e*(n+1)) +
1355  Dist[1/(a*(n+1)),
1356    Int[(a*(b*B+c*C)*n + a^2*A*(n+1) +
1357        (a^2*B*n + c*(b*C-c*B)*n + a*b*A*(n+1))*Cos[d+e*x] +
1358        (a^2*C*n - b*(b*C-c*B)*n + a*c*A*(n+1))*Sin[d+e*x])*
1359      (a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n-1),x]] /;
1360FreeQ[{a,b,c,d,e,A,B,C},x] && NonzeroQ[a^2-b^2-c^2] && RationalQ[n] && n>0
1361
1362
1363(* ::Subsubsection:: *)
1364(*Reference: G&R 2.558.1 inverted with B=0*)
1365
1366
1367(* ::Code:: *)
1368Int[(A_.+C_.*Sin[d_.+e_.*x_])*(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^n_,x_Symbol] :=
1369  -(b*C+a*C*Cos[d+e*x])*(a+b*Cos[d+e*x]+c*Sin[d+e*x])^n/(a*e*(n+1)) +
1370  Dist[1/(a*(n+1)),
1371    Int[(a*c*C*n+a^2*A*(n+1)+(c*b*C*n+a*b*A*(n+1))*Cos[d+e*x]+(a^2*C*n-b^2*C*n+a*c*A*(n+1))*Sin[d+e*x])*
1372      (a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n-1),x]] /;
1373FreeQ[{a,b,c,d,e,A,C},x] && NonzeroQ[a^2-b^2-c^2] && RationalQ[n] && n>0
1374
1375
1376(* ::Subsubsection:: *)
1377(*Reference: G&R 2.558.1 inverted with C=0*)
1378
1379
1380(* ::Code:: *)
1381Int[(A_.+B_.*Cos[d_.+e_.*x_])*(a_+b_.*Cos[d_.+e_.*x_]+c_.*Sin[d_.+e_.*x_])^n_,x_Symbol] :=
1382  (B*c+a*B*Sin[d+e*x])*(a+b*Cos[d+e*x]+c*Sin[d+e*x])^n/(a*e*(n+1)) +
1383  Dist[1/(a*(n+1)),
1384    Int[(a*b*B*n+a^2*A*(n+1)+(a^2*B*n-c^2*B*n+a*b*A*(n+1))*Cos[d+e*x]+(b*c*B*n+a*c*A*(n+1))*Sin[d+e*x])*
1385      (a+b*Cos[d+e*x]+c*Sin[d+e*x])^(n-1),x]] /;
1386FreeQ[{a,b,c,d,e,A,B},x] && NonzeroQ[a^2-b^2-c^2] && RationalQ[n] && n>0
1387
1388
1389(* ::PageBreak:: *)
1390(**)
1391