1<?xml version="1.0" encoding="utf-8"?>
2<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
3                version="1.0"
4                xmlns:fo="http://www.w3.org/1999/XSL/Format">
5
6<xsl:import href="http://docbook.sourceforge.net/release/xsl/current/fo/docbook.xsl"/>
7<xsl:include href="stylesheet-common.xsl" />
8
9<xsl:param name="fop1.extensions" select="1"></xsl:param>
10<xsl:param name="tablecolumns.extension" select="0"></xsl:param>
11<xsl:param name="toc.max.depth">3</xsl:param>
12<xsl:param name="ulink.footnotes" select="1"></xsl:param>
13<xsl:param name="use.extensions" select="1"></xsl:param>
14<xsl:param name="variablelist.as.blocks" select="1"></xsl:param>
15
16<xsl:attribute-set name="monospace.verbatim.properties"
17                   use-attribute-sets="verbatim.properties monospace.properties">
18  <xsl:attribute name="wrap-option">wrap</xsl:attribute>
19</xsl:attribute-set>
20
21<xsl:attribute-set name="nongraphical.admonition.properties">
22  <xsl:attribute name="border-style">solid</xsl:attribute>
23  <xsl:attribute name="border-width">1pt</xsl:attribute>
24  <xsl:attribute name="border-color">black</xsl:attribute>
25  <xsl:attribute name="padding-start">12pt</xsl:attribute>
26  <xsl:attribute name="padding-end">12pt</xsl:attribute>
27  <xsl:attribute name="padding-top">6pt</xsl:attribute>
28  <xsl:attribute name="padding-bottom">6pt</xsl:attribute>
29</xsl:attribute-set>
30
31<xsl:attribute-set name="admonition.title.properties">
32  <xsl:attribute name="text-align">center</xsl:attribute>
33</xsl:attribute-set>
34
35<!-- fix missing space after vertical simplelist
36     https://github.com/docbook/xslt10-stylesheets/issues/31 -->
37<xsl:attribute-set name="normal.para.spacing">
38  <xsl:attribute name="space-after.optimum">1em</xsl:attribute>
39  <xsl:attribute name="space-after.minimum">0.8em</xsl:attribute>
40  <xsl:attribute name="space-after.maximum">1.2em</xsl:attribute>
41</xsl:attribute-set>
42
43<!-- Change display of some elements -->
44
45<xsl:template match="command">
46  <xsl:call-template name="inline.monoseq"/>
47</xsl:template>
48
49<xsl:template match="confgroup" mode="bibliography.mode">
50  <fo:inline>
51    <xsl:apply-templates select="conftitle/text()" mode="bibliography.mode"/>
52    <xsl:text>, </xsl:text>
53    <xsl:apply-templates select="confdates/text()" mode="bibliography.mode"/>
54    <xsl:value-of select="$biblioentry.item.separator"/>
55  </fo:inline>
56</xsl:template>
57
58<xsl:template match="isbn" mode="bibliography.mode">
59  <fo:inline>
60    <xsl:text>ISBN </xsl:text>
61    <xsl:apply-templates mode="bibliography.mode"/>
62    <xsl:value-of select="$biblioentry.item.separator"/>
63  </fo:inline>
64</xsl:template>
65
66<!-- bug fix from <https://sourceforge.net/p/docbook/bugs/1360/#831b> -->
67
68<xsl:template match="varlistentry/term" mode="xref-to">
69  <xsl:param name="verbose" select="1"/>
70  <xsl:apply-templates mode="no.anchor.mode"/>
71</xsl:template>
72
73<!-- include refsects in PDF bookmarks
74     (https://github.com/docbook/xslt10-stylesheets/issues/46) -->
75
76<xsl:template match="refsect1|refsect2|refsect3"
77              mode="bookmark">
78
79  <xsl:variable name="id">
80    <xsl:call-template name="object.id"/>
81  </xsl:variable>
82  <xsl:variable name="bookmark-label">
83    <xsl:apply-templates select="." mode="object.title.markup"/>
84  </xsl:variable>
85
86  <fo:bookmark internal-destination="{$id}">
87    <xsl:attribute name="starting-state">
88      <xsl:value-of select="$bookmarks.state"/>
89    </xsl:attribute>
90    <fo:bookmark-title>
91      <xsl:value-of select="normalize-space($bookmark-label)"/>
92    </fo:bookmark-title>
93    <xsl:apply-templates select="*" mode="bookmark"/>
94  </fo:bookmark>
95</xsl:template>
96
97</xsl:stylesheet>
98