1TEMPLATE = app
2TARGET =
3DEPENDPATH += .
4INCLUDEPATH += .
5VERSION = $$QT_VERSION
6
7# Input
8HEADERS += \
9           demoapplication.h \
10           fluidlauncher.h \
11           pictureflow.h \
12           slideshow.h
13
14SOURCES += \
15           demoapplication.cpp \
16           fluidlauncher.cpp \
17           main.cpp \
18           pictureflow.cpp \
19           slideshow.cpp
20
21embedded{
22    target.path = $$[QT_INSTALL_DEMOS]/embedded/fluidlauncher
23    sources.files = $$SOURCES $$HEADERS $$RESOURCES *.pro *.html config.xml screenshots slides
24    sources.path = $$[QT_INSTALL_DEMOS]/embedded/fluidlauncher
25    INSTALLS += target sources
26}
27
28wince*{
29    QT += svg
30
31    BUILD_DIR = release
32    if(!debug_and_release|build_pass):CONFIG(debug, debug|release) {
33        BUILD_DIR = debug
34    }
35
36    executables.files = \
37        $$QT_BUILD_TREE/demos/embedded/embeddedsvgviewer/$${BUILD_DIR}/embeddedsvgviewer.exe \
38        $$QT_BUILD_TREE/demos/embedded/styledemo/$${BUILD_DIR}/styledemo.exe \
39        $$QT_BUILD_TREE/demos/deform/$${BUILD_DIR}/deform.exe \
40        $$QT_BUILD_TREE/demos/pathstroke/$${BUILD_DIR}/pathstroke.exe \
41        $$QT_BUILD_TREE/examples/graphicsview/elasticnodes/$${BUILD_DIR}/elasticnodes.exe \
42        $$QT_BUILD_TREE/examples/widgets/wiggly/$${BUILD_DIR}/wiggly.exe \
43        $$QT_BUILD_TREE/examples/painting/concentriccircles/$${BUILD_DIR}/concentriccircles.exe \
44        $$QT_BUILD_TREE/examples/draganddrop/$${BUILD_DIR}/fridgemagnets.exe
45
46    executables.path = .
47
48    files.files = $$PWD/screenshots $$PWD/slides $$PWD/../embeddedsvgviewer/shapes.svg
49    files.path = .
50
51    config.files = $$PWD/config_wince/config.xml
52    config.path = .
53
54    DEPLOYMENT += config files executables
55
56    DEPLOYMENT_PLUGIN += qgif qjpeg qmng qsvg
57}
58
59symbian {
60    load(data_caging_paths)
61    include($$QT_SOURCE_TREE/demos/symbianpkgrules.pri)
62    RSS_RULES = # Clear RSS_RULES, otherwise fluidlauncher will get put into QtDemos folder
63
64    TARGET.UID3 = 0xA000A641
65
66    defineReplace(regResourceDir) {
67        symbian-abld|symbian-sbsv2 {
68            return($${EPOCROOT}$$HW_ZDIR$$REG_RESOURCE_IMPORT_DIR/$$basename(1))
69        } else {
70            return($${QT_BUILD_TREE}/$$1)
71        }
72    }
73
74    defineReplace(appResourceDir) {
75        symbian-abld|symbian-sbsv2 {
76            return($${EPOCROOT}$${HW_ZDIR}$${APP_RESOURCE_DIR}/$$basename(1))
77        } else {
78            return($${QT_BUILD_TREE}/$$1)
79        }
80    }
81
82    executables.files = \
83        $$QT_BUILD_TREE/demos/embedded/styledemo/styledemo.exe \
84        $$QT_BUILD_TREE/demos/deform/deform.exe \
85        $$QT_BUILD_TREE/demos/pathstroke/pathstroke.exe \
86        $$QT_BUILD_TREE/examples/widgets/wiggly/wiggly.exe \
87        $$QT_BUILD_TREE/examples/network/qftp/qftp.exe \
88        $$QT_BUILD_TREE/examples/xml/saxbookmarks/saxbookmarks.exe \
89        $$QT_BUILD_TREE/demos/embedded/desktopservices/desktopservices.exe \
90        $$QT_BUILD_TREE/examples/draganddrop/fridgemagnets/fridgemagnets.exe \
91        $$QT_BUILD_TREE/examples/widgets/softkeys/softkeys.exe \
92        $$QT_BUILD_TREE/demos/embedded/raycasting/raycasting.exe \
93        $$QT_BUILD_TREE/demos/embedded/flickable/flickable.exe \
94        $$QT_BUILD_TREE/demos/embedded/digiflip/digiflip.exe \
95        $$QT_BUILD_TREE/demos/embedded/lightmaps/lightmaps.exe \
96        $$QT_BUILD_TREE/demos/embedded/flightinfo/flightinfo.exe
97
98    executables.path = /sys/bin
99
100    reg_resource.files = \
101        $$regResourceDir(demos/embedded/styledemo/styledemo_reg.rsc) \
102        $$regResourceDir(demos/deform/deform_reg.rsc) \
103        $$regResourceDir(demos/pathstroke/pathstroke_reg.rsc) \
104        $$regResourceDir(examples/widgets/wiggly/wiggly_reg.rsc) \
105        $$regResourceDir(examples/network/qftp/qftp_reg.rsc)\
106        $$regResourceDir(examples/xml/saxbookmarks/saxbookmarks_reg.rsc) \
107        $$regResourceDir(demos/embedded/desktopservices/desktopservices_reg.rsc) \
108        $$regResourceDir(examples/draganddrop/fridgemagnets/fridgemagnets_reg.rsc) \
109        $$regResourceDir(examples/widgets/softkeys/softkeys_reg.rsc) \
110        $$regResourceDir(demos/embedded/raycasting/raycasting_reg.rsc) \
111        $$regResourceDir(demos/embedded/flickable/flickable_reg.rsc) \
112        $$regResourceDir(demos/embedded/digiflip/digiflip_reg.rsc) \
113        $$regResourceDir(demos/embedded/lightmaps/lightmaps_reg.rsc) \
114        $$regResourceDir(demos/embedded/flightinfo/flightinfo_reg.rsc)
115
116    contains(QT_CONFIG, phonon) {
117        reg_resource.files += $$regResourceDir(demos/qmediaplayer/qmediaplayer_reg.rsc)
118    }
119
120    contains(QT_CONFIG, multimedia) {
121        reg_resource.files += $$regResourceDir(demos/spectrum/app/spectrum_reg.rsc)
122    }
123
124
125    reg_resource.path = $$REG_RESOURCE_IMPORT_DIR
126
127    resource.files = \
128        $$appResourceDir(demos/embedded/styledemo/styledemo.rsc) \
129        $$appResourceDir(demos/deform/deform.rsc) \
130        $$appResourceDir(demos/pathstroke/pathstroke.rsc) \
131        $$appResourceDir(examples/widgets/wiggly/wiggly.rsc) \
132        $$appResourceDir(examples/network/qftp/qftp.rsc)\
133        $$appResourceDir(examples/xml/saxbookmarks/saxbookmarks.rsc) \
134        $$appResourceDir(demos/embedded/desktopservices/desktopservices.rsc) \
135        $$appResourceDir(examples/draganddrop/fridgemagnets/fridgemagnets.rsc) \
136        $$appResourceDir(examples/widgets/softkeys/softkeys.rsc) \
137        $$appResourceDir(demos/embedded/raycasting/raycasting.rsc) \
138        $$appResourceDir(demos/embedded/flickable/flickable.rsc) \
139        $$appResourceDir(demos/embedded/digiflip/digiflip.rsc) \
140        $$appResourceDir(demos/embedded/lightmaps/lightmaps.rsc) \
141        $$appResourceDir(demos/embedded/flightinfo/flightinfo.rsc)
142
143
144    resource.path = $$APP_RESOURCE_DIR
145
146    mifs.files = \
147        $$appResourceDir(demos/embedded/fluidlauncher/fluidlauncher.mif) \
148        $$appResourceDir(demos/embedded/styledemo/styledemo.mif) \
149        $$appResourceDir(demos/deform/deform.mif) \
150        $$appResourceDir(demos/pathstroke/pathstroke.mif) \
151        $$appResourceDir(examples/widgets/wiggly/wiggly.mif) \
152        $$appResourceDir(examples/network/qftp/qftp.mif) \
153        $$appResourceDir(examples/xml/saxbookmarks/saxbookmarks.mif) \
154        $$appResourceDir(demos/embedded/desktopservices/desktopservices.mif) \
155        $$appResourceDir(examples/draganddrop/fridgemagnets/fridgemagnets.mif) \
156        $$appResourceDir(examples/widgets/softkeys/softkeys.mif) \
157        $$appResourceDir(demos/embedded/raycasting/raycasting.mif) \
158        $$appResourceDir(demos/embedded/flickable/flickable.mif) \
159        $$appResourceDir(demos/embedded/digiflip/digiflip.mif) \
160        $$appResourceDir(demos/embedded/lightmaps/lightmaps.mif) \
161        $$appResourceDir(demos/embedded/flightinfo/flightinfo.mif)
162    mifs.path = $$APP_RESOURCE_DIR
163
164    contains(QT_CONFIG, svg) {
165        executables.files += \
166            $$QT_BUILD_TREE/demos/embedded/embeddedsvgviewer/embeddedsvgviewer.exe \
167            $$QT_BUILD_TREE/demos/embedded/weatherinfo/weatherinfo.exe
168
169        reg_resource.files += \
170            $$regResourceDir(demos/embedded/embeddedsvgviewer/embeddedsvgviewer_reg.rsc) \
171            $$regResourceDir(demos/embedded/weatherinfo/weatherinfo_reg.rsc)
172
173        resource.files += \
174            $$appResourceDir(demos/embedded/embeddedsvgviewer/embeddedsvgviewer.rsc) \
175            $$appResourceDir(demos/embedded/weatherinfo/weatherinfo.rsc)
176
177        mifs.files += \
178            $$appResourceDir(demos/embedded/embeddedsvgviewer/embeddedsvgviewer.mif) \
179            $$appResourceDir(demos/embedded/weatherinfo/weatherinfo.mif)
180
181    }
182    contains(QT_CONFIG, webkit) {
183        executables.files += $$QT_BUILD_TREE/demos/embedded/anomaly/anomaly.exe
184        reg_resource.files += $$regResourceDir(demos/embedded/anomaly/anomaly_reg.rsc)
185        resource.files += $$appResourceDir(demos/embedded/anomaly/anomaly.rsc)
186        mifs.files += \
187            $$appResourceDir(demos/embedded/anomaly/anomaly.mif)
188
189        isEmpty(QT_LIBINFIX) {
190            # Since Fluidlauncher itself doesn't link webkit, we won't get dependency automatically
191            executables.pkg_prerules += \
192                "; Dependency to Qt Webkit" \
193                "(0x200267C2), $${QT_MAJOR_VERSION}, $${QT_MINOR_VERSION}, $${QT_PATCH_VERSION},  {\"QtWebKit\"}"
194        }
195    }
196
197    contains(QT_CONFIG, phonon) {
198        executables.files += $$QT_BUILD_TREE/demos/qmediaplayer/qmediaplayer.exe
199        resource.files += $$appResourceDir(demos/qmediaplayer/qmediaplayer.rsc)
200        mifs.files += \
201            $$appResourceDir(demos/qmediaplayer/qmediaplayer.mif)
202    }
203
204    contains(QT_CONFIG, multimedia) {
205        executables.files += $$QT_BUILD_TREE/demos/spectrum/app/spectrum.exe
206        executables.files += $$QT_BUILD_TREE/demos/spectrum/3rdparty/fftreal/fftreal.dll
207        resource.files += $$appResourceDir(demos/spectrum/app/spectrum.rsc)
208        mifs.files += \
209            $$appResourceDir(demos/spectrum/app/spectrum.mif)
210    }
211
212    contains(QT_CONFIG, script) {
213        executables.files += $$QT_BUILD_TREE/examples/script/context2d/context2d.exe
214        reg_resource.files += $$regResourceDir(examples/script/context2d/context2d_reg.rsc)
215        resource.files += $$appResourceDir(examples/script/context2d/context2d.rsc)
216        mifs.files += \
217            $$appResourceDir(examples/script/context2d/context2d.mif)
218    }
219
220    qmldemos = qmlcalculator qmlclocks qmldialcontrol qmleasing qmlflickr qmlphotoviewer qmltwitter
221    contains(QT_CONFIG, declarative) {
222        for(qmldemo, qmldemos) {
223            executables.files += $$QT_BUILD_TREE/demos/embedded/$${qmldemo}/$${qmldemo}.exe
224            reg_resource.files += $$regResourceDir(demos/embedded/$${qmldemo}/$${qmldemo}_reg.rsc)
225            resource.files += $$appResourceDir(demos/embedded/$${qmldemo}/$${qmldemo}.rsc)
226            mifs.files += $$appResourceDir(demos/embedded/$${qmldemo}/$${qmldemo}.mif)
227        }
228    }
229
230    files.files = $$PWD/screenshots $$PWD/slides
231    files.path = .
232
233    config.files = $$PWD/config_s60/config.xml
234    config.path = .
235
236    viewerimages.files = $$PWD/../embeddedsvgviewer/shapes.svg
237    viewerimages.path = /data/images/qt/demos/embeddedsvgviewer
238
239    # demos/mediaplayer make also use of these files.
240    desktopservices_music.files = \
241        $$PWD/../desktopservices/data/*.mp3 \
242        $$PWD/../desktopservices/data/*.wav
243    desktopservices_music.path = /data/sounds
244
245    desktopservices_images.files = $$PWD/../desktopservices/data/*.png
246    desktopservices_images.path = /data/images
247
248    saxbookmarks.files = $$PWD/../../../examples/xml/saxbookmarks/frank.xbel
249    saxbookmarks.files += $$PWD/../../../examples/xml/saxbookmarks/jennifer.xbel
250    saxbookmarks.path = /data/qt/saxbookmarks
251
252    fluidbackup.files = backup_registration.xml
253    fluidbackup.path = /private/$$replace(TARGET.UID3, 0x,)
254
255    DEPLOYMENT += config files executables viewerimages saxbookmarks reg_resource resource \
256        mifs desktopservices_music desktopservices_images fluidbackup
257
258    contains(QT_CONFIG, declarative):for(qmldemo, qmldemos):include($$QT_BUILD_TREE/demos/embedded/$${qmldemo}/deployment.pri)
259
260    DEPLOYMENT.installer_header = 0xA000D7CD
261
262    TARGET.EPOCHEAPSIZE = 100000 20000000
263}
264