1<CsoundSynthesizer>
2
3; Id: C01.CSD mg (2006, rev.2009)
4; author: marco gasperini (marcogsp at yahoo dot it)
5
6; G.M. Koenig
7; ESSAY (1957)
8
9<CsOptions>
10-W -f -oC01.wav
11</CsOptions>
12
13<CsInstruments>
14
15sr     = 192000
16kr     = 192000
17ksmps  = 1
18nchnls = 1
19
20	zakinit 1 , 10
21gifreq	init 0
22
23;=============================================
24; SINUS TONES (S)
25;=============================================
26	instr 1
27iamp	= ampdb(90+p4)
28ifreq	= p5
29gkfreq	= ifreq
30
31a1	oscili iamp , ifreq , 1
32aenv	linen 1 , .005 , p3 , .005
33
34aout	= a1 * aenv
35
36	out aout
37	endin
38;=============================================
39
40;=============================================
41; FILTERED NOISE (N)
42;=============================================
43	instr 2
44iamp	= ampdb(90+p4)
45ifreq	= p5
46gkfreq	= ifreq
47ibw	= ifreq * .05		; filtered noise's bandwidth 5% of central frequency
48
49a1	rnd31 iamp , 1
50k1	rms a1
51
52afilt	butterbp a1 , ifreq , ibw
53afilt	butterbp afilt , ifreq , ibw
54
55aenv	linen .9,  .01 , p3 , .005
56
57aout	gain afilt , k1
58aout	= aout * aenv
59
60	out aout
61	endin
62;=============================================
63
64;=============================================
65; FILTERED IMPULSES (I)
66;=============================================
67	instr 3
68iamp	= ampdb(90+p4)
69ifreq	= p5
70gkfreq	= ifreq
71ibw	= ifreq * .01		; filtered noise's bandwidth 5% of central frequency
72
73if1	= ifreq-(ibw/3)
74if2	= ifreq+((2*ibw)/3)
75
76
77a1	mpulse iamp , 0
78k1	rms a1
79
80afilt	atonex a1 , if1 , 4
81afilt	tonex afilt*100 , if2 , 4
82afilt	butterbp afilt*140 , ifreq , ibw *.5
83
84aenv	linseg 1 , p3-.005, 1 , .005 , 0
85
86aout	= afilt * aenv
87
88	out aout*(sr/192000)
89	endin
90;=============================================
91
92;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
93; Ununderstandable instrument! (mg)
94;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
95	instr 9
96kfreq	= gkfreq
97kndx	zkr 1
98
99	tablew kfreq , kndx*.93 , 2
100
101kndx	= (kndx) + 1
102	display kndx ,p3
103	zkw kndx, 1
104	endin
105;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
106
107
108</CsInstruments>
109<CsScore>
110;functions--------------------------------------------------
111f1	0	8192	10	1	; sinusoid
112f2	0	4096	-2 	0 0 2048 0
113;/functions--------------------------------------------------
114
115t0	4572	; 76.2 cm/sec. tape speed (durations in cm)
116;test--------------------------------------------------
117;mute--------------------------------------------------
118q 1 0 1
119q 2 0 1
120q 3 0 1
121;/mute-------------------------------------------------
122;/test-------------------------------------------------
123
124;==================================================
125; 130. MATERIAL C
126; 131. total length: 76 cm, 3 sections
127;
128; length   sequence
129; 24    cm (2)
130; 16    cm (1)
131; 36    cm (3)
132;==================================================
133
134;==================================131.1
135; 24 cm 11/10
136;---------------------------------------
137;			p4	p5
138;			iamp	ifreq	timbre
139;			[dB]	[Hz]
140i1	0	2.1	0	200	; S
141i1	+	4.1	0	400	; S
142i1	+	3.1	0	238	; S
143i1	+	2.5	0	800	; S
144i1	+	2.3	0	476	; S
145i1	+	3.4	0	1600	; S
146i1	+	2.8	0	283	; S
147i1	+	3.7	0	951	; S
148
149i9	0	24
150s
151t0	4572
152;==================================131.2
153; 16 cm 12/11
154;---------------------------------------
155i1	0	2.6	0	3200	; S
156i1	+	2.4	0	566     ; S
157i1	+	1.9	0	1903    ; S
158i1	+	1.6	0	336     ; S
159i1	+	1.5	0	6400    ; S
160i1	+	2.1	0	1081    ; S
161i1	+	1.7	0	3806    ; S
162i1	+	2.2	0	673     ; S
163
164i9	0	16
165s
166t0	4572
167;==================================131.3
168; 36 cm 10/9
169;---------------------------------------
170i1	0	4.6	0	2263	; S
171i1	+	4.2	0	7611    ; S
172i1	+	3	0	1346    ; S
173i1	+	5.7	0	4526    ; S
174i1	+	5.1	0	2691    ; S
175i1	+	3.4	0	9052    ; S
176i1	+	6.3	0	5382    ; S
177i1	+	3.7	0	10764   ; S
178
179; total length: 76 cm
180
181;-----------------------------------------------------------------------------------------------------------------
182; NOTE
183; the actual values for this last section in the Universal Edition score are wrong, as attested by a comunication
184; between Alvise Vidolin and G.M. Koenig. The values used here are the right values. Those given in the score
185; for 131.3 are the following
186;
187; 2.2 cm
188; 2.5
189; 2.7
190; 3.0
191; 3.4
192; 3.7
193; 4.2
194; 4.6
195; sequence: 5 4 1 7 6 2 8 3
196;
197; the right values are as follow
198;
199; 3.0 cm
200; 3.4
201; 3.7
202; 4.2
203; 4.6
204; 5.1
205; 5.7
206; 6.3
207; sequence: 5 4 1 7 6 2 8 3
208;---------------------------------------------------------------------------------------------------------------------
209
210
211;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
212i9	0	36
213f3	36	4096	-24	2	0 1000
214;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
215e
216</CsScore>
217</CsoundSynthesizer>