1<CsoundSynthesizer>
2
3; Id: F00_b.CSD mg (2006, rev.2009)
4; author: marco gasperini (marcogsp at yahoo dot it)
5
6; G.M. Koenig
7; ESSAY (1957)
8
9<CsOptions>
10-W -f -oF00_b.wav
11</CsOptions>
12
13<CsInstruments>
14
15sr     = 192000
16kr     = 192000
17ksmps  = 1
18nchnls = 1
19
20;=============================================
21; SINUS TONES (S)
22;=============================================
23	instr 1
24iamp	= ampdb(90+p4)
25ifreq	= p5
26
27a1	oscili iamp , ifreq , 1
28aenv	expseg .001 , .005, 1 , p3-.01 ,1, .005,.001
29
30aout	= a1 * aenv
31
32	out aout
33	endin
34;=============================================
35
36;=============================================
37; FILTERED NOISE (N)
38;=============================================
39	instr 2
40iamp	= ampdb(87+p4)
41ifreq	= p5
42ibw	= ifreq * .05		; filtered noise's bandwidth 5% of central frequency
43
44a1	rnd31 iamp , 1
45k1	rms a1
46
47afilt	butterbp a1 , ifreq , ibw
48afilt	butterbp afilt , ifreq , ibw
49
50aenv	expseg .001 , .005, .8 , p3-.01 ,.8 ,.005,.001
51
52aout	gain afilt , k1
53aout	= aout * aenv
54
55	out aout
56	endin
57;=============================================
58
59;=============================================
60; FILTERED IMPULSES (I)
61;=============================================
62	instr 3
63iamp	= ampdb(86+p4)
64ifreq	= p5
65ibw	= ifreq * .01		; filtered pulse's bandwidth 1% of central frequency
66
67if1	= ifreq-(ibw/3)
68if2	= ifreq+((2*ibw)/3)
69
70
71a1	mpulse iamp , 0
72
73afilt	atonex a1 , if1 , 2
74afilt	tonex afilt*900 , if2 , 2
75afilt	butterbp afilt*320 , ifreq , ibw*.05
76
77aenv	linseg 1 , p3-.01, 1 , .01 , 0
78
79aout	= afilt * aenv
80
81	out aout*(sr/192000)
82	endin
83;=============================================
84</CsInstruments>
85<CsScore>
86;functions--------------------------------------------------
87f1	0	8192	10	1	; sinusoid
88;/functions--------------------------------------------------
89
90t0	4572	; 76.2 cm/sec. tape speed (durations in cm)
91
92;test--------------------------------------------------
93;mute-------------------------------------------------
94q 1 0 1
95q 2 0 1
96q 3 0 1
97;/mute-------------------------------------------------
98;/test-------------------------------------------------
99
100;====================================================
101; 160. MATERIAL F
102; 161. total length: 114 cm, 4 sections
103;
104; sequence b1
105;
106; length    sequence
107; 14     cm (1)
108; 21     cm (2)
109
110; sequence b2
111;
112; length    sequence
113; 31.6   cm (3)
114; 47.4   cm (4)
115;==================================================
116
117
118;************************************************** b1
119;==================================161.21
120; 14 cm 12/11
121;----------------------------------------
122;			p4	p5
123;			iamp	ifreq	timbre
124;			[dB]	[Hz]
125i1	0	2.1	0	400	; S
126i1	+	1.6	0	436     ; S
127i1	+	2	0	476     ; S
128i3	5.7	1.4	4	519     ; I
129i1	7.1	1.5	0	566     ; S
130i1	+	1.8	0	617     ; S
131i3	10.4	2.3	2	673     ; I
132i3	+	1.3	1.5	734     ; I
133s
134t0	4572
135;==================================161.22
136; 21 cm 11/10
137;----------------------------------------
138i3	0	3.6	.5	800	; I
139i3	+	2.7	0	872     ; I
140i2	6.3	3.3	-6	951     ; R
141i2	+	2.2	-6	1037    ; R
142i3	11.8	2.4	-2	1131    ; I
143i2	13.2	3	-4	1233    ; R
144i2	+	1.8	-6	1345    ; R
145i2	+	2	-6	1467    ; R
146s
147t0	4572
148;************************************************** b2
149;==================================161.23
150; 31.6 cm 10/9
151;----------------------------------------
152i2	0	3	-5	1532	; R
153i2	+	5	-5	1405    ; R
154i2	+	2.7	-5	1288    ; R
155i2	+	4	-5	1181    ; R
156i2	+	4.5	-5	1083    ; R
157i2	+	5.5	-5	993     ; R
158i2	+	3.3	-5	911     ; R
159i2	+	3.6	-5	835     ; R
160s
161t0	4572
162;==================================161.24
163; 47.4 cm 9/8
164;----------------------------------------
165i2	0	5.4	-4	766	; R
166i2	+	3.8	-4	702     ; R
167i2	+	4.8	-4	644     ; R
168i2	+	7.7	-4	591     ; R
169i2	+	8.6	-4	542     ; R
170i2	+	4.2	-4	497     ; R
171i2	+	6.1	-4	456     ; R
172i2	+	6.8	-4	418     ; R
173
174; total length: 114 cm
175e
176</CsScore>
177</CsoundSynthesizer>