1# Qt core object module
2
3HEADERS += \
4        kernel/qabstracteventdispatcher.h \
5        kernel/qabstractnativeeventfilter.h \
6        kernel/qbasictimer.h \
7        kernel/qdeadlinetimer.h \
8        kernel/qdeadlinetimer_p.h \
9        kernel/qelapsedtimer.h \
10        kernel/qeventloop.h \
11        kernel/qpointer.h \
12        kernel/qcorecmdlineargs_p.h \
13        kernel/qcoreapplication.h \
14        kernel/qcoreevent.h \
15        kernel/qmetaobject.h \
16        kernel/qmetatype.h \
17        kernel/qmimedata.h \
18        kernel/qobject.h \
19        kernel/qobject_impl.h \
20        kernel/qobjectdefs.h \
21        kernel/qobjectdefs_impl.h \
22        kernel/qsignalmapper.h \
23        kernel/qsocketnotifier.h \
24        kernel/qtimer.h \
25        kernel/qtranslator.h \
26        kernel/qtranslator_p.h \
27        kernel/qvariant.h \
28        kernel/qabstracteventdispatcher_p.h \
29        kernel/qcoreapplication_p.h \
30        kernel/qobjectcleanuphandler.h \
31        kernel/qvariant_p.h \
32        kernel/qmetaobject_p.h \
33        kernel/qmetaobject_moc_p.h \
34        kernel/qmetaobjectbuilder_p.h \
35        kernel/qobject_p.h \
36        kernel/qcoreglobaldata_p.h \
37        kernel/qsharedmemory.h \
38        kernel/qsharedmemory_p.h \
39        kernel/qsystemsemaphore.h \
40        kernel/qsystemsemaphore_p.h \
41        kernel/qfunctions_p.h \
42        kernel/qmath.h \
43        kernel/qsystemerror_p.h \
44        kernel/qmetatype_p.h \
45        kernel/qmetatypeswitcher_p.h \
46        kernel/qtestsupport_core.h
47
48SOURCES += \
49        kernel/qabstracteventdispatcher.cpp \
50        kernel/qabstractnativeeventfilter.cpp \
51        kernel/qbasictimer.cpp \
52        kernel/qdeadlinetimer.cpp \
53        kernel/qelapsedtimer.cpp \
54        kernel/qeventloop.cpp \
55        kernel/qcoreapplication.cpp \
56        kernel/qcoreevent.cpp \
57        kernel/qmetaobject.cpp \
58        kernel/qmetatype.cpp \
59        kernel/qmetaobjectbuilder.cpp \
60        kernel/qmimedata.cpp \
61        kernel/qobject.cpp \
62        kernel/qobjectcleanuphandler.cpp \
63        kernel/qsignalmapper.cpp \
64        kernel/qsocketnotifier.cpp \
65        kernel/qtimer.cpp \
66        kernel/qtranslator.cpp \
67        kernel/qvariant.cpp \
68        kernel/qcoreglobaldata.cpp \
69        kernel/qsharedmemory.cpp \
70        kernel/qsystemsemaphore.cpp \
71        kernel/qpointer.cpp \
72        kernel/qmath.cpp \
73        kernel/qsystemerror.cpp \
74        kernel/qtestsupport_core.cpp
75
76win32 {
77        SOURCES += \
78                kernel/qcoreapplication_win.cpp \
79                kernel/qelapsedtimer_win.cpp \
80                kernel/qwineventnotifier.cpp \
81                kernel/qsharedmemory_win.cpp \
82                kernel/qsystemsemaphore_win.cpp
83        HEADERS += \
84                kernel/qwineventnotifier.h \
85                kernel/qwineventnotifier_p.h
86
87        winrt {
88            SOURCES += kernel/qeventdispatcher_winrt.cpp
89            HEADERS += kernel/qeventdispatcher_winrt_p.h
90        } else {
91            SOURCES += kernel/qeventdispatcher_win.cpp \
92                       kernel/qwinregistry.cpp
93            HEADERS += kernel/qeventdispatcher_win_p.h \
94                       kernel/qwinregistry_p.h
95        }
96
97        !winrt: LIBS_PRIVATE += -lversion
98}
99
100winrt {
101        SOURCES += \
102                kernel/qfunctions_winrt.cpp
103        HEADERS += \
104                kernel/qfunctions_fake_env_p.h \
105                kernel/qfunctions_winrt.h
106}
107
108mac {
109    HEADERS += \
110        kernel/qcfsocketnotifier_p.h \
111        kernel/qcore_mac_p.h \
112        kernel/qeventdispatcher_cf_p.h
113
114    SOURCES += \
115        kernel/qcfsocketnotifier.cpp \
116        kernel/qcoreapplication_mac.cpp \
117        kernel/qcore_foundation.mm \
118        kernel/qcore_mac.mm \
119        kernel/qeventdispatcher_cf.mm
120
121    !nacl: SOURCES += kernel/qelapsedtimer_mac.cpp
122
123    LIBS_PRIVATE += -framework Foundation
124
125    osx: LIBS_PRIVATE += -framework CoreServices -framework AppKit -framework Security
126
127    ios|tvos {
128        # We need UIKit for UIApplication in qeventdispatcher_cf.mm
129        LIBS_PRIVATE += -framework UIKit
130    }
131
132    watchos {
133        # We need WatchKit for WKExtension in qeventdispatcher_cf.mm
134        LIBS_PRIVATE += -framework WatchKit
135    }
136}
137
138nacl {
139    SOURCES += \
140        kernel/qfunctions_nacl.cpp
141    HEADERS += \
142        kernel/qfunctions_nacl.h
143}
144
145unix|integrity {
146    SOURCES += \
147            kernel/qcore_unix.cpp \
148            kernel/qeventdispatcher_unix.cpp \
149            kernel/qtimerinfo_unix.cpp
150    !darwin|nacl: SOURCES += kernel/qelapsedtimer_unix.cpp
151
152    HEADERS += \
153            kernel/qcore_unix_p.h \
154            kernel/qeventdispatcher_unix_p.h \
155            kernel/qpoll_p.h \
156            kernel/qtimerinfo_unix_p.h
157
158    qtConfig(poll_select): SOURCES += kernel/qpoll.cpp
159
160    qtConfig(glib) {
161        SOURCES += \
162            kernel/qeventdispatcher_glib.cpp
163        HEADERS += \
164            kernel/qeventdispatcher_glib_p.h
165        QMAKE_USE_PRIVATE += glib
166    }
167
168    qtConfig(clock-gettime): QMAKE_USE_PRIVATE += librt
169
170    !android {
171        SOURCES += kernel/qsharedmemory_posix.cpp \
172                   kernel/qsharedmemory_systemv.cpp \
173                   kernel/qsharedmemory_unix.cpp \
174                   kernel/qsystemsemaphore_posix.cpp \
175                   kernel/qsystemsemaphore_systemv.cpp \
176                   kernel/qsystemsemaphore_unix.cpp
177    } else {
178        SOURCES += kernel/qsharedmemory_android.cpp \
179                   kernel/qsystemsemaphore_android.cpp
180    }
181
182    # This is needed by QMetaType::typeName array implementation
183    integrity: QMAKE_CXXFLAGS += --pending_instantiations=128
184}
185
186vxworks {
187        SOURCES += \
188                kernel/qfunctions_vxworks.cpp
189        HEADERS += \
190                kernel/qfunctions_vxworks.h
191}
192
193qnx:qtConfig(qqnx_pps) {
194        QMAKE_USE_PRIVATE += pps
195        SOURCES += \
196                kernel/qppsattribute.cpp \
197                kernel/qppsobject.cpp
198        HEADERS += \
199                kernel/qppsattribute_p.h \
200                kernel/qppsattributeprivate_p.h \
201                kernel/qppsobject_p.h \
202                kernel/qppsobjectprivate_p.h
203}
204
205android:!android-embedded {
206        SOURCES += \
207                   kernel/qjnionload.cpp \
208                   kernel/qjnihelpers.cpp \
209                   kernel/qjni.cpp
210        HEADERS += \
211                   kernel/qjnihelpers_p.h \
212                   kernel/qjni_p.h
213}
214
215!darwin:!unix:!win32: SOURCES += kernel/qelapsedtimer_generic.cpp
216