1gnome = import('gnome')
2
3desktop_file = i18n.merge_file(
4  'desktop',
5  type: 'desktop',
6  input: 'org.gnome.Screenshot.desktop.in',
7  output: 'org.gnome.Screenshot.desktop',
8  po_dir: join_paths(meson.current_source_dir(), '../po'),
9  install: true,
10  install_dir: gnome_screenshot_appsdir
11)
12
13# Validate Desktop file
14desktop_file_validate = find_program('desktop-file-validate', required: false)
15if desktop_file_validate.found()
16  test(
17    'validate-desktop',
18    desktop_file_validate,
19    args: [
20      desktop_file.full_path()
21    ]
22  )
23endif
24
25metainfo_file = i18n.merge_file(
26  'appdata',
27  input: 'org.gnome.Screenshot.metainfo.xml.in',
28  output: 'org.gnome.Screenshot.metainfo.xml',
29  po_dir: join_paths(meson.current_source_dir(), '../po'),
30  install: true,
31  install_dir: gnome_screenshot_appdatadir
32)
33
34# Validate metainfo
35appstream_util = find_program('appstream-util', required: false)
36if appstream_util.found()
37  test(
38    'validate-metainfo',
39    appstream_util,
40    args: [
41      'validate',
42      '--nonet',
43      metainfo_file.full_path()
44    ]
45  )
46endif
47
48service_conf = configuration_data()
49service_conf.set('bindir', gnome_screenshot_bindir)
50configure_file(
51  input: 'org.gnome.Screenshot.service.in',
52  output: 'org.gnome.Screenshot.service',
53  configuration: service_conf,
54  install: true,
55  install_dir: gnome_screenshot_servicesdir
56)
57
58install_data(
59  'org.gnome.gnome-screenshot.gschema.xml',
60  install_dir: gnome_screenshot_schemadir
61)
62
63glib_compile_schemas = find_program('glib-compile-schemas', required: false)
64# Validata GSchema
65if glib_compile_schemas.found()
66  test(
67    'validate-gschema',
68    glib_compile_schemas,
69    args: [
70      '--strict',
71      '--dry-run',
72      meson.current_source_dir()
73    ]
74  )
75endif
76
77resources = gnome.compile_resources(
78  'screenshot-resources',
79  'org.gnome.Screenshot.gresource.xml',
80  source_dir: '.',
81  c_name: 'screenshot'
82)
83
84install_data(
85  'gnome-screenshot.1',
86  install_dir: join_paths(get_option('mandir'), 'man1')
87)
88
89subdir('icons')
90