1i18n = import('i18n')
2
3install_data(
4  'uk.co.ibboard.cawbird.gschema.xml',
5  install_dir: join_paths(get_option('datadir'), 'glib-2.0', 'schemas')
6)
7meson.add_install_script('meson_post_install.py')
8
9i18n.merge_file(
10  input:  'uk.co.ibboard.cawbird.desktop.in',
11  output: 'uk.co.ibboard.cawbird.desktop',
12  po_dir: '../po/',
13  type:   'desktop',
14  install: true,
15  install_dir: join_paths(get_option('datadir'), 'applications')
16)
17
18if get_option('appdata')
19  i18n.merge_file(
20    input:  'uk.co.ibboard.cawbird.appdata.xml.in',
21    output: 'uk.co.ibboard.cawbird.appdata.xml',
22    po_dir: '../po/',
23    type:   'xml',
24    install: true,
25    install_dir: join_paths(get_option('datadir'), 'metainfo')
26  )
27endif
28
29install_man('cawbird.1')
30
31conf = configuration_data()
32conf.set('bindir', join_paths(get_option('prefix'), 'bin'))
33
34configure_file(
35  input: 'uk.co.ibboard.cawbird.service.in',
36  output: 'uk.co.ibboard.cawbird.service',
37  configuration: conf,
38  install_dir: join_paths(get_option('datadir'), 'dbus-1/services')
39)
40
41gnome.compile_schemas(
42  build_by_default: true,
43  depend_files: ['uk.co.ibboard.cawbird.gschema.xml']
44)
45
46# Install all application icons in one go
47install_subdir(
48  'hicolor',
49  install_dir: join_paths(get_option('datadir'), 'icons')
50)
51