1TARGET     = QtWidgets
2QT = core-private gui-private
3MODULE_CONFIG = uic
4
5CONFIG += $$MODULE_CONFIG
6DEFINES   += QT_NO_USING_NAMESPACE
7msvc:equals(QT_ARCH, i386): QMAKE_LFLAGS += /BASE:0x65000000
8
9TRACEPOINT_PROVIDER = $$PWD/qtwidgets.tracepoints
10CONFIG += qt_tracepoints
11
12QMAKE_DOCS = $$PWD/doc/qtwidgets.qdocconf
13
14#platforms
15mac:include(kernel/mac.pri)
16win32:include(kernel/win.pri)
17
18#modules
19include(kernel/kernel.pri)
20include(styles/styles.pri)
21include(widgets/widgets.pri)
22include(dialogs/dialogs.pri)
23include(accessible/accessible.pri)
24include(itemviews/itemviews.pri)
25include(graphicsview/graphicsview.pri)
26include(util/util.pri)
27include(statemachine/statemachine.pri)
28
29qtConfig(graphicseffect) {
30    include(effects/effects.pri)
31}
32
33QMAKE_LIBS += $$QMAKE_LIBS_GUI
34
35QMAKE_DYNAMIC_LIST_FILE = $$PWD/QtWidgets.dynlist
36
37# Code coverage with TestCocoon
38# The following is required as extra compilers use $$QMAKE_CXX instead of $(CXX).
39# Without this, testcocoon.prf is read only after $$QMAKE_CXX is used by the
40# extra compilers.
41testcocoon {
42    load(testcocoon)
43}
44
45MODULE_PLUGIN_TYPES += \
46    styles
47load(qt_module)
48
49CONFIG += metatypes install_metatypes
50