1;
2; jdcolext.asm - colorspace conversion (AVX2)
3;
4; Copyright 2009, 2012 Pierre Ossman <ossman@cendio.se> for Cendio AB
5; Copyright (C) 2012, 2016, D. R. Commander.
6; Copyright (C) 2015, Intel Corporation.
7;
8; Based on the x86 SIMD extension for IJG JPEG library
9; Copyright (C) 1999-2006, MIYASAKA Masaru.
10; For conditions of distribution and use, see copyright notice in jsimdext.inc
11;
12; This file should be assembled with NASM (Netwide Assembler),
13; can *not* be assembled with Microsoft's MASM or any compatible
14; assembler (including Borland's Turbo Assembler).
15; NASM is available from http://nasm.sourceforge.net/ or
16; http://sourceforge.net/project/showfiles.php?group_id=6208
17
18%include "jcolsamp.inc"
19
20; --------------------------------------------------------------------------
21;
22; Convert some rows of samples to the output colorspace.
23;
24; GLOBAL(void)
25; jsimd_ycc_rgb_convert_avx2(JDIMENSION out_width, JSAMPIMAGE input_buf,
26;                            JDIMENSION input_row, JSAMPARRAY output_buf,
27;                            int num_rows)
28;
29
30%define out_width(b)   (b) + 8          ; JDIMENSION out_width
31%define input_buf(b)   (b) + 12         ; JSAMPIMAGE input_buf
32%define input_row(b)   (b) + 16         ; JDIMENSION input_row
33%define output_buf(b)  (b) + 20         ; JSAMPARRAY output_buf
34%define num_rows(b)    (b) + 24         ; int num_rows
35
36%define original_ebp   ebp + 0
37%define wk(i)          ebp - (WK_NUM - (i)) * SIZEOF_YMMWORD
38                                        ; ymmword wk[WK_NUM]
39%define WK_NUM         2
40%define gotptr         wk(0) - SIZEOF_POINTER  ; void * gotptr
41
42    align       32
43    GLOBAL_FUNCTION(jsimd_ycc_rgb_convert_avx2)
44
45EXTN(jsimd_ycc_rgb_convert_avx2):
46    push        ebp
47    mov         eax, esp                     ; eax = original ebp
48    sub         esp, byte 4
49    and         esp, byte (-SIZEOF_YMMWORD)  ; align to 256 bits
50    mov         [esp], eax
51    mov         ebp, esp                     ; ebp = aligned ebp
52    lea         esp, [wk(0)]
53    pushpic     eax                     ; make a room for GOT address
54    push        ebx
55;   push        ecx                     ; need not be preserved
56;   push        edx                     ; need not be preserved
57    push        esi
58    push        edi
59
60    get_GOT     ebx                     ; get GOT address
61    movpic      POINTER [gotptr], ebx   ; save GOT address
62
63    mov         ecx, JDIMENSION [out_width(eax)]  ; num_cols
64    test        ecx, ecx
65    jz          near .return
66
67    push        ecx
68
69    mov         edi, JSAMPIMAGE [input_buf(eax)]
70    mov         ecx, JDIMENSION [input_row(eax)]
71    mov         esi, JSAMPARRAY [edi+0*SIZEOF_JSAMPARRAY]
72    mov         ebx, JSAMPARRAY [edi+1*SIZEOF_JSAMPARRAY]
73    mov         edx, JSAMPARRAY [edi+2*SIZEOF_JSAMPARRAY]
74    lea         esi, [esi+ecx*SIZEOF_JSAMPROW]
75    lea         ebx, [ebx+ecx*SIZEOF_JSAMPROW]
76    lea         edx, [edx+ecx*SIZEOF_JSAMPROW]
77
78    pop         ecx
79
80    mov         edi, JSAMPARRAY [output_buf(eax)]
81    mov         eax, INT [num_rows(eax)]
82    test        eax, eax
83    jle         near .return
84    alignx      16, 7
85.rowloop:
86    push        eax
87    push        edi
88    push        edx
89    push        ebx
90    push        esi
91    push        ecx                     ; col
92
93    mov         esi, JSAMPROW [esi]     ; inptr0
94    mov         ebx, JSAMPROW [ebx]     ; inptr1
95    mov         edx, JSAMPROW [edx]     ; inptr2
96    mov         edi, JSAMPROW [edi]     ; outptr
97    movpic      eax, POINTER [gotptr]   ; load GOT address (eax)
98    alignx      16, 7
99.columnloop:
100
101    vmovdqu     ymm5, YMMWORD [ebx]     ; ymm5=Cb(0123456789ABCDEFGHIJKLMNOPQRSTUV)
102    vmovdqu     ymm1, YMMWORD [edx]     ; ymm1=Cr(0123456789ABCDEFGHIJKLMNOPQRSTUV)
103
104    vpcmpeqw    ymm0, ymm0, ymm0
105    vpcmpeqw    ymm7, ymm7, ymm7
106    vpsrlw      ymm0, ymm0, BYTE_BIT    ; ymm0={0xFF 0x00 0xFF 0x00 ..}
107    vpsllw      ymm7, ymm7, 7           ; ymm7={0xFF80 0xFF80 0xFF80 0xFF80 ..}
108
109    vpand       ymm4, ymm0, ymm5        ; ymm4=Cb(02468ACEGIKMOQSU)=CbE
110    vpsrlw      ymm5, ymm5, BYTE_BIT    ; ymm5=Cb(13579BDFHJLNPRTV)=CbO
111    vpand       ymm0, ymm0, ymm1        ; ymm0=Cr(02468ACEGIKMOQSU)=CrE
112    vpsrlw      ymm1, ymm1, BYTE_BIT    ; ymm1=Cr(13579BDFHJLNPRTV)=CrO
113
114    vpaddw      ymm2, ymm4, ymm7
115    vpaddw      ymm3, ymm5, ymm7
116    vpaddw      ymm6, ymm0, ymm7
117    vpaddw      ymm7, ymm1, ymm7
118
119    ; (Original)
120    ; R = Y                + 1.40200 * Cr
121    ; G = Y - 0.34414 * Cb - 0.71414 * Cr
122    ; B = Y + 1.77200 * Cb
123    ;
124    ; (This implementation)
125    ; R = Y                + 0.40200 * Cr + Cr
126    ; G = Y - 0.34414 * Cb + 0.28586 * Cr - Cr
127    ; B = Y - 0.22800 * Cb + Cb + Cb
128
129    vpaddw      ymm4, ymm2, ymm2                     ; ymm4=2*CbE
130    vpaddw      ymm5, ymm3, ymm3                     ; ymm5=2*CbO
131    vpaddw      ymm0, ymm6, ymm6                     ; ymm0=2*CrE
132    vpaddw      ymm1, ymm7, ymm7                     ; ymm1=2*CrO
133
134    vpmulhw     ymm4, ymm4, [GOTOFF(eax,PW_MF0228)]  ; ymm4=(2*CbE * -FIX(0.22800))
135    vpmulhw     ymm5, ymm5, [GOTOFF(eax,PW_MF0228)]  ; ymm5=(2*CbO * -FIX(0.22800))
136    vpmulhw     ymm0, ymm0, [GOTOFF(eax,PW_F0402)]   ; ymm0=(2*CrE * FIX(0.40200))
137    vpmulhw     ymm1, ymm1, [GOTOFF(eax,PW_F0402)]   ; ymm1=(2*CrO * FIX(0.40200))
138
139    vpaddw      ymm4, ymm4, [GOTOFF(eax,PW_ONE)]
140    vpaddw      ymm5, ymm5, [GOTOFF(eax,PW_ONE)]
141    vpsraw      ymm4, ymm4, 1                        ; ymm4=(CbE * -FIX(0.22800))
142    vpsraw      ymm5, ymm5, 1                        ; ymm5=(CbO * -FIX(0.22800))
143    vpaddw      ymm0, ymm0, [GOTOFF(eax,PW_ONE)]
144    vpaddw      ymm1, ymm1, [GOTOFF(eax,PW_ONE)]
145    vpsraw      ymm0, ymm0, 1                        ; ymm0=(CrE * FIX(0.40200))
146    vpsraw      ymm1, ymm1, 1                        ; ymm1=(CrO * FIX(0.40200))
147
148    vpaddw      ymm4, ymm4, ymm2
149    vpaddw      ymm5, ymm5, ymm3
150    vpaddw      ymm4, ymm4, ymm2                     ; ymm4=(CbE * FIX(1.77200))=(B-Y)E
151    vpaddw      ymm5, ymm5, ymm3                     ; ymm5=(CbO * FIX(1.77200))=(B-Y)O
152    vpaddw      ymm0, ymm0, ymm6                     ; ymm0=(CrE * FIX(1.40200))=(R-Y)E
153    vpaddw      ymm1, ymm1, ymm7                     ; ymm1=(CrO * FIX(1.40200))=(R-Y)O
154
155    vmovdqa     YMMWORD [wk(0)], ymm4                ; wk(0)=(B-Y)E
156    vmovdqa     YMMWORD [wk(1)], ymm5                ; wk(1)=(B-Y)O
157
158    vpunpckhwd  ymm4, ymm2, ymm6
159    vpunpcklwd  ymm2, ymm2, ymm6
160    vpmaddwd    ymm2, ymm2, [GOTOFF(eax,PW_MF0344_F0285)]
161    vpmaddwd    ymm4, ymm4, [GOTOFF(eax,PW_MF0344_F0285)]
162    vpunpckhwd  ymm5, ymm3, ymm7
163    vpunpcklwd  ymm3, ymm3, ymm7
164    vpmaddwd    ymm3, ymm3, [GOTOFF(eax,PW_MF0344_F0285)]
165    vpmaddwd    ymm5, ymm5, [GOTOFF(eax,PW_MF0344_F0285)]
166
167    vpaddd      ymm2, ymm2, [GOTOFF(eax,PD_ONEHALF)]
168    vpaddd      ymm4, ymm4, [GOTOFF(eax,PD_ONEHALF)]
169    vpsrad      ymm2, ymm2, SCALEBITS
170    vpsrad      ymm4, ymm4, SCALEBITS
171    vpaddd      ymm3, ymm3, [GOTOFF(eax,PD_ONEHALF)]
172    vpaddd      ymm5, ymm5, [GOTOFF(eax,PD_ONEHALF)]
173    vpsrad      ymm3, ymm3, SCALEBITS
174    vpsrad      ymm5, ymm5, SCALEBITS
175
176    vpackssdw   ymm2, ymm2, ymm4             ; ymm2=CbE*-FIX(0.344)+CrE*FIX(0.285)
177    vpackssdw   ymm3, ymm3, ymm5             ; ymm3=CbO*-FIX(0.344)+CrO*FIX(0.285)
178    vpsubw      ymm2, ymm2, ymm6             ; ymm2=CbE*-FIX(0.344)+CrE*-FIX(0.714)=(G-Y)E
179    vpsubw      ymm3, ymm3, ymm7             ; ymm3=CbO*-FIX(0.344)+CrO*-FIX(0.714)=(G-Y)O
180
181    vmovdqu     ymm5, YMMWORD [esi]          ; ymm5=Y(0123456789ABCDEFGHIJKLMNOPQRSTUV)
182
183    vpcmpeqw    ymm4, ymm4, ymm4
184    vpsrlw      ymm4, ymm4, BYTE_BIT         ; ymm4={0xFF 0x00 0xFF 0x00 ..}
185    vpand       ymm4, ymm4, ymm5             ; ymm4=Y(02468ACEGIKMOQSU)=YE
186    vpsrlw      ymm5, ymm5, BYTE_BIT         ; ymm5=Y(13579BDFHJLNPRTV)=YO
187
188    vpaddw      ymm0, ymm0, ymm4             ; ymm0=((R-Y)E+YE)=RE=R(02468ACEGIKMOQSU)
189    vpaddw      ymm1, ymm1, ymm5             ; ymm1=((R-Y)O+YO)=RO=R(13579BDFHJLNPRTV)
190    vpackuswb   ymm0, ymm0, ymm0             ; ymm0=R(02468ACE********GIKMOQSU********)
191    vpackuswb   ymm1, ymm1, ymm1             ; ymm1=R(13579BDF********HJLNPRTV********)
192
193    vpaddw      ymm2, ymm2, ymm4             ; ymm2=((G-Y)E+YE)=GE=G(02468ACEGIKMOQSU)
194    vpaddw      ymm3, ymm3, ymm5             ; ymm3=((G-Y)O+YO)=GO=G(13579BDFHJLNPRTV)
195    vpackuswb   ymm2, ymm2, ymm2             ; ymm2=G(02468ACE********GIKMOQSU********)
196    vpackuswb   ymm3, ymm3, ymm3             ; ymm3=G(13579BDF********HJLNPRTV********)
197
198    vpaddw      ymm4, ymm4, YMMWORD [wk(0)]  ; ymm4=(YE+(B-Y)E)=BE=B(02468ACEGIKMOQSU)
199    vpaddw      ymm5, ymm5, YMMWORD [wk(1)]  ; ymm5=(YO+(B-Y)O)=BO=B(13579BDFHJLNPRTV)
200    vpackuswb   ymm4, ymm4, ymm4             ; ymm4=B(02468ACE********GIKMOQSU********)
201    vpackuswb   ymm5, ymm5, ymm5             ; ymm5=B(13579BDF********HJLNPRTV********)
202
203%if RGB_PIXELSIZE == 3  ; ---------------
204
205    ; ymmA=(00 02 04 06 08 0A 0C 0E ** 0G 0I 0K 0M 0O 0Q 0S 0U **)
206    ; ymmB=(01 03 05 07 09 0B 0D 0F ** 0H 0J 0L 0N 0P 0R 0T 0V **)
207    ; ymmC=(10 12 14 16 18 1A 1C 1E ** 1G 1I 1K 1M 1O 1Q 1S 1U **)
208    ; ymmD=(11 13 15 17 19 1B 1D 1F ** 1H 1J 1L 1N 1P 1R 1T 1V **)
209    ; ymmE=(20 22 24 26 28 2A 2C 2E ** 2G 2I 2K 2M 2O 2Q 2S 2U **)
210    ; ymmF=(21 23 25 27 29 2B 2D 2F ** 2H 2J 2L 2N 2P 2R 2T 2V **)
211    ; ymmG=(** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** **)
212    ; ymmH=(** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** **)
213
214    vpunpcklbw  ymmA, ymmA, ymmC        ; ymmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E
215                                        ;       0G 1G 0I 1I 0K 1K 0M 1M 0O 1O 0Q 1Q 0S 1S 0U 1U)
216    vpunpcklbw  ymmE, ymmE, ymmB        ; ymmE=(20 01 22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F
217                                        ;       2G 0H 2I 0J 2K 0L 2M 0N 2O 0P 2Q 0R 2S 0T 2U 0V)
218    vpunpcklbw  ymmD, ymmD, ymmF        ; ymmD=(11 21 13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F
219                                        ;       1H 2H 1J 2J 1L 2L 1N 2N 1P 2P 1R 2R 1T 2T 1V 2V)
220
221    vpsrldq     ymmH, ymmA, 2           ; ymmH=(02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E 0G 1G
222                                        ;       0I 1I 0K 1K 0M 1M 0O 1O 0Q 1Q 0S 1S 0U 1U -- --)
223    vpunpckhwd  ymmG, ymmA, ymmE        ; ymmG=(08 18 28 09 0A 1A 2A 0B 0C 1C 2C 0D 0E 1E 2E 0F
224                                        ;       0O 1O 2O 0P 0Q 1Q 2Q 0R 0S 1S 2S 0T 0U 1U 2U 0V)
225    vpunpcklwd  ymmA, ymmA, ymmE        ; ymmA=(00 10 20 01 02 12 22 03 04 14 24 05 06 16 26 07
226                                        ;       0G 1G 2G 0H 0I 1I 2I 0J 0K 1K 2K 0L 0M 1M 2M 0N)
227
228    vpsrldq     ymmE, ymmE, 2           ; ymmE=(22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F 2G 0H
229                                        ;       2I 0J 2K 0L 2M 0N 2O 0P 2Q 0R 2S 0T 2U 0V -- --)
230
231    vpsrldq     ymmB, ymmD, 2           ; ymmB=(13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F 1H 2H
232                                        ;       1J 2J 1L 2L 1N 2N 1P 2P 1R 2R 1T 2T 1V 2V -- --)
233    vpunpckhwd  ymmC, ymmD, ymmH        ; ymmC=(19 29 0A 1A 1B 2B 0C 1C 1D 2D 0E 1E 1F 2F 0G 1G
234                                        ;       1P 2P 0Q 1Q 1R 2R 0S 1S 1T 2T 0U 1U 1V 2V -- --)
235    vpunpcklwd  ymmD, ymmD, ymmH        ; ymmD=(11 21 02 12 13 23 04 14 15 25 06 16 17 27 08 18
236                                        ;       1H 2H 0I 1I 1J 2J 0K 1K 1L 2L 0M 1M 1N 2N 0O 1O)
237
238    vpunpckhwd  ymmF, ymmE, ymmB        ; ymmF=(2A 0B 1B 2B 2C 0D 1D 2D 2E 0F 1F 2F 2G 0H 1H 2H
239                                        ;       2Q 0R 1R 2R 2S 0T 1T 2T 2U 0V 1V 2V -- -- -- --)
240    vpunpcklwd  ymmE, ymmE, ymmB        ; ymmE=(22 03 13 23 24 05 15 25 26 07 17 27 28 09 19 29
241                                        ;       2I 0J 1J 2J 2K 0L 1L 2L 2M 0N 1N 2N 2O 0P 1P 2P)
242
243    vpshufd     ymmH, ymmA, 0x4E        ; ymmH=(04 14 24 05 06 16 26 07 00 10 20 01 02 12 22 03
244                                        ;       0K 1K 2K 0L 0M 1M 2M 0N 0G 1G 2G 0H 0I 1I 2I 0J)
245    vpunpckldq  ymmA, ymmA, ymmD        ; ymmA=(00 10 20 01 11 21 02 12 02 12 22 03 13 23 04 14
246                                        ;       0G 1G 2G 0H 1H 2H 0I 1I 0I 1I 2I 0J 1J 2J 0K 1K)
247    vpunpckhdq  ymmD, ymmD, ymmE        ; ymmD=(15 25 06 16 26 07 17 27 17 27 08 18 28 09 19 29
248                                        ;       1L 2L 0M 1M 2M 0N 1N 2N 1N 2N 0O 1O 2O 0P 1P 2P)
249    vpunpckldq  ymmE, ymmE, ymmH        ; ymmE=(22 03 13 23 04 14 24 05 24 05 15 25 06 16 26 07
250                                        ;       2I 0J 1J 2J 0K 1K 2K 0L 2K 0L 1L 2L 0M 1M 2M 0N)
251
252    vpshufd     ymmH, ymmG, 0x4E        ; ymmH=(0C 1C 2C 0D 0E 1E 2E 0F 08 18 28 09 0A 1A 2A 0B
253                                        ;       0S 1S 2S 0T 0U 1U 2U 0V 0O 1O 2O 0P 0Q 1Q 2Q 0R)
254    vpunpckldq  ymmG, ymmG, ymmC        ; ymmG=(08 18 28 09 19 29 0A 1A 0A 1A 2A 0B 1B 2B 0C 1C
255                                        ;       0O 1O 2O 0P 1P 2P 0Q 1Q 0Q 1Q 2Q 0R 1R 2R 0S 1S)
256    vpunpckhdq  ymmC, ymmC, ymmF        ; ymmC=(1D 2D 0E 1E 2E 0F 1F 2F 1F 2F 0G 1G 2G 0H 1H 2H
257                                        ;       1T 2T 0U 1U 2U 0V 1V 2V 1V 2V -- -- -- -- -- --)
258    vpunpckldq  ymmF, ymmF, ymmH        ; ymmF=(2A 0B 1B 2B 0C 1C 2C 0D 2C 0D 1D 2D 0E 1E 2E 0F
259                                        ;       2Q 0R 1R 2R 0S 1S 2S 0T 2S 0T 1T 2T 0U 1U 2U 0V)
260
261    vpunpcklqdq ymmH, ymmA, ymmE        ; ymmH=(00 10 20 01 11 21 02 12 22 03 13 23 04 14 24 05
262                                        ;       0G 1G 2G 0H 1H 2H 0I 1I 2I 0J 1J 2J 0K 1K 2K 0L)
263    vpunpcklqdq ymmG, ymmD, ymmG        ; ymmG=(15 25 06 16 26 07 17 27 08 18 28 09 19 29 0A 1A
264                                        ;       1L 2L 0M 1M 2M 0N 1N 2N 0O 1O 2O 0P 1P 2P 0Q 1Q)
265    vpunpcklqdq ymmC, ymmF, ymmC        ; ymmC=(2A 0B 1B 2B 0C 1C 2C 0D 1D 2D 0E 1E 2E 0F 1F 2F
266                                        ;       2Q 0R 1R 2R 0S 1S 2S 0T 1T 2T 0U 1U 2U 0V 1V 2V)
267
268    vperm2i128  ymmA, ymmH, ymmG, 0x20  ; ymmA=(00 10 20 01 11 21 02 12 22 03 13 23 04 14 24 05
269                                        ;       15 25 06 16 26 07 17 27 08 18 28 09 19 29 0A 1A)
270    vperm2i128  ymmD, ymmC, ymmH, 0x30  ; ymmD=(2A 0B 1B 2B 0C 1C 2C 0D 1D 2D 0E 1E 2E 0F 1F 2F
271                                        ;       0G 1G 2G 0H 1H 2H 0I 1I 2I 0J 1J 2J 0K 1K 2K 0L)
272    vperm2i128  ymmF, ymmG, ymmC, 0x31  ; ymmF=(1L 2L 0M 1M 2M 0N 1N 2N 0O 1O 2O 0P 1P 2P 0Q 1Q
273                                        ;       2Q 0R 1R 2R 0S 1S 2S 0T 1T 2T 0U 1U 2U 0V 1V 2V)
274
275    cmp         ecx, byte SIZEOF_YMMWORD
276    jb          short .column_st64
277
278    test        edi, SIZEOF_YMMWORD-1
279    jnz         short .out1
280    ; --(aligned)-------------------
281    vmovntdq    YMMWORD [edi+0*SIZEOF_YMMWORD], ymmA
282    vmovntdq    YMMWORD [edi+1*SIZEOF_YMMWORD], ymmD
283    vmovntdq    YMMWORD [edi+2*SIZEOF_YMMWORD], ymmF
284    jmp         short .out0
285.out1:  ; --(unaligned)-----------------
286    vmovdqu     YMMWORD [edi+0*SIZEOF_YMMWORD], ymmA
287    vmovdqu     YMMWORD [edi+1*SIZEOF_YMMWORD], ymmD
288    vmovdqu     YMMWORD [edi+2*SIZEOF_YMMWORD], ymmF
289.out0:
290    add         edi, byte RGB_PIXELSIZE*SIZEOF_YMMWORD  ; outptr
291    sub         ecx, byte SIZEOF_YMMWORD
292    jz          near .nextrow
293
294    add         esi, byte SIZEOF_YMMWORD  ; inptr0
295    add         ebx, byte SIZEOF_YMMWORD  ; inptr1
296    add         edx, byte SIZEOF_YMMWORD  ; inptr2
297    jmp         near .columnloop
298    alignx      16, 7
299
300.column_st64:
301    lea         ecx, [ecx+ecx*2]            ; imul ecx, RGB_PIXELSIZE
302    cmp         ecx, byte 2*SIZEOF_YMMWORD
303    jb          short .column_st32
304    vmovdqu     YMMWORD [edi+0*SIZEOF_YMMWORD], ymmA
305    vmovdqu     YMMWORD [edi+1*SIZEOF_YMMWORD], ymmD
306    add         edi, byte 2*SIZEOF_YMMWORD  ; outptr
307    vmovdqa     ymmA, ymmF
308    sub         ecx, byte 2*SIZEOF_YMMWORD
309    jmp         short .column_st31
310.column_st32:
311    cmp         ecx, byte SIZEOF_YMMWORD
312    jb          short .column_st31
313    vmovdqu     YMMWORD [edi+0*SIZEOF_YMMWORD], ymmA
314    add         edi, byte SIZEOF_YMMWORD    ; outptr
315    vmovdqa     ymmA, ymmD
316    sub         ecx, byte SIZEOF_YMMWORD
317    jmp         short .column_st31
318.column_st31:
319    cmp         ecx, byte SIZEOF_XMMWORD
320    jb          short .column_st15
321    vmovdqu     XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
322    add         edi, byte SIZEOF_XMMWORD    ; outptr
323    vperm2i128  ymmA, ymmA, ymmA, 1
324    sub         ecx, byte SIZEOF_XMMWORD
325.column_st15:
326    ; Store the lower 8 bytes of xmmA to the output when it has enough
327    ; space.
328    cmp         ecx, byte SIZEOF_MMWORD
329    jb          short .column_st7
330    vmovq       XMM_MMWORD [edi], xmmA
331    add         edi, byte SIZEOF_MMWORD
332    sub         ecx, byte SIZEOF_MMWORD
333    vpsrldq     xmmA, xmmA, SIZEOF_MMWORD
334.column_st7:
335    ; Store the lower 4 bytes of xmmA to the output when it has enough
336    ; space.
337    cmp         ecx, byte SIZEOF_DWORD
338    jb          short .column_st3
339    vmovd       XMM_DWORD [edi], xmmA
340    add         edi, byte SIZEOF_DWORD
341    sub         ecx, byte SIZEOF_DWORD
342    vpsrldq     xmmA, xmmA, SIZEOF_DWORD
343.column_st3:
344    ; Store the lower 2 bytes of eax to the output when it has enough
345    ; space.
346    vmovd       eax, xmmA
347    cmp         ecx, byte SIZEOF_WORD
348    jb          short .column_st1
349    mov         word [edi], ax
350    add         edi, byte SIZEOF_WORD
351    sub         ecx, byte SIZEOF_WORD
352    shr         eax, 16
353.column_st1:
354    ; Store the lower 1 byte of eax to the output when it has enough
355    ; space.
356    test        ecx, ecx
357    jz          short .nextrow
358    mov         byte [edi], al
359
360%else  ; RGB_PIXELSIZE == 4 ; -----------
361
362%ifdef RGBX_FILLER_0XFF
363    vpcmpeqb    ymm6, ymm6, ymm6        ; ymm6=XE=X(02468ACE********GIKMOQSU********)
364    vpcmpeqb    ymm7, ymm7, ymm7        ; ymm7=XO=X(13579BDF********HJLNPRTV********)
365%else
366    vpxor       ymm6, ymm6, ymm6        ; ymm6=XE=X(02468ACE********GIKMOQSU********)
367    vpxor       ymm7, ymm7, ymm7        ; ymm7=XO=X(13579BDF********HJLNPRTV********)
368%endif
369    ; ymmA=(00 02 04 06 08 0A 0C 0E ** 0G 0I 0K 0M 0O 0Q 0S 0U **)
370    ; ymmB=(01 03 05 07 09 0B 0D 0F ** 0H 0J 0L 0N 0P 0R 0T 0V **)
371    ; ymmC=(10 12 14 16 18 1A 1C 1E ** 1G 1I 1K 1M 1O 1Q 1S 1U **)
372    ; ymmD=(11 13 15 17 19 1B 1D 1F ** 1H 1J 1L 1N 1P 1R 1T 1V **)
373    ; ymmE=(20 22 24 26 28 2A 2C 2E ** 2G 2I 2K 2M 2O 2Q 2S 2U **)
374    ; ymmF=(21 23 25 27 29 2B 2D 2F ** 2H 2J 2L 2N 2P 2R 2T 2V **)
375    ; ymmG=(30 32 34 36 38 3A 3C 3E ** 3G 3I 3K 3M 3O 3Q 3S 3U **)
376    ; ymmH=(31 33 35 37 39 3B 3D 3F ** 3H 3J 3L 3N 3P 3R 3T 3V **)
377
378    vpunpcklbw  ymmA, ymmA, ymmC        ; ymmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E
379                                        ;       0G 1G 0I 1I 0K 1K 0M 1M 0O 1O 0Q 1Q 0S 1S 0U 1U)
380    vpunpcklbw  ymmE, ymmE, ymmG        ; ymmE=(20 30 22 32 24 34 26 36 28 38 2A 3A 2C 3C 2E 3E
381                                        ;       2G 3G 2I 3I 2K 3K 2M 3M 2O 3O 2Q 3Q 2S 3S 2U 3U)
382    vpunpcklbw  ymmB, ymmB, ymmD        ; ymmB=(01 11 03 13 05 15 07 17 09 19 0B 1B 0D 1D 0F 1F
383                                        ;       0H 1H 0J 1J 0L 1L 0N 1N 0P 1P 0R 1R 0T 1T 0V 1V)
384    vpunpcklbw  ymmF, ymmF, ymmH        ; ymmF=(21 31 23 33 25 35 27 37 29 39 2B 3B 2D 3D 2F 3F
385                                        ;       2H 3H 2J 3J 2L 3L 2N 3N 2P 3P 2R 3R 2T 3T 2V 3V)
386
387    vpunpckhwd  ymmC, ymmA, ymmE        ; ymmC=(08 18 28 38 0A 1A 2A 3A 0C 1C 2C 3C 0E 1E 2E 3E
388                                        ;       0O 1O 2O 3O 0Q 1Q 2Q 3Q 0S 1S 2S 3S 0U 1U 2U 3U)
389    vpunpcklwd  ymmA, ymmA, ymmE        ; ymmA=(00 10 20 30 02 12 22 32 04 14 24 34 06 16 26 36
390                                        ;       0G 1G 2G 3G 0I 1I 2I 3I 0K 1K 2K 3K 0M 1M 2M 3M)
391    vpunpckhwd  ymmG, ymmB, ymmF        ; ymmG=(09 19 29 39 0B 1B 2B 3B 0D 1D 2D 3D 0F 1F 2F 3F
392                                        ;       0P 1P 2P 3P 0R 1R 2R 3R 0T 1T 2T 3T 0V 1V 2V 3V)
393    vpunpcklwd  ymmB, ymmB, ymmF        ; ymmB=(01 11 21 31 03 13 23 33 05 15 25 35 07 17 27 37
394                                        ;       0H 1H 2H 3H 0J 1J 2J 3J 0L 1L 2L 3L 0N 1N 2N 3N)
395
396    vpunpckhdq  ymmE, ymmA, ymmB        ; ymmE=(04 14 24 34 05 15 25 35 06 16 26 36 07 17 27 37
397                                        ;       0K 1K 2K 3K 0L 1L 2L 3L 0M 1M 2M 3M 0N 1N 2N 3N)
398    vpunpckldq  ymmB, ymmA, ymmB        ; ymmB=(00 10 20 30 01 11 21 31 02 12 22 32 03 13 23 33
399                                        ;       0G 1G 2G 3G 0H 1H 2H 3H 0I 1I 2I 3I 0J 1J 2J 3J)
400    vpunpckhdq  ymmF, ymmC, ymmG        ; ymmF=(0C 1C 2C 3C 0D 1D 2D 3D 0E 1E 2E 3E 0F 1F 2F 3F
401                                        ;       0S 1S 2S 3S 0T 1T 2T 3T 0U 1U 2U 3U 0V 1V 2V 3V)
402    vpunpckldq  ymmG, ymmC, ymmG        ; ymmG=(08 18 28 38 09 19 29 39 0A 1A 2A 3A 0B 1B 2B 3B
403                                        ;       0O 1O 2O 3O 0P 1P 2P 3P 0Q 1Q 2Q 3Q 0R 1R 2R 3R)
404
405    vperm2i128  ymmA, ymmB, ymmE, 0x20  ; ymmA=(00 10 20 30 01 11 21 31 02 12 22 32 03 13 23 33
406                                        ;       04 14 24 34 05 15 25 35 06 16 26 36 07 17 27 37)
407    vperm2i128  ymmD, ymmG, ymmF, 0x20  ; ymmD=(08 18 28 38 09 19 29 39 0A 1A 2A 3A 0B 1B 2B 3B
408                                        ;       0C 1C 2C 3C 0D 1D 2D 3D 0E 1E 2E 3E 0F 1F 2F 3F)
409    vperm2i128  ymmC, ymmB, ymmE, 0x31  ; ymmC=(0G 1G 2G 3G 0H 1H 2H 3H 0I 1I 2I 3I 0J 1J 2J 3J
410                                        ;       0K 1K 2K 3K 0L 1L 2L 3L 0M 1M 2M 3M 0N 1N 2N 3N)
411    vperm2i128  ymmH, ymmG, ymmF, 0x31  ; ymmH=(0O 1O 2O 3O 0P 1P 2P 3P 0Q 1Q 2Q 3Q 0R 1R 2R 3R
412                                        ;       0S 1S 2S 3S 0T 1T 2T 3T 0U 1U 2U 3U 0V 1V 2V 3V)
413
414    cmp         ecx, byte SIZEOF_YMMWORD
415    jb          short .column_st64
416
417    test        edi, SIZEOF_YMMWORD-1
418    jnz         short .out1
419    ; --(aligned)-------------------
420    vmovntdq    YMMWORD [edi+0*SIZEOF_YMMWORD], ymmA
421    vmovntdq    YMMWORD [edi+1*SIZEOF_YMMWORD], ymmD
422    vmovntdq    YMMWORD [edi+2*SIZEOF_YMMWORD], ymmC
423    vmovntdq    YMMWORD [edi+3*SIZEOF_YMMWORD], ymmH
424    jmp         short .out0
425.out1:  ; --(unaligned)-----------------
426    vmovdqu     YMMWORD [edi+0*SIZEOF_YMMWORD], ymmA
427    vmovdqu     YMMWORD [edi+1*SIZEOF_YMMWORD], ymmD
428    vmovdqu     YMMWORD [edi+2*SIZEOF_YMMWORD], ymmC
429    vmovdqu     YMMWORD [edi+3*SIZEOF_YMMWORD], ymmH
430.out0:
431    add         edi, RGB_PIXELSIZE*SIZEOF_YMMWORD  ; outptr
432    sub         ecx, byte SIZEOF_YMMWORD
433    jz          near .nextrow
434
435    add         esi, byte SIZEOF_YMMWORD  ; inptr0
436    add         ebx, byte SIZEOF_YMMWORD  ; inptr1
437    add         edx, byte SIZEOF_YMMWORD  ; inptr2
438    jmp         near .columnloop
439    alignx      16, 7
440
441.column_st64:
442    cmp         ecx, byte SIZEOF_YMMWORD/2
443    jb          short .column_st32
444    vmovdqu     YMMWORD [edi+0*SIZEOF_YMMWORD], ymmA
445    vmovdqu     YMMWORD [edi+1*SIZEOF_YMMWORD], ymmD
446    add         edi, byte 2*SIZEOF_YMMWORD  ; outptr
447    vmovdqa     ymmA, ymmC
448    vmovdqa     ymmD, ymmH
449    sub         ecx, byte SIZEOF_YMMWORD/2
450.column_st32:
451    cmp         ecx, byte SIZEOF_YMMWORD/4
452    jb          short .column_st16
453    vmovdqu     YMMWORD [edi+0*SIZEOF_YMMWORD], ymmA
454    add         edi, byte SIZEOF_YMMWORD    ; outptr
455    vmovdqa     ymmA, ymmD
456    sub         ecx, byte SIZEOF_YMMWORD/4
457.column_st16:
458    cmp         ecx, byte SIZEOF_YMMWORD/8
459    jb          short .column_st15
460    vmovdqu     XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
461    vperm2i128  ymmA, ymmA, ymmA, 1
462    add         edi, byte SIZEOF_XMMWORD    ; outptr
463    sub         ecx, byte SIZEOF_YMMWORD/8
464.column_st15:
465    ; Store two pixels (8 bytes) of ymmA to the output when it has enough
466    ; space.
467    cmp         ecx, byte SIZEOF_YMMWORD/16
468    jb          short .column_st7
469    vmovq       MMWORD [edi], xmmA
470    add         edi, byte SIZEOF_YMMWORD/16*4
471    sub         ecx, byte SIZEOF_YMMWORD/16
472    vpsrldq     xmmA, SIZEOF_YMMWORD/16*4
473.column_st7:
474    ; Store one pixel (4 bytes) of ymmA to the output when it has enough
475    ; space.
476    test        ecx, ecx
477    jz          short .nextrow
478    vmovd       XMM_DWORD [edi], xmmA
479
480%endif  ; RGB_PIXELSIZE ; ---------------
481
482    alignx      16, 7
483
484.nextrow:
485    pop         ecx
486    pop         esi
487    pop         ebx
488    pop         edx
489    pop         edi
490    pop         eax
491
492    add         esi, byte SIZEOF_JSAMPROW
493    add         ebx, byte SIZEOF_JSAMPROW
494    add         edx, byte SIZEOF_JSAMPROW
495    add         edi, byte SIZEOF_JSAMPROW  ; output_buf
496    dec         eax                        ; num_rows
497    jg          near .rowloop
498
499    sfence                              ; flush the write buffer
500
501.return:
502    vzeroupper
503    pop         edi
504    pop         esi
505;   pop         edx                     ; need not be preserved
506;   pop         ecx                     ; need not be preserved
507    pop         ebx
508    mov         esp, ebp                ; esp <- aligned ebp
509    pop         esp                     ; esp <- original ebp
510    pop         ebp
511    ret
512
513; For some reason, the OS X linker does not honor the request to align the
514; segment unless we do this.
515    align       32
516